From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1700713-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id DBD2815802C
for <garchives@archives.gentoo.org>; Mon, 16 Dec 2024 06:11:05 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 58BC7E09F3;
Mon, 16 Dec 2024 06:11:04 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 83575E09DC
for <gentoo-commits@lists.gentoo.org>; Mon, 16 Dec 2024 06:11:02 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id B50E734106C
for <gentoo-commits@lists.gentoo.org>; Mon, 16 Dec 2024 06:11:01 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 19E6D1F24
for <gentoo-commits@lists.gentoo.org>; Mon, 16 Dec 2024 06:11:00 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1734328837.41f36b1bbca88a3ca557cb43f074c2445d03adf2.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/moto/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-python/moto/Manifest dev-python/moto/moto-5.0.23.ebuild
X-VCS-Directories: dev-python/moto/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: 41f36b1bbca88a3ca557cb43f074c2445d03adf2
X-VCS-Branch: master
Date: Mon, 16 Dec 2024 06:11:00 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: a95808b7-36ab-4658-92ec-7554671b955b
X-Archives-Hash: e1806181150d7336ce3845ceccdeed1b
commit: 41f36b1bbca88a3ca557cb43f074c2445d03adf2
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Dec 16 06:00:37 2024 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Dec 16 06:00:37 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=41f36b1b
dev-python/moto: Bump to 5.0.23
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/moto/Manifest | 1 +
dev-python/moto/moto-5.0.23.ebuild | 133 +++++++++++++++++++++++++++++++++++++
2 files changed, 134 insertions(+)
diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index 0c77c78d6d11..af06ff8420d6 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -1,3 +1,4 @@
DIST moto-4.2.14.tar.gz 4933741 BLAKE2B 4c50a808dc8f27cfbcd0ba234d268084ee9a32f36cb5d6af61aacc4ee79f7bf5cf1045147c4642472129eee37bef8bc2c1953d140260d39d7f333ae0f5e5cf95 SHA512 d4079118ed1d2eef9134575e33dc0ed749bff0293d753baa63a630dbb987914b9933445027abdc344bb93fa1d6e483baf8a337a444c9dd055dda50b095ff9937
DIST moto-5.0.21.tar.gz 6212667 BLAKE2B 6f1d991214ab4cfacab76db68a5a5b143adf6de226c0bda2b1c48e0d4f3cbd470b83419edf14cb46dbd35ae6f5129db305a4b07b20e9b2da6f746823939b35ca SHA512 a881426643ab1b3fa858bc8effa1816195ea907352aeb96e9a457a3108d8e712f77788f1e7476822484a3a829d68ba1d9f18a3dc990bc9e403b1c049f892064a
DIST moto-5.0.22.tar.gz 6303034 BLAKE2B 6607f14c2246a63c289ee0ab6b4168a5446e46a9616f680fc2f1ece70a413d0e31d3e078a108556e723e5b4b08657161e1e2224bc602ca60d6c5e935f37af50c SHA512 3f5dcf4f514e7c0864b9a29b26f795505d4604a26c4e062fab4f0414c7a8e009542957ca3c3c6e763e6bccdbd22b74791f3a01f6a52b87a155fe804efeaf9167
+DIST moto-5.0.23.tar.gz 6326074 BLAKE2B 04e313ceb01d03b5982cb4d03d6c2b1af04f06fa6f496fe9cb626b6189bfbb5b2c9e457a91e14f87799deb7e6c0672e687f9068ecba8d1d22a4a667426c3eefa SHA512 b1b720d480031d1dddb76b29b1373a9651a02866d45386f1fe30030ef7da493180068c39fcb6d104329953d0c258448c135bc0aea10090035dd0dc60cd2f8555
diff --git a/dev-python/moto/moto-5.0.23.ebuild b/dev-python/moto/moto-5.0.23.ebuild
new file mode 100644
index 000000000000..2d270d4224ac
--- /dev/null
+++ b/dev-python/moto/moto-5.0.23.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi toolchain-funcs
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="
+ https://github.com/getmoto/moto/
+ https://pypi.org/project/moto/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+ >=dev-python/aws-xray-sdk-0.93[${PYTHON_USEDEP}]
+ dev-python/boto3[${PYTHON_USEDEP}]
+ >=dev-python/botocore-1.14.0[${PYTHON_USEDEP}]
+ >=dev-python/cfn-lint-0.40.0[${PYTHON_USEDEP}]
+ >=dev-python/cryptography-35.0.0[${PYTHON_USEDEP}]
+ dev-python/cookies[${PYTHON_USEDEP}]
+ >=dev-python/docker-3.0.0[${PYTHON_USEDEP}]
+ dev-python/flask[${PYTHON_USEDEP}]
+ dev-python/flask-cors[${PYTHON_USEDEP}]
+ >=dev-python/idna-2.5[${PYTHON_USEDEP}]
+ >=dev-python/jinja2-2.10.1[${PYTHON_USEDEP}]
+ >=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+ dev-python/jsonpath-ng[${PYTHON_USEDEP}]
+ dev-python/jsonschema[${PYTHON_USEDEP}]
+ dev-python/more-itertools[${PYTHON_USEDEP}]
+ >=dev-python/pyparsing-3.0.7[${PYTHON_USEDEP}]
+ >=dev-python/openapi-spec-validator-0.5.0[${PYTHON_USEDEP}]
+ dev-python/pyaml[${PYTHON_USEDEP}]
+ >=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+ >=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+ dev-python/python-dateutil[${PYTHON_USEDEP}]
+ dev-python/python-jose[${PYTHON_USEDEP}]
+ >=dev-python/responses-0.15.0[${PYTHON_USEDEP}]
+ >=dev-python/requests-2.5[${PYTHON_USEDEP}]
+ dev-python/sshpubkeys[${PYTHON_USEDEP}]
+ dev-python/typing-extensions[${PYTHON_USEDEP}]
+ dev-python/xmltodict[${PYTHON_USEDEP}]
+ dev-python/werkzeug[${PYTHON_USEDEP}]
+ dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+ test? (
+ dev-python/antlr4-python3-runtime[${PYTHON_USEDEP}]
+ dev-python/freezegun[${PYTHON_USEDEP}]
+ dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+ )
+"
+
+: "${EPYTEST_TIMEOUT:=180}"
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+ local EPYTEST_DESELECT=(
+ # Needs network (or docker?) but not marked as such, bug #807031
+ # TODO: report upstream
+ tests/test_core/test_request_passthrough.py
+ tests/test_core/test_responses_module.py::TestResponsesMockWithPassThru::test_aws_and_http_requests
+ tests/test_core/test_responses_module.py::TestResponsesMockWithPassThru::test_http_requests
+ # broken code? (local variable used referenced before definition)
+ tests/test_appsync/test_appsync_schema.py
+ # require py_partiql_parser
+ tests/test_s3/test_s3_select.py
+ tests/test_dynamodb/test_dynamodb_statements.py
+ # require joserfc
+ tests/test_apigateway/test_apigateway.py::test_update_authorizer_configuration
+ tests/test_apigateway/test_apigateway.py::test_create_authorizer
+ tests/test_apigateway/test_apigateway.py::test_delete_authorizer
+ tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserDeleter::test_authenticate_with_signed_out_user
+ tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserPoolDuplidateEmails::test_use_existing_email__when_email_is_
+ tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserPoolDuplidateEmails::test_use_existing_email__when_username_
+ tests/test_cognitoidp/test_cognitoidp_replay.py::TestCreateUserPoolWithPredeterminedID::test_different_seed
+ tests/test_cognitoidp/test_cognitoidp_replay.py::TestCreateUserPoolWithPredeterminedID::test_same_seed
+ tests/test_cognitoidp/test_server.py::test_sign_up_user_without_authentication
+ tests/test_cognitoidp/test_server.py::test_admin_create_user_without_authentication
+ tests/test_cognitoidp/test_server.py::test_associate_software_token
+ # TODO
+ tests/test_dynamodb/test_dynamodb_import_table.py
+ tests/test_firehose/test_firehose_put.py::test_put_record_http_destination
+ tests/test_firehose/test_firehose_put.py::test_put_record_batch_http_destination
+ tests/test_stepfunctions/parser/test_stepfunctions_dynamodb_integration.py::test_zero_retry
+ # random crashes
+ tests/test_stepfunctions/parser/test_stepfunctions_sns_integration.py
+ tests/test_stepfunctions/parser/test_stepfunctions_sqs_integration.py
+ tests/test_stepfunctions/test_stepfunctions.py
+ )
+ local EPYTEST_IGNORE=(
+ # require joserfc
+ tests/test_cognitoidp/test_cognitoidp.py
+ )
+
+ case ${EPYTHON} in
+ python3.13)
+ EPYTEST_DESELECT+=(
+ # suddenly started crashing, *shrug*
+ tests/test_xray/test_xray_client.py::test_xray_context_patched
+ tests/test_xray/test_xray_client.py::test_xray_dynamo_request_id
+ tests/test_xray/test_xray_client.py::test_xray_dynamo_request_id_with_context_mgr
+ tests/test_xray/test_xray_client.py::test_xray_udp_emitter_patched
+ )
+ ;;
+ esac
+
+ if ! tc-has-64bit-time_t; then
+ einfo "time_t is smaller than 64 bits, will skip broken tests"
+ EPYTEST_DESELECT+=(
+ tests/test_acm/test_acm.py::test_request_certificate_with_optional_arguments
+ tests/test_s3/test_multiple_accounts_server.py::TestAccountIdResolution::test_with_custom_request_header
+ tests/test_s3/test_server.py::test_s3_server_post_cors_multiple_origins
+ )
+ EPYTEST_IGNORE+=(
+ tests/test_route53domains/test_route53domains_domain.py
+ )
+ fi
+
+ local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+ local -x TZ=UTC
+
+ rm -rf moto || die
+ epytest -m 'not network and not requires_docker' \
+ -p rerunfailures --reruns=5
+}