[gentoo-commits] repo/gentoo:master commit in: dev-libs/yaz/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     2cca807ccd1bd0047d55e0785a637dfb1dbf07a8
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Sun Dec 29 09:39:00 2024 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Thu Jan  2 00:10:21 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2cca807c

dev-libs/yaz: add 5.34.2

Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Closes: https://github.com/gentoo/gentoo/pull/39887
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 dev-libs/yaz/Manifest          |  1 +
 dev-libs/yaz/yaz-5.34.2.ebuild | 71 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)

diff --git a/dev-libs/yaz/Manifest b/dev-libs/yaz/Manifest
index c3e7c5a58e68..95cf69726d04 100644
--- a/dev-libs/yaz/Manifest
+++ b/dev-libs/yaz/Manifest
@@ -1 +1,2 @@
 DIST yaz-5.34.0.tar.gz 2656382 BLAKE2B 7a16974dc815c1121aaea4179843a6982600a0491c8c95a03f28cf0c68725b986ebc39049e2159cd0d105b23811d35ae3d3538a83e945b64951cc9215efe7f3d SHA512 0c835b98b4640e077459c9ead8043cea941a75f39dace9501efbb56c38837b1525349b8668c135ac0753ba7a4803e38d9c90d7bf3f6f2951c0e7e863b4c51f65
+DIST yaz-5.34.2.tar.gz 2601365 BLAKE2B 525197c4c10e3a41fb0b050a78f00a8122de844a5c7e53d115a079c0ec16144312e7861b048c31cecf00cac900d8fc7dffd98e2ac18c6b046ac9ae521c7d60aa SHA512 8fd22b97cf46c7db8083198ad67745f4b99b303253b669e28f8c509fe3fee223de64d79a7b0a5d9318637b65d056129ca220e3ecbfc7ad392ef634c87543a16b

diff --git a/dev-libs/yaz/yaz-5.34.2.ebuild b/dev-libs/yaz/yaz-5.34.2.ebuild
new file mode 100644
index 000000000000..bd0af16636d5
--- /dev/null
+++ b/dev-libs/yaz/yaz-5.34.2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="C/C++ toolkit for Z39.50v3 clients and servers"
+HOMEPAGE="https://www.indexdata.com/resources/software/yaz/"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/indexdata/yaz.git"
+else
+	SRC_URI="https://ftp.indexdata.com/pub/${PN}/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~s390 ~sparc ~x86"
+fi
+
+LICENSE="BSD GPL-2"
+SLOT="0/5"
+IUSE="gnutls tcpd ziffy"
+
+RDEPEND="
+	dev-libs/icu:=
+	dev-libs/libxml2
+	dev-libs/libxslt
+	sys-libs/readline:=
+	sys-libs/ncurses:=
+	virtual/libintl
+	!gnutls? ( dev-libs/openssl:0= )
+	gnutls? ( net-libs/gnutls:= )
+	tcpd? ( sys-apps/tcp-wrappers )
+	ziffy? ( net-libs/libpcap )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-lang/tcl:0
+	app-alternatives/yacc
+	>=dev-build/libtool-2
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	# Hardcoded assumption of libraries residing in lib/,  bug #730016
+	sed -i -e "s|/lib\"|/$(get_libdir)\"|" configure.ac || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-shared \
+		$(use_with gnutls) \
+		$(use_enable tcpd tcpd /usr)
+}
+
+src_install() {
+	local docdir="/usr/share/doc/${PF}"
+	emake DESTDIR="${D}" docdir="${EPREFIX}/${docdir}" install
+
+	find "${D}" -name '*.la' -delete || die
+
+	dodir "${docdir}"/html
+	mv -f "${ED}"/${docdir}/*.{html,png} "${ED}"/${docdir}/html/ || die "Failed to move HTML docs"
+	mv -f "${ED}"/usr/share/doc/${PN}/common "${ED}"/${docdir}/html/ || die "Failed to move HTML docs"
+	rm -rf "${ED}"/usr/share/doc/${PN} || die
+
+	dodoc ChangeLog NEWS
+}