[gentoo-commits] repo/gentoo:master commit in: kde-plasma/plasma-nm/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     230b73c42ff6f527db3561c8be37299e783dda7a
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  1 19:30:54 2025 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Jan  1 21:04:04 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=230b73c4

kde-plasma/plasma-nm: 6.2.5 version bump

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-plasma/plasma-nm/Manifest               |  1 +
 kde-plasma/plasma-nm/plasma-nm-6.2.5.ebuild | 76 +++++++++++++++++++++++++++++
 2 files changed, 77 insertions(+)

diff --git a/kde-plasma/plasma-nm/Manifest b/kde-plasma/plasma-nm/Manifest
index 6c83a1e24899..64eab99ef170 100644
--- a/kde-plasma/plasma-nm/Manifest
+++ b/kde-plasma/plasma-nm/Manifest
@@ -1 +1,2 @@
 DIST plasma-nm-6.2.4.tar.xz 1248848 BLAKE2B 9fb4d9499e328777544194266fe3360c6180b415578c75f45a016bef53a65ee43e45e28e4a840aceda11b449f71f25db76832583c90e7d27c0b3be9d797bbd67 SHA512 01ab70241b29bf1d0cf79f93a3ee9e1aa9ee2d712fdfba87185d3c2a0c1bb011c197ab98c6d635c9b0337c8d2e26f602c6af3e4ee3c7bb4b59ffca595d242926
+DIST plasma-nm-6.2.5.tar.xz 1243156 BLAKE2B ba7e375a3570a25301c8e32679ef995d7a6b24f0f6ab3de3750fdcfe844b57ca03319a131c2305794041cb1b8677ae3d3571a913bb725d4b7d33fadfe508e2fc SHA512 110c1ce9614a043f7d1aee0f3fe5c0700db4e2708ea9c444006aa90ecbf813acda61c578245929117c39c24a041afb725fec928adf04d8bc077adf4efae0ffaf

diff --git a/kde-plasma/plasma-nm/plasma-nm-6.2.5.ebuild b/kde-plasma/plasma-nm/plasma-nm-6.2.5.ebuild
new file mode 100644
index 000000000000..9416e0c9689d
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-6.2.5.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=6.6.0
+QTMIN=6.7.2
+inherit ecm plasma.kde.org
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="openconnect teamd"
+
+DEPEND="
+	>=app-crypt/qca-2.3.7:2[qt6(+)]
+	dev-libs/qcoro[dbus]
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
+	>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
+	>=kde-frameworks/kcolorscheme-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kitemviews-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ksvg-${KFMIN}:6
+	>=kde-frameworks/kwallet-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/modemmanager-qt-${KFMIN}:6
+	>=kde-frameworks/networkmanager-qt-${KFMIN}:6[teamd=]
+	>=kde-frameworks/solid-${KFMIN}:6
+	>=kde-plasma/libplasma-${KDE_CATV}:6
+	net-misc/mobile-broadband-provider-info
+	net-misc/networkmanager[teamd=]
+	openconnect? (
+		>=dev-qt/qtwebengine-${QTMIN}:6
+		net-vpn/networkmanager-openconnect
+		net-vpn/openconnect:=
+	)
+"
+RDEPEND="${DEPEND}
+	>=kde-frameworks/kdeclarative-${KFMIN}:6
+	>=kde-frameworks/kirigami-${KFMIN}:6
+	>=kde-frameworks/kquickcharts-${KFMIN}:6
+"
+BDEPEND="
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_OPENCONNECT=$(usex openconnect)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if ! has_version "kde-frameworks/kcmutils:6"; then
+		elog "${PN} is not terribly useful without kde-frameworks/kcmutils:6."
+		elog "However, the networkmanagement KCM can be called from either systemsettings"
+		elog "or manually: $ kcmshell6 kcm_networkmanagement"
+	fi
+}