[gentoo-commits] repo/gentoo:master commit in: app-emacs/dape/

["Sam James" <sam@gentoo.org>]

commit:     0f206d54cb8ebd1e692f9d22d36effa6637eac7b
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Sun Dec 22 09:42:58 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sun Dec 22 09:42:58 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0f206d54

app-emacs/dape: add 0.19.0

Signed-off-by: Sam James <sam <AT> gentoo.org>

 app-emacs/dape/Manifest           |  1 +
 app-emacs/dape/dape-0.19.0.ebuild | 68 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/app-emacs/dape/Manifest b/app-emacs/dape/Manifest
index b21a2d796060..2072bba05d01 100644
--- a/app-emacs/dape/Manifest
+++ b/app-emacs/dape/Manifest
@@ -1 +1,2 @@
 DIST dape-0.18.0.tar.gz 78174 BLAKE2B cf883262a7d23d67c5f76dacb47dbc6ea6ed62d81506e1f124d4d85e8a818c692bd26b7d3ef7543fdead999713603a3b008832d5296edcd7fa2d784a2019ec1b SHA512 4d447c7b0fb01707046baa7c6bcd9528fc12bc295259be34a3dca21f9dea85a020cec9557468282947257aad059b174ae211f953ade6d67d615fa2daf50d1400
+DIST dape-0.19.0.tar.gz 78244 BLAKE2B aaa4d0b129c1a3f80228527836a202ce7352c6fe4d5ac31710c62d6f9069108ed66a4e3e35808c2e197e8d57b7688249a1605eb288f212cd4f48879dcc687e68 SHA512 7533a0e88dd5418f924378861f7fa33e60c886684dff50785add4347c1cb3c0e728625f7fd9ef703787eea671ead6e5fd81ed3a3c468205e163c352dbe2a49d0

diff --git a/app-emacs/dape/dape-0.19.0.ebuild b/app-emacs/dape/dape-0.19.0.ebuild
new file mode 100644
index 000000000000..3238a5a3963b
--- /dev/null
+++ b/app-emacs/dape/dape-0.19.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+NEED_EMACS=29.1
+
+inherit elisp
+
+DESCRIPTION="Debug Adapter Protocol for Emacs"
+HOMEPAGE="https://github.com/svaante/dape"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/svaante/${PN}.git"
+else
+	SRC_URI="https://github.com/svaante/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+RDEPEND="
+	|| (
+		app-emacs/jsonrpc
+		>=app-editors/emacs-30:*
+	)
+"
+DEPEND="
+	${RDEPEND}
+"
+
+# Requires debugpy, but we do not package debugpy right now, as well as
+# js-debug.  Most tests use only the former.
+RESTRICT="test"
+
+DOCS=( README.org CHANGELOG.org LICENSE )
+SITEFILE="50${PN}-gentoo.el"
+
+# elisp-enable-tests ert . -l dape-tests.el
+
+pkg_setup() {
+	elisp_pkg_setup
+	local has_jsonrpc="$(${EMACS} ${EMACSFLAGS} \
+		--eval "(princ (>= emacs-major-version 30))")"
+	if has_version app-emacs/jsonrpc || [[ ${has_jsonrpc} = t ]]; then
+		:
+	else
+		die "Emacs does not have jsonrpc.el 1.0.25 or later, nor was app-emacs/jsonrpc installed"
+	fi
+}
+
+src_compile() {
+	elisp_src_compile
+	elisp-make-autoload-file
+}
+
+# src_test() {
+# 	elisp-test
+# }
+
+src_install() {
+	# Need to ignore dape-tests.el.
+	einstalldocs
+	elisp-install "${PN}" dape.el dape.elc dape-autoloads.el
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+}