[gentoo-commits] repo/gentoo:master commit in: dev-tex/rubber/

["Florian Schmaus" <flow@gentoo.org>]

commit:     f8e9383f204a109cfe331614a3796adf1c03eb5a
Author:     Florian Schmaus <flow <AT> gentoo <DOT> org>
AuthorDate: Mon Dec  9 20:58:07 2024 +0000
Commit:     Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Mon Dec  9 20:59:24 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f8e9383f

dev-tex/rubber: add 1.6.7

Signed-off-by: Florian Schmaus <flow <AT> gentoo.org>

 dev-tex/rubber/Manifest            |   1 +
 dev-tex/rubber/rubber-1.6.7.ebuild | 104 +++++++++++++++++++++++++++++++++++++
 2 files changed, 105 insertions(+)

diff --git a/dev-tex/rubber/Manifest b/dev-tex/rubber/Manifest
index 8072a480575e..be3a9c0f2f42 100644
--- a/dev-tex/rubber/Manifest
+++ b/dev-tex/rubber/Manifest
@@ -1,2 +1,3 @@
 DIST rubber-1.6.5.tar.bz2 100300 BLAKE2B bbddf550fbce2f2f98ecf2e737515b4c6891e89494dc2c39cc4a0f268d76f505cad184f27c5f333bc706fe08adcce1d668e8e33c37e26fc6142b12b32797e402 SHA512 e0fadbca6d9e570e6414a99a72da22656abb0fc71e14dd0840bd3dd68364d0da0b2fd5c416f45eb8489bdcb10c226657799efae4ae0c73807b2485b8c8c2094b
 DIST rubber-1.6.6.tar.bz2 100502 BLAKE2B fa74c189b7265206495436b14f229588f7998e0c2f1b148eb8202805ddea54f6391ee15c6ca40957e242b1f065eb1159904fbafe0ddc4d8e6d64cdd26478d614 SHA512 0913a1c9ac012a8bd577e975aca92eae0965137fbc01b049b139f8f31bd85856503af7d760defc67f76894a74ca0616fcb887b1a9395be5a93ff0397ec6795ae
+DIST rubber-1.6.7.tar.bz2 100670 BLAKE2B 468af397d58bc0866fb3443098ae55fff8eff2be9ef9537d8b7d8ea4c45f9928083732778106850f90bcc52d8decafd11386d4c1c69583c3953094180ce4065c SHA512 82ff4457fbe98de15c09adce2dc6dc9693f1ce8bb8f5fa358e9e9f0268e98fb4aa05fe08bafb5a1fad1c400c1623af21e21376c42cec6a162dd05c7791819ef4

diff --git a/dev-tex/rubber/rubber-1.6.7.ebuild b/dev-tex/rubber/rubber-1.6.7.ebuild
new file mode 100644
index 000000000000..da5c2eb0edec
--- /dev/null
+++ b/dev-tex/rubber/rubber-1.6.7.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+DISTUTILS_USE_PEP517=hatchling
+
+inherit distutils-r1
+
+if [[ ${PV} == "9999" ]] || [[ -n "${EGIT_COMMIT_ID}" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/latex-rubber/${PN}.git"
+else
+	# NOTE: Cannot be "PYPI_PN=latex-rubber" + "inherit pypi" due to missing files
+	SRC_URI="https://gitlab.com/latex-rubber/${PN}/-/archive/${PV}/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~ppc ~riscv ~x86"
+fi
+
+DESCRIPTION="A LaTeX wrapper for automatically building documents"
+HOMEPAGE="https://gitlab.com/latex-rubber/rubber"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="virtual/latex-base"
+
+# Test dependencies:
+# - app-text/texlive-core for rubber's 'cweave' test
+# - dev-lang/R for rubber's 'knitr' test (requires knitr R library, currently disabled)
+# - dev-texlive/texlive-latexextra for rubber's 'combine' test (currently disabled)
+BDEPEND="
+	${RDEPEND}
+	virtual/texi2dvi
+	test? (
+		app-text/ghostscript-gpl
+		app-text/texlive-core
+		dev-tex/biber
+		dev-tex/biblatex
+		dev-tex/glossaries
+		dev-tex/latex-beamer
+		$(python_gen_cond_dep 'dev-tex/pythontex[${PYTHON_USEDEP}]')
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-pstricks
+		media-gfx/asymptote
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.6.4-pythontex.patch
+)
+
+pkg_setup() {
+	# https://bugs.gentoo.org/727996
+	export VARTEXFONTS="${T}"/fonts
+}
+
+python_test() {
+	cd tests || die
+
+	# Disable the broken 'combine' test as it uses the 'combine' as a
+	# latex package when it is only a document class (probably only in
+	# newer versions of combine). Also note that this tests works
+	# under debian 'buster'. TODO: Look into potential modifications
+	# done by debian.
+	touch combine/disable || die
+
+	# This test does not work under Gentoo nor Debian 'buster'.
+	# TODO: Investigate why it does not work.
+	touch cweb-latex/disable || die
+
+	# TODO: Investigate why the following are failing.
+	touch fig2dev-dvi/disable || die
+	touch fig2dev-path/disable || die
+	touch fig2dev-path-inplace/disable || die
+	touch fig2dev-path-into/disable || die
+	touch graphicx-dotted-files/disable || die
+	touch hooks-input-file/disable || die
+	touch knitr/disable || die
+
+	# Even tough metapost is available, those tests fail on Gentoo
+	# (while they succeed on Debian 'buster').
+	# TODO: Determine why.
+	# ERROR:mpost:I can't read MetaPost's log file, this is wrong.
+	touch metapost/disable || die
+	# expected error message not reported by Rubber
+	touch metapost-error/disable || die
+	# ERROR:mpost:I can't read MetaPost's log file, this is wrong.
+	touch metapost-input/disable || die
+
+	./run.sh * || die "Tests failed with ${EPYTHON}"
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# Move misplaced files to correct location
+	doinfo doc/${PN}/${PN}.info
+	rm "${ED}"/usr/share/doc/${PN}/${PN}.{texi,info} || die
+	mv "${ED}"/usr/share/doc/{${PN}/*,${PF}/} || die
+	rmdir "${ED}"/usr/share/doc/${PN} || die
+}