[gentoo-commits] repo/gentoo:master commit in: app-editors/tea/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     ba2f84fde3c835b1733d76c83c6caaecdbeec9c0
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  1 13:11:41 2025 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Jan  1 16:47:44 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ba2f84fd

app-editors/tea: Drop IUSE qt5 (make Qt6 non-optional)

Add missing dev-qt/qtbase:6[gui] USEdep
See also: https://github.com/gentoo/gentoo/pull/34400

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-editors/tea/tea-62.4.0-r1.ebuild | 72 ++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)

diff --git a/app-editors/tea/tea-62.4.0-r1.ebuild b/app-editors/tea/tea-62.4.0-r1.ebuild
new file mode 100644
index 000000000000..673249d95bf6
--- /dev/null
+++ b/app-editors/tea/tea-62.4.0-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+MY_P="tea-qt-${PV}"
+
+DESCRIPTION="Small, lightweight Qt text editor"
+HOMEPAGE="https://tea.ourproject.org/"
+SRC_URI="https://github.com/psemiletov/tea-qt/archive/${PV}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="amd64 ~riscv x86"
+IUSE="aspell djvu pdf"
+
+RESTRICT="test" # no tests
+
+DEPEND="
+	app-text/hunspell:=
+	dev-qt/qt5compat:6
+	dev-qt/qtbase:6[gui,widgets]
+	sys-libs/zlib
+	aspell? ( app-text/aspell )
+	djvu? ( app-text/djvu )
+	pdf? ( app-text/poppler:=[qt6(+)] )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog NEWS NEWS-RU TODO )
+
+PATCHES=( "${FILESDIR}/tea-62.1.1-fix-desktop.patch" )
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Replace AUR link with p.g.o link
+	sed -i \
+		-e 's,AUR: aur.archlinux.org/packages/tea-qt-git,Gentoo: https://packages.gentoo.org/packages/app-editors/tea,' \
+		tea.cpp translations/{de,es,fr,pl,ru}.ts || die
+
+	# Rename tea to tea-qt to avoid file conflict with dev-util/tea
+	# bug #917587
+	# https://github.com/psemiletov/tea-qt/issues/50
+	sed -i -e '/set_target_properties(tea PROPERTIES$/ a\
+		OUTPUT_NAME \"tea-qt\"' \
+		CMakeLists.txt || die
+	sed -i -e '/Exec/ { s/tea/tea-qt/ }' desktop/tea.desktop || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_ASPELL=$(usex aspell)
+		-DUSE_PDF=$(usex pdf)
+		-DUSE_DJVU=$(usex djvu)
+		-DUSE_PRINTER=OFF # appears to be setup wrong
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if [[ "${REPLACING_VERSIONS}" == "47.0.0" ]]; then
+		elog "Executable 'tea' has been renamed to 'tea-qt'"
+	fi
+}