[gentoo-commits] repo/gentoo:master commit in: lxqt-base/lxqt-session/

["Jimi Huotari" <chiitoo@gentoo.org>]

commit:     75d8d858813013dffe5d056ea56b55e35f452ec3
Author:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 24 16:31:25 2024 +0000
Commit:     Jimi Huotari <chiitoo <AT> gentoo <DOT> org>
CommitDate: Tue Dec 24 16:34:22 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=75d8d858

lxqt-base/lxqt-session: add 2.1.1

This fixes build against 'procps-ng ≥ 4.0.5'.

Signed-off-by: Jimi Huotari <chiitoo <AT> gentoo.org>

 lxqt-base/lxqt-session/Manifest                  |  1 +
 lxqt-base/lxqt-session/lxqt-session-2.1.1.ebuild | 58 ++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/lxqt-base/lxqt-session/Manifest b/lxqt-base/lxqt-session/Manifest
index 1e1955c19260..c95e4b4d7a0c 100644
--- a/lxqt-base/lxqt-session/Manifest
+++ b/lxqt-base/lxqt-session/Manifest
@@ -1,2 +1,3 @@
 DIST lxqt-session-2.0.0.tar.xz 194480 BLAKE2B 18954f9d440ad8a553b9ccf0aa6bb28a971e7d2010a5b8f0dc32080d5829654bdbc5dd5bd292a0285b1e75af4e0cb0fe4585061e86814c0976c69824015719b4 SHA512 c0b8bbcb666b55b0218bfe1e6669fff0de44a89986dae9afb17ae169e13a2816ef56e62d0b9210449023113a8066d45ccef4fa54b0a5c08c60c2ca4311f142ed
 DIST lxqt-session-2.1.0.tar.xz 212308 BLAKE2B 4036295e6cb61b8f94ee0c56e46c3792894de55f32de0dcd2d121881d1f68450bf9fa9c36f0b9740cb6eaccbbd11aa8e210eaa77e16e97c8f03de1008def4d00 SHA512 b0f70ef1f166fd5c48394f66794c655f1a26411d69c831f671c07ca5eaf9434d2902fbcda507f3b75b69d165a6e234a774c5f8f3f85d7cb924fa3152866d88b5
+DIST lxqt-session-2.1.1.tar.xz 213328 BLAKE2B 4dac6bcd880b2c5e3908feb8c6f13b79e02235015cff7f270f345604f99aff258612cb14cb4243218ce39880181d22d82f81871191992126423bc12e39e2cad9 SHA512 31e5eb2bd4b8cf3b8e7b5dd102339b38f0f132e1dc5784debb6788b31adac877fb45e8885eeae5897ec8c497ed966feab2203325daaa525e1493587cf4e9ef9d

diff --git a/lxqt-base/lxqt-session/lxqt-session-2.1.1.ebuild b/lxqt-base/lxqt-session/lxqt-session-2.1.1.ebuild
new file mode 100644
index 000000000000..3f3742a379aa
--- /dev/null
+++ b/lxqt-base/lxqt-session/lxqt-session-2.1.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="LXQt Session Manager"
+HOMEPAGE="https://lxqt-project.org/"
+
+MY_PV="$(ver_cut 1-2)"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="LGPL-2.1 LGPL-2.1+"
+SLOT="0"
+IUSE="+udev"
+
+BDEPEND="
+	>=dev-qt/qttools-6.6:6[linguist]
+	>=dev-util/lxqt-build-tools-2.1.0
+"
+DEPEND="
+	>=app-misc/qtxdg-tools-4.1.0
+	>=dev-libs/libqtxdg-4.1.0
+	>=dev-qt/qtbase-6.6:6[dbus,gui,widgets]
+	kde-frameworks/kwindowsystem:6[X]
+	kde-plasma/layer-shell-qt:6
+	=lxqt-base/liblxqt-${MY_PV}*:=
+	sys-process/procps:=
+	x11-libs/libX11
+	x11-misc/xdg-user-dirs
+	udev? ( virtual/libudev:= )
+"
+RDEPEND="${DEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_LIBUDEV=$(usex udev)
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	doman lxqt-config-session/man/*.1 lxqt-session/man/*.1
+
+	newenvd - 91lxqt-config-dir <<- _EOF_
+		XDG_CONFIG_DIRS='${EPREFIX}/usr/share'
+	_EOF_
+}