[gentoo-commits] repo/gentoo:master commit in: xfce-extra/xfce4-pulseaudio-plugin/

["Michał Górny" <mgorny@gentoo.org>]

commit:     82fc17ae3a1d9023ca35605d598d2585e537b1e2
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Dec  6 03:21:10 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Dec  6 03:26:57 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=82fc17ae

xfce-extra/xfce4-pulseaudio-plugin: Bump to 0.4.9

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 xfce-extra/xfce4-pulseaudio-plugin/Manifest        |  1 +
 .../xfce4-pulseaudio-plugin-0.4.9.ebuild           | 77 ++++++++++++++++++++++
 2 files changed, 78 insertions(+)

diff --git a/xfce-extra/xfce4-pulseaudio-plugin/Manifest b/xfce-extra/xfce4-pulseaudio-plugin/Manifest
index bad14d876d09..bcc089c0049f 100644
--- a/xfce-extra/xfce4-pulseaudio-plugin/Manifest
+++ b/xfce-extra/xfce4-pulseaudio-plugin/Manifest
@@ -1 +1,2 @@
 DIST xfce4-pulseaudio-plugin-0.4.8.tar.bz2 434257 BLAKE2B 0ba1336fae01199996cd56b26393eecbf1276a645cdc8129ba4a4d817699282e0b84a1c060513fbffee1c84ed2e863b2a82eb5875ef5ea42c53332d6aae5de7f SHA512 8f6f06a65295ff53bd18a32dc302b2d12fb722bcfacd549c79dbc88e8ab6890888f158ea02ce5a21b261fa681068d68f18eb076f1dc2cb9135b7fc1e77fa7ce8
+DIST xfce4-pulseaudio-plugin-0.4.9.tar.bz2 483722 BLAKE2B d2ca77b8072feddf80557c693f37fa4806726701bc7542201bd47193220e1bc2b64559b4a4faaf5abae284bca61c63f12999e7d9c3bcd72b8af422123998b0b9 SHA512 7fa29e85146e8cbbd420aed11050924fbb9c1a93657da1a4d3e207f5a7cc7fc99acdc41b467420a8948535a7f45e2a8e6d63f79df3cef228ada810566f15c263

diff --git a/xfce-extra/xfce4-pulseaudio-plugin/xfce4-pulseaudio-plugin-0.4.9.ebuild b/xfce-extra/xfce4-pulseaudio-plugin/xfce4-pulseaudio-plugin-0.4.9.ebuild
new file mode 100644
index 000000000000..f55338deb501
--- /dev/null
+++ b/xfce-extra/xfce4-pulseaudio-plugin/xfce4-pulseaudio-plugin-0.4.9.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit xdg-utils
+
+DESCRIPTION="A panel plug-in for PulseAudio volume control"
+HOMEPAGE="
+	https://docs.xfce.org/panel-plugins/xfce4-pulseaudio-plugin/start
+	https://gitlab.xfce.org/panel-plugins/xfce4-pulseaudio-plugin/
+"
+SRC_URI="https://archive.xfce.org/src/panel-plugins/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+# TODO: remove wnck when libxfce4windowing is ready to go stable
+IUSE="+keybinder libcanberra libnotify libxfce4windowing wnck"
+REQUIRED_USE="?? ( libxfce4windowing wnck )"
+
+DEPEND="
+	>=dev-libs/glib-2.44.0
+	media-libs/libpulse:=[glib]
+	>=x11-libs/gtk+-3.20.0:3
+	>=xfce-base/exo-0.11:=
+	>=xfce-base/libxfce4ui-4.11.0:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.9.0:=
+	>=xfce-base/xfce4-panel-4.11.0:=
+	>=xfce-base/xfconf-4.6.0:=
+	keybinder? ( dev-libs/keybinder:3 )
+	libcanberra? ( media-libs/libcanberra )
+	libnotify? ( x11-libs/libnotify )
+	libxfce4windowing? ( >=xfce-base/libxfce4windowing-4.19.6:= )
+	wnck? ( x11-libs/libwnck:3 )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local myconf=(
+		$(use_enable keybinder)
+		$(use_enable libcanberra)
+		$(use_enable libnotify)
+		$(use_enable libxfce4windowing)
+		$(use_enable wnck)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	if ! has_version media-sound/pavucontrol; then
+		elog "For the 'audio mixer...' shortcut to work, you need to install"
+		elog "an external mixer application. Please either install:"
+		elog
+		elog "	media-sound/pavucontrol"
+		elog
+		elog "or specify another application to use in the 'Properties' dialog."
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}