[gentoo-commits] repo/gentoo:master commit in: games-puzzle/braid-gog/

["James Le Cuirot" <chewi@gentoo.org>]

commit:     7365363861fa6dc9abe8a9c79723e2406f88875c
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 27 23:17:34 2024 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Fri Dec 27 23:17:34 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=73653638

games-puzzle/braid-gog: Make launcher optional, use bundled FLTK

The FLTK 1.3 package will drop 32-bit support or possibly go away entirely.

Signed-off-by: James Le Cuirot <chewi <AT> gentoo.org>

 games-puzzle/braid-gog/braid-gog-2.0.0.3-r1.ebuild | 84 ++++++++++++++++++++++
 games-puzzle/braid-gog/braid-gog-2.0.0.3.ebuild    | 55 --------------
 games-puzzle/braid-gog/metadata.xml                |  3 +
 3 files changed, 87 insertions(+), 55 deletions(-)

diff --git a/games-puzzle/braid-gog/braid-gog-2.0.0.3-r1.ebuild b/games-puzzle/braid-gog/braid-gog-2.0.0.3-r1.ebuild
new file mode 100644
index 000000000000..29f625d647fb
--- /dev/null
+++ b/games-puzzle/braid-gog/braid-gog-2.0.0.3-r1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop unpacker xdg
+
+MY_PN="braid"
+DESCRIPTION="Platform game where you manipulate flow of time"
+HOMEPAGE="https://www.gog.com/en/game/braid"
+SRC_URI="gog_${MY_PN}_${PV}.sh"
+S="${WORKDIR}/data/noarch/game"
+
+LICENSE="GOG-EULA Arphic CC-BY-NC-SA-1.0"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="launcher"
+RESTRICT="bindist fetch splitdebug"
+
+BDEPEND="
+	app-arch/unzip
+"
+
+RDEPEND="
+	!${CATEGORY}/${MY_PN}-hb
+	media-gfx/nvidia-cg-toolkit[abi_x86_32]
+	media-libs/libsdl2[joystick,opengl,sound,video,abi_x86_32]
+	virtual/opengl[abi_x86_32]
+	launcher? (
+		media-libs/fontconfig:1.0[abi_x86_32]
+		x11-libs/libX11[abi_x86_32]
+		x11-libs/libXcursor[abi_x86_32]
+		x11-libs/libXext[abi_x86_32]
+		x11-libs/libXfixes[abi_x86_32]
+		x11-libs/libXft[abi_x86_32]
+		x11-libs/libXinerama[abi_x86_32]
+	)
+"
+
+DIR="/opt/${MY_PN}"
+QA_PREBUILT="${DIR#/}/*"
+
+pkg_nofetch() {
+	einfo "Please buy and download ${SRC_URI} from:"
+	einfo "  ${HOMEPAGE}"
+	einfo "and move it to your distfiles directory."
+}
+
+src_unpack() {
+	unpack_zip ${A}
+}
+
+src_install() {
+	exeinto "${DIR}"
+	insinto "${DIR}"
+
+	doexe Braid.bin.x86
+	doins -r data Icon.bmp
+	dodoc READ_ME.txt
+
+	if use launcher; then
+		doexe launcher.bin.x86
+		exeinto "${DIR}"/lib
+		doexe lib/libfltk.so.1.3
+		dosym "../..${DIR}/launcher.bin.x86" /usr/bin/${MY_PN}
+	else
+		dosym "../..${DIR}/Braid.bin.x86" /usr/bin/${MY_PN}
+	fi
+
+	newicon -s 256 Icon.png ${MY_PN}.png
+	make_desktop_entry ${MY_PN} Braid
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if ! use launcher; then
+		elog "You have disabled the launcher. The game will run fullscreen with"
+		elog "Vsync and postprocessing enabled at an optimal framerate by default."
+		elog "Pass these options to change that:"
+		elog ""
+		elog "  -windowed -width [X] -height [Y] -no_vsync -no_post -[R]fps"
+	fi
+}

diff --git a/games-puzzle/braid-gog/braid-gog-2.0.0.3.ebuild b/games-puzzle/braid-gog/braid-gog-2.0.0.3.ebuild
deleted file mode 100644
index 487d6adc7a25..000000000000
--- a/games-puzzle/braid-gog/braid-gog-2.0.0.3.ebuild
+++ /dev/null
@@ -1,55 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit desktop unpacker wrapper xdg
-
-MY_PN="braid"
-DESCRIPTION="Platform game where you manipulate flow of time"
-HOMEPAGE="https://www.gog.com/en/game/braid"
-SRC_URI="gog_${MY_PN}_${PV}.sh"
-
-LICENSE="GOG-EULA Arphic CC-BY-NC-SA-1.0"
-SLOT="0"
-KEYWORDS="-* ~amd64 ~x86"
-RESTRICT="bindist fetch splitdebug"
-
-BDEPEND="
-	app-arch/unzip
-"
-
-RDEPEND="
-	media-gfx/nvidia-cg-toolkit[abi_x86_32]
-	media-libs/libsdl2[joystick,opengl,sound,video,abi_x86_32]
-	virtual/opengl[abi_x86_32]
-	x11-libs/fltk:1[abi_x86_32]
-	x11-libs/libX11[abi_x86_32]
-	!${CATEGORY}/${MY_PN}-hb
-"
-
-S="${WORKDIR}/data/noarch/game"
-DIR="/opt/${MY_PN}"
-QA_PREBUILT="${DIR#/}/*"
-
-pkg_nofetch() {
-	einfo "Please buy and download ${SRC_URI} from:"
-	einfo "  ${HOMEPAGE}"
-	einfo "and move it to your distfiles directory."
-}
-
-src_unpack() {
-	unpack_zip ${A}
-}
-
-src_install() {
-	exeinto "${DIR}"
-	insinto "${DIR}"
-
-	doexe {Braid,launcher}.bin.x86
-	doins -r data Icon.*
-	dodoc READ_ME.txt
-
-	make_wrapper ${MY_PN} ./launcher.bin.x86 "${DIR}" /usr/$(ABI=x86 get_libdir)/fltk
-	make_desktop_entry ${MY_PN} Braid "${EPREFIX}${DIR}"/Icon.png
-}

diff --git a/games-puzzle/braid-gog/metadata.xml b/games-puzzle/braid-gog/metadata.xml
index 7c730d47817a..9628757c45f0 100644
--- a/games-puzzle/braid-gog/metadata.xml
+++ b/games-puzzle/braid-gog/metadata.xml
@@ -5,4 +5,7 @@
 		<email>games@gentoo.org</email>
 		<name>Gentoo Games Project</name>
 	</maintainer>
+	<use>
+		<flag name="launcher">Install FLTK-based launcher that you probably don't need</flag>
+	</use>
 </pkgmetadata>