[gentoo-commits] repo/gentoo:master commit in: app-emacs/dape/

["Maciej Barć" <xgqt@gentoo.org>]

commit:     65a5b4c3bf6880fb854dedf9b22a5336585b1e68
Author:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
AuthorDate: Mon Jan  6 21:55:26 2025 +0000
Commit:     Maciej Barć <xgqt <AT> gentoo <DOT> org>
CommitDate: Mon Jan  6 22:18:20 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=65a5b4c3

app-emacs/dape: bump to 0.20.0

Signed-off-by: Maciej Barć <xgqt <AT> gentoo.org>

 app-emacs/dape/Manifest           |  1 +
 app-emacs/dape/dape-0.20.0.ebuild | 71 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/app-emacs/dape/Manifest b/app-emacs/dape/Manifest
index 8119ac18d989..ef3c817e1d97 100644
--- a/app-emacs/dape/Manifest
+++ b/app-emacs/dape/Manifest
@@ -1 +1,2 @@
 DIST dape-0.19.0.tar.gz 78244 BLAKE2B aaa4d0b129c1a3f80228527836a202ce7352c6fe4d5ac31710c62d6f9069108ed66a4e3e35808c2e197e8d57b7688249a1605eb288f212cd4f48879dcc687e68 SHA512 7533a0e88dd5418f924378861f7fa33e60c886684dff50785add4347c1cb3c0e728625f7fd9ef703787eea671ead6e5fd81ed3a3c468205e163c352dbe2a49d0
+DIST dape-0.20.0.tar.gz 78429 BLAKE2B 9f079311883ffae56226ad7bbe6835c404397980333dd9539835b2f9301908fe83be6c88eebb2e5fe553eda94303bbc6cbb4f497b92131fa9979c88dccd5a032 SHA512 8a770d84c54fe75275067ca981c96fced384797896a19331d53f782029ec984d3755801dfd29d8c4446e6ac531ffa9dc534cca3b21ae3af52547292da4158b0a

diff --git a/app-emacs/dape/dape-0.20.0.ebuild b/app-emacs/dape/dape-0.20.0.ebuild
new file mode 100644
index 000000000000..c4b8f0561c5d
--- /dev/null
+++ b/app-emacs/dape/dape-0.20.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+NEED_EMACS="29.1"
+
+inherit elisp
+
+DESCRIPTION="Debug Adapter Protocol for Emacs"
+HOMEPAGE="https://github.com/svaante/dape"
+
+if [[ "${PV}" == 9999 ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/svaante/${PN}.git"
+else
+	SRC_URI="https://github.com/svaante/${PN}/archive/refs/tags/${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+RDEPEND="
+	|| (
+		app-emacs/jsonrpc
+		>=app-editors/emacs-30:*
+	)
+"
+DEPEND="
+	${RDEPEND}
+"
+
+# Requires debugpy, but we do not package debugpy right now, as well as
+# js-debug.  Most tests use only the former.
+RESTRICT="test"
+
+DOCS=( README.org CHANGELOG.org LICENSE )
+SITEFILE="50${PN}-gentoo.el"
+
+# elisp-enable-tests ert . -l dape-tests.el
+
+pkg_setup() {
+	elisp_pkg_setup
+	local has_jsonrpc="$(${EMACS} ${EMACSFLAGS} \
+		--eval "(princ (>= emacs-major-version 30))")"
+	if has_version app-emacs/jsonrpc || [[ ${has_jsonrpc} = t ]]; then
+		:
+	else
+		die "Emacs does not have jsonrpc.el 1.0.25 or later, nor was app-emacs/jsonrpc installed"
+	fi
+}
+
+src_compile() {
+	elisp_src_compile
+	elisp-make-autoload-file
+}
+
+# src_test() {
+# 	elisp-test
+# }
+
+src_install() {
+	# Need to ignore dape-tests.el.
+	einstalldocs
+	elisp-install "${PN}" dape.el dape.elc dape-autoloads.el
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+}