[gentoo-commits] repo/gentoo:master commit in: media-gfx/nomacs/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     6fd8c4ffb1035b5bdd982456c28e6671b167b966
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 31 20:23:25 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Dec 31 20:24:46 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6fd8c4ff

media-gfx/nomacs: Add missing dependency

Closes: https://bugs.gentoo.org/946680
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-gfx/nomacs/nomacs-3.19.1-r1.ebuild | 77 ++++++++++++++++++++++++++++++++
 1 file changed, 77 insertions(+)

diff --git a/media-gfx/nomacs/nomacs-3.19.1-r1.ebuild b/media-gfx/nomacs/nomacs-3.19.1-r1.ebuild
new file mode 100644
index 000000000000..376134cdea20
--- /dev/null
+++ b/media-gfx/nomacs/nomacs-3.19.1-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_BUILD_TYPE="Release" # buildsys: what a mess
+PLUGIN_PKG="${PN}-plugins-$(ver_cut 1-2).0"
+inherit cmake xdg
+
+DESCRIPTION="Qt-based image viewer"
+HOMEPAGE="https://nomacs.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
+plugins? ( https://github.com/novomesk/${PN}-plugins/archive/refs/tags/$(ver_cut 1-2).0.tar.gz -> ${PLUGIN_PKG}.tar.gz )"
+CMAKE_USE_DIR="${S}/ImageLounge"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86 ~amd64-linux"
+IUSE="+opencv plugins raw +tiff test zip"
+REQUIRED_USE="
+	raw? ( opencv )
+	tiff? ( opencv )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-qt/qt5compat:6
+	dev-qt/qtbase:6[concurrent,cups,gui,network,widgets]
+	dev-qt/qtsvg:6
+	media-gfx/exiv2:=
+	opencv? ( >=media-libs/opencv-3.4:= )
+	raw? ( media-libs/libraw:= )
+	tiff? (
+		dev-qt/qtimageformats:6
+		media-libs/tiff:=
+	)
+	zip? ( dev-libs/quazip:0=[qt6(+)] )
+"
+DEPEND="${RDEPEND}
+	test? ( dev-cpp/gtest )
+"
+BDEPEND="
+	dev-qt/qttools:6[linguist]
+	virtual/pkgconfig
+"
+
+DOCS=( src/changelog.txt )
+
+src_prepare() {
+	if use plugins ; then
+		rmdir ImageLounge/plugins || die
+		mv -v ../${PLUGIN_PKG} ImageLounge/plugins || die
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DQT_VERSION_MAJOR=6
+		-DENABLE_CODE_COV=OFF
+		-DUSE_SYSTEM_QUAZIP=ON
+		-DENABLE_TRANSLATIONS=ON
+		-DENABLE_OPENCV=$(usex opencv)
+		-DENABLE_PLUGINS=$(usex plugins)
+		-DENABLE_RAW=$(usex raw)
+		-DENABLE_TESTING=$(usex test)
+		-DENABLE_TIFF=$(usex tiff)
+		-DENABLE_QUAZIP=$(usex zip)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	cmake_build core_tests
+	cmake_src_test
+}