[gentoo-commits] repo/gentoo:master commit in: dev-util/edi/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     90fd578396c4efba82548e89051f860127c35883
Author:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  1 08:15:25 2025 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Wed Jan  1 08:15:25 2025 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=90fd5783

dev-util/edi: update EAPI 7 -> 8, update to llvm-r2.eclass

Closes: https://bugs.gentoo.org/945345
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-util/edi/edi-0.8.0-r3.ebuild | 66 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

diff --git a/dev-util/edi/edi-0.8.0-r3.ebuild b/dev-util/edi/edi-0.8.0-r3.ebuild
new file mode 100644
index 000000000000..ccd558fbace2
--- /dev/null
+++ b/dev-util/edi/edi-0.8.0-r3.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_COMPAT=( 18 19 )
+
+inherit llvm-r2 meson xdg
+
+DESCRIPTION="An EFL-based IDE"
+HOMEPAGE="https://www.enlightenment.org/about-edi
+	https://phab.enlightenment.org/w/projects/edi/
+	https://github.com/Enlightenment/edi"
+SRC_URI="https://github.com/Enlightenment/edi/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2 GPL-3 LGPL-2.1-with-linking-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="clang"
+
+RDEPEND="|| ( dev-libs/efl[X] dev-libs/efl[wayland] )
+	>=dev-libs/efl-1.22.0[eet]
+	clang? (
+		dev-util/bear
+		$(llvm_gen_dep 'llvm-core/clang:${LLVM_SLOT}=')
+	)"
+DEPEND="${RDEPEND}
+	dev-libs/check"
+BDEPEND="virtual/libintl
+	virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/edi-0.8.0-meson-0.61.1-fix.patch )
+
+llvm_check_deps() {
+	has_version "llvm-core/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+	use clang && llvm-r2_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# fix a QA issue with .desktop file, https://phab.enlightenment.org/T7368
+	sed -i '/Version=/d' data/desktop/edi.desktop* || die
+
+	# fix 'unexpected path' QA warning
+	sed -i 's|share/doc/edi/|share/doc/'${PF}'/|g' doc/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use clang bear)
+		$(meson_use clang libclang)
+	)
+
+	if use clang; then
+		emesonargs+=(
+			-D libclang-headerdir="$(llvm-config --includedir)"
+			-D libclang-libdir="$(llvm-config --libdir)"
+		)
+	fi
+
+	meson_src_configure
+}