[gentoo-commits] repo/gentoo:master commit in: dev-ada/gnatcoll-bindings/

["Alfredo Tupone" <tupone@gentoo.org>]

commit:     363485acfd57c67125db6c84b620d177e2a8d4af
Author:     Alfredo Tupone <tupone <AT> gentoo <DOT> org>
AuthorDate: Sat Jan 11 21:36:01 2025 +0000
Commit:     Alfredo Tupone <tupone <AT> gentoo <DOT> org>
CommitDate: Sat Jan 11 21:37:58 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=363485ac

dev-ada/gnatcoll-bindings: add 25.0.0

Signed-off-by: Alfredo Tupone <tupone <AT> gentoo.org>

 dev-ada/gnatcoll-bindings/Manifest                 |   1 +
 .../gnatcoll-bindings-25.0.0.ebuild                | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/dev-ada/gnatcoll-bindings/Manifest b/dev-ada/gnatcoll-bindings/Manifest
index 747f9dbea5eb..eb2ea67853aa 100644
--- a/dev-ada/gnatcoll-bindings/Manifest
+++ b/dev-ada/gnatcoll-bindings/Manifest
@@ -1 +1,2 @@
 DIST gnatcoll-bindings-24.0.0.tar.gz 253286 BLAKE2B 6f9ee60a298f98921df3f8bfd3c6e21a3b54412dfea3d67cb6fe0e85d7ba90f17f83d564d9853e989cd60b0d9d9052694a14a70d10a4f70d161878501edd036b SHA512 d82f593cd0a2822d0007ba768a05e9870aa80b47232154008ea91af4ec758df1b23b92eb5264a58f2b4bedf775d143ce7119046a9ba8f7d5496ed89f3a4a2118
+DIST gnatcoll-bindings-25.0.0.tar.gz 299443 BLAKE2B 8feee477728f036d32b4957ffde309d529eb5ccead784dd1bfaf7a3b945046672467ed3eac49336369bda473f317d30ce73f2d6a8afcbb289da4a4f7496f523a SHA512 0cc5b4a1e966b6e05dcfa15e60cb3960894ffe73b9348f0642a972f4d517e535c617893a4080d33095ee62779b14aeb6cdd8a8f0a8b5a6c8e81c94df132420b2

diff --git a/dev-ada/gnatcoll-bindings/gnatcoll-bindings-25.0.0.ebuild b/dev-ada/gnatcoll-bindings/gnatcoll-bindings-25.0.0.ebuild
new file mode 100644
index 000000000000..9a8aebb46a2b
--- /dev/null
+++ b/dev-ada/gnatcoll-bindings/gnatcoll-bindings-25.0.0.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+ADA_COMPAT=( gcc_13 gcc_14 )
+inherit ada multiprocessing python-single-r1
+
+DESCRIPTION="GNAT Component Collection"
+HOMEPAGE="https://github.com/AdaCore/gnatcoll-bindings/"
+SRC_URI="https://github.com/AdaCore/${PN}/archive/refs/tags/v${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc gmp lzma openmp +shared static-libs static-pic"
+REQUIRED_USE="|| ( shared static-libs static-pic )
+	${PYTHON_REQUIRED_USE}
+	${ADA_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	${ADA_DEPS}
+	dev-ada/gnatcoll-core:${SLOT}[${ADA_USEDEP},shared?,static-libs?,static-pic?]
+	gmp? ( dev-libs/gmp:* )
+	lzma? ( app-arch/xz-utils )
+	openmp? ( sys-devel/gcc:=[openmp] )
+	$(python_gen_cond_dep '
+		doc? (
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		)
+	')"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild[${ADA_USEDEP}]"
+
+QA_EXECSTACK=usr/lib/gnatcoll_readline.*/libgnatcoll_readline.*
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ada_pkg_setup
+}
+
+src_prepare() {
+	rm -r python || die
+	mv python3 python || die
+	default
+}
+
+src_compile() {
+	build () {
+		gprbuild -j$(makeopts_jobs) -m -p -v \
+			-XGPR_BUILD=$2 -XGNATCOLL_CORE_BUILD=$2 \
+			-XLIBRARY_TYPE=$2 -P $1/gnatcoll_$1.gpr -XBUILD="PROD" \
+			-XGNATCOLL_VERSION=${PV} \
+			-XGNATCOLL_ICONV_OPT= -XGNATCOLL_PYTHON_CFLAGS="-I$(python_get_includedir)" \
+			-XGNATCOLL_PYTHON_LIBS=$(python_get_library_path) \
+			-cargs:Ada ${ADAFLAGS} -cargs:C ${CFLAGS} || die "gprbuild failed"
+	}
+	for kind in shared static-libs static-pic ; do
+		if use $kind; then
+			lib=${kind%-libs}
+			lib=${lib/shared/relocatable}
+			build cpp $lib
+			build iconv $lib
+			use gmp && build gmp $lib
+			use lzma && build lzma $lib
+			use openmp && build omp $lib
+			build python $lib
+			build syslog $lib
+			build readline $lib
+			build zlib $lib
+		fi
+	done
+	if use doc; then
+		emake -C iconv/docs html
+		emake -C readline/docs html
+		emake -C syslog/docs html
+		mkdir html
+		mv iconv/docs/_build/html html/iconv || die
+		mv readline/docs/_build/html html/readline || die
+		mv syslog/docs/_build/html html/syslog || die
+	fi
+}
+
+src_install() {
+	build () {
+		gprinstall -p -f -XBUILD=PROD --prefix="${D}"/usr -XLIBRARY_TYPE=$2 \
+			-XGPR_BUILD=$2 -XGNATCOLL_CORE_BUILD=$2 \
+			-XGNATCOLL_VERSION=${PV} --build-var=LIBRARY_TYPE \
+			-XGNATCOLL_ICONV_OPT= -P $1/gnatcoll_$1.gpr --build-name=$2
+	}
+	for kind in shared static-libs static-pic ; do
+		if use $kind; then
+			lib=${kind%-libs}
+			lib=${lib/shared/relocatable}
+			build cpp $lib
+			use gmp && build gmp $lib
+			build iconv $lib
+			use lzma && build lzma $lib
+			use openmp && build omp $lib
+			build python $lib
+			build syslog $lib
+			build readline $lib
+			use lzma && build lzma $lib
+			build zlib $lib
+		fi
+	done
+	rm -rf "${D}"/usr/share/gpr/manifests
+	use doc && HTML_DOCS=( html/* )
+	einstalldocs
+}