From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1699953-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 2CEDB1581F0
for <garchives@archives.gentoo.org>; Fri, 13 Dec 2024 23:39:30 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 452E1E0909;
Fri, 13 Dec 2024 23:39:29 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [140.211.166.183])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 4CAC9E090A
for <gentoo-commits@lists.gentoo.org>; Fri, 13 Dec 2024 23:39:28 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.3 with cipher TLS_AES_256_GCM_SHA384 (256/256 bits)
key-exchange X25519 server-signature RSA-PSS (4096 bits) server-digest SHA256)
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 39784340C53
for <gentoo-commits@lists.gentoo.org>; Fri, 13 Dec 2024 23:39:27 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 8E2661C7A
for <gentoo-commits@lists.gentoo.org>; Fri, 13 Dec 2024 23:39:25 +0000 (UTC)
From: "Ionen Wolkens" <ionen@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Ionen Wolkens" <ionen@gentoo.org>
Message-ID: <1734133142.9bc18ca442337b0878120ea556deff319f608f88.ionen@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: games-emulation/mgba/
X-VCS-Repository: repo/gentoo
X-VCS-Files: games-emulation/mgba/Manifest games-emulation/mgba/mgba-0.10.4.ebuild
X-VCS-Directories: games-emulation/mgba/
X-VCS-Committer: ionen
X-VCS-Committer-Name: Ionen Wolkens
X-VCS-Revision: 9bc18ca442337b0878120ea556deff319f608f88
X-VCS-Branch: master
Date: Fri, 13 Dec 2024 23:39:25 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 3d4d24e3-22d8-4599-b88a-0968d8b822fa
X-Archives-Hash: 56ee756d9857ff8e12e094e98cca985d
commit: 9bc18ca442337b0878120ea556deff319f608f88
Author: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 13 23:12:59 2024 +0000
Commit: Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Fri Dec 13 23:39:02 2024 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9bc18ca4
games-emulation/mgba: add 0.10.4
ftr still no Qt6 support in this version, this will be in 0.11.x
Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>
games-emulation/mgba/Manifest | 1 +
games-emulation/mgba/mgba-0.10.4.ebuild | 116 ++++++++++++++++++++++++++++++++
2 files changed, 117 insertions(+)
diff --git a/games-emulation/mgba/Manifest b/games-emulation/mgba/Manifest
index e8faf3bf19e9..959842c7dfee 100644
--- a/games-emulation/mgba/Manifest
+++ b/games-emulation/mgba/Manifest
@@ -1 +1,2 @@
DIST mgba-0.10.3.tar.gz 14350721 BLAKE2B 2109c53455ece7beba0af30787cd75cad85db334be44e41b51f579f813393f8d83c5c9537832b190bb8b0ac1c28d78e92adb6af23191b17b463847df3360f656 SHA512 de92725a18f00ec8645a75cf434a667bfc5aba954d0ae8be188241371a4a310214123be2cec13d20dbff4f660b401364efb51c43c7bdc24eea40454949062a52
+DIST mgba-0.10.4.tar.gz 14355132 BLAKE2B 1f99fd1f79e1645f2de8c1fbd07bdc4996fbc12263fd14b3588e0dcccff910780be73ed92084e53ed873f5e55eef70a983afee2f3f0bd166c578a03bcf57ea0b SHA512 300c09ae8d6dc9677aabb6771345da42b78dc2e4e63e14f1fc404b89737e5161f412f4903488fd222fcf3ac9b0161ba5947a099cd9b5095137d100ce14a14aa3
diff --git a/games-emulation/mgba/mgba-0.10.4.ebuild b/games-emulation/mgba/mgba-0.10.4.ebuild
new file mode 100644
index 000000000000..f0e400060c46
--- /dev/null
+++ b/games-emulation/mgba/mgba-0.10.4.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-{3..4} )
+inherit cmake lua-single xdg
+
+if [[ ${PV} == 9999 ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/mgba-emu/mgba.git"
+else
+ SRC_URI="https://github.com/mgba-emu/mgba/archive/${PV}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Game Boy Advance Emulator"
+HOMEPAGE="https://mgba.io/"
+
+LICENSE="MPL-2.0 BSD LGPL-2.1+ public-domain discord? ( MIT )"
+SLOT="0/$(ver_cut 1-2)"
+IUSE="
+ debug discord elf ffmpeg gles2 gles3 gui libretro
+ lua +opengl +sdl +sqlite test
+"
+REQUIRED_USE="
+ gui? ( || ( gles2 gles3 opengl ) sqlite )
+ lua? ( ${LUA_REQUIRED_USE} )
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ media-libs/libpng:=
+ sys-libs/zlib:=[minizip]
+ debug? ( dev-libs/libedit )
+ elf? ( dev-libs/elfutils )
+ ffmpeg? ( media-video/ffmpeg:= )
+ gles2? ( media-libs/libglvnd )
+ gles3? ( media-libs/libglvnd )
+ lua? ( ${LUA_DEPS} )
+ opengl? ( media-libs/libglvnd )
+ gui? (
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtmultimedia:5
+ dev-qt/qtnetwork:5
+ dev-qt/qtwidgets:5
+ )
+ sdl? ( media-libs/libsdl2[sound,joystick,gles2?,opengl?,video] )
+ sqlite? ( dev-db/sqlite:3 )
+"
+DEPEND="
+ ${RDEPEND}
+ test? ( dev-util/cmocka )
+"
+BDEPEND="
+ gui? ( dev-qt/linguist-tools:5 )
+ lua? ( virtual/pkgconfig )
+"
+
+PATCHES=(
+ "${FILESDIR}"/${PN}-0.10.0-optional-updater.patch
+)
+
+pkg_setup() {
+ use lua && lua-single_pkg_setup
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -DBUILD_CINEMA=$(usex test)
+ -DBUILD_GL=$(usex opengl)
+ -DBUILD_GLES2=$(usex gles2)
+ -DBUILD_GLES3=$(usex gles3)
+ -DBUILD_LIBRETRO=$(usex libretro)
+ -DBUILD_QT=$(usex gui)
+ -DBUILD_ROM_TEST=yes #918855
+ -DBUILD_SDL=$(usex sdl) # also used for gamepads in QT build
+ -DBUILD_SUITE=$(usex test)
+ -DBUILD_UPDATER=no
+ -DENABLE_SCRIPTING=$(usex lua)
+ -DMARKDOWN=no #752048
+ -DUSE_DEBUGGERS=$(usex debug)
+ -DUSE_DISCORD_RPC=$(usex discord)
+ -DUSE_EDITLINE=$(usex debug)
+ -DUSE_ELF=$(usex elf)
+ -DUSE_EPOXY=no
+ -DUSE_FFMPEG=$(usex ffmpeg)
+ -DUSE_GDB_STUB=$(usex debug)
+ -DUSE_LIBZIP=no
+ -DUSE_LZMA=yes
+ -DUSE_MINIZIP=yes
+ -DUSE_PNG=yes
+ -DUSE_SQLITE3=$(usex sqlite)
+ -DUSE_ZLIB=yes
+ $(usev libretro -DLIBRETRO_LIBDIR="${EPREFIX}"/usr/$(get_libdir)/libretro)
+ )
+ use lua && mycmakeargs+=( -DUSE_LUA=$(ver_cut 1-2 $(lua_get_version)) )
+
+ cmake_src_configure
+}
+
+src_test() {
+ # CMakeLists.txt forces SKIP_RPATH=yes when PREFIX=/usr
+ local -x LD_LIBRARY_PATH=${BUILD_DIR}:${LD_LIBRARY_PATH}
+
+ cmake_src_test
+}
+
+src_install() {
+ cmake_src_install
+
+ use !test || rm "${ED}"/usr/bin/mgba-cinema || die
+
+ rm -r -- "${ED}"/usr/share/doc/${PF}/{LICENSE,licenses} || die
+}