[gentoo-commits] repo/gentoo:master commit in: dev-python/poetry/

["Michał Górny" <mgorny@gentoo.org>]

commit:     e1f6c2bbeea9e466dd5501a2110a422b8a9bd926
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sat Dec  7 05:54:31 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat Dec  7 06:32:54 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e1f6c2bb

dev-python/poetry: Bump to 1.8.5

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/poetry/Manifest            |  1 +
 dev-python/poetry/poetry-1.8.5.ebuild | 83 +++++++++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+)

diff --git a/dev-python/poetry/Manifest b/dev-python/poetry/Manifest
index 7baa6258d0d6..886dbc5cd6ce 100644
--- a/dev-python/poetry/Manifest
+++ b/dev-python/poetry/Manifest
@@ -1 +1,2 @@
 DIST poetry-1.8.4.tar.gz 1519163 BLAKE2B 20b73806ae4559e3a137d80db1abbd52b0ba2edb8b512875dcd784c66fa74ebe8659518af9a87349f5ae821f3962bd325d06c2f52567c6d7bd6fb9e10d2988d4 SHA512 59e4e9737ae8a129544460735aa6d82dd4370bd94b37231b5d336cc4f5b9d48a3b7aeaeea1a5b564339663fd0fa914afc83ddf43aef98aa62387daa959d032c0
+DIST poetry-1.8.5.tar.gz 1519790 BLAKE2B 378cb327fe6762e8dd09d7f08fb11cd17963c382754a20fba3cc000ac07ab93672b54d967ba6d609d00e9f303461e55ec40eb9549a0b9329f50c4af363fd2343 SHA512 91c2902e5dfb8f3319de53472b1da20b1d8f570a7a3212e6e55883e364295a9e58ce5b7c59450e741f97692e897283d9f624f3d2128db017476d94fd2ea7839c

diff --git a/dev-python/poetry/poetry-1.8.5.ebuild b/dev-python/poetry/poetry-1.8.5.ebuild
new file mode 100644
index 000000000000..2a5737492d83
--- /dev/null
+++ b/dev-python/poetry/poetry-1.8.5.ebuild
@@ -0,0 +1,83 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A frontend for poetry - a python dependency management and packaging tool"
+HOMEPAGE="
+	https://python-poetry.org/
+	https://github.com/python-poetry/poetry
+	https://pypi.org/project/poetry/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/poetry-core-1.9.1[${PYTHON_USEDEP}]
+	>=dev-python/poetry-plugin-export-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/build-1.0.3[${PYTHON_USEDEP}]
+	>=dev-python/cachecontrol-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cleo-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/crashtest-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/dulwich-0.21.2[${PYTHON_USEDEP}]
+	>=dev-python/fastjsonschema-2.18.0[${PYTHON_USEDEP}]
+	>=dev-python/installer-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/keyring-24.0.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-23.1[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/pkginfo-1.12[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.26[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/shellingham-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/tomlkit-0.11.6[${PYTHON_USEDEP}]
+	>=dev-python/trove-classifiers-2022.5.19[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26.0[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-20.26.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/deepdiff-6.3.1[${PYTHON_USEDEP}]
+		>=dev-python/httpretty-1.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-3.9[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	# unpin
+	sed -e 's:\^:>=:' \
+		-e '/poetry-core/s:":">=:' \
+		-e 's:,<[0-9.]*::' \
+		-i pyproject.toml || die
+
+	distutils-r1_src_prepare
+}
+
+EPYTEST_DESELECT=(
+	# Internal test for lockfile being up-to-date
+	# Meaningless, also sdist does not include lockfile
+	tests/installation/test_installer.py::test_not_fresh_lock
+
+	# TODO
+	tests/installation/test_executor.py::test_executor_known_hashes
+	tests/utils/env/test_env_manager.py::test_create_venv_finds_no_python_executable
+)
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -m "not network" -p pytest_mock
+}