[gentoo-commits] repo/gentoo:master commit in: games-arcade/cdogs-sdl/

["Ionen Wolkens" <ionen@gentoo.org>]

commit:     4ea883315e71deaa70fc3bbb8fba5ffa6cb7e711
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 13 23:01:13 2024 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Fri Dec 13 23:37:43 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4ea88331

games-arcade/cdogs-sdl: add 2.2.0

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-arcade/cdogs-sdl/Manifest               |  1 +
 games-arcade/cdogs-sdl/cdogs-sdl-2.2.0.ebuild | 53 +++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/games-arcade/cdogs-sdl/Manifest b/games-arcade/cdogs-sdl/Manifest
index 42e28e424b3d..ae987ebfde27 100644
--- a/games-arcade/cdogs-sdl/Manifest
+++ b/games-arcade/cdogs-sdl/Manifest
@@ -1 +1,2 @@
 DIST cdogs-sdl-2.1.0.tar.gz 35945061 BLAKE2B 03dc9554fd982ecc322a01224846fde05a116cdea8ed8415ba703d2711957ec5314301c7a92117d231d338cabe4c21e14297c2cff1205f6cf1abac1ff7606c4a SHA512 92b82a94cd73c7e33e141878db6ee71ca1e164a41c79e0c575aa02f4121506496e2e8e6bbef1eb239c7b145b90c0a49c3f31f4cc6d8817f75e91f5554b6d6d05
+DIST cdogs-sdl-2.2.0.tar.gz 36897841 BLAKE2B 0f1af568a3bb504475f3072463fadb7a14a97c1a9b49c4ee0fe113ae631d46f307b9602be5d52b45680c3eb161cf976f158bf2aad740c189f7ef3e687531bf01 SHA512 59829c81af2359613f885e54bb1efa917e4ffcd851dc9031dc6f6cf0119a05b7807f3d4d78e1fe05184b50da9982d800f63a08b5ecb6cf7518f9aec5f685f607

diff --git a/games-arcade/cdogs-sdl/cdogs-sdl-2.2.0.ebuild b/games-arcade/cdogs-sdl/cdogs-sdl-2.2.0.ebuild
new file mode 100644
index 000000000000..45e3f8fbcc15
--- /dev/null
+++ b/games-arcade/cdogs-sdl/cdogs-sdl-2.2.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic xdg
+
+DESCRIPTION="Classic overhead run-and-gun game"
+HOMEPAGE="https://cxong.github.io/cdogs-sdl/"
+SRC_URI="
+	https://github.com/cxong/cdogs-sdl/archive/refs/tags/${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="
+	GPL-2+
+	BSD-2 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-3.0 CC0-1.0 WTFPL-2 XMAME public-domain
+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	media-libs/libsdl2[haptic,opengl]
+	media-libs/sdl2-image[png]
+	media-libs/sdl2-mixer[mp3,vorbis,wav]
+	net-libs/enet:1.3=
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.1.1-cmake.patch
+)
+
+src_configure() {
+	filter-lto #858527
+
+	local mycmakeargs=(
+		-DCDOGS_DATA_DIR="${EPREFIX}"/usr/share/${PN}/ # trailing / is needed
+		-DBUILD_EDITOR=OFF
+		-DUSE_SHARED_ENET=ON
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	dodoc doc/{AUTHORS,original_readme.txt}
+
+	# CREDITS is used at runtime, rest is licenses or duplicates
+	find "${ED}"/usr/share/${PN}/doc -type f ! -name CREDITS -delete || die
+}