[gentoo-commits] repo/gentoo:master commit in: app-admin/bitwarden-desktop-bin/

["Yixun Lan" <dlan@gentoo.org>]

commit:     1a2b5d494640eb8f1dafb502baab9e8d2e802b60
Author:     Yixun Lan <dlan <AT> gentoo <DOT> org>
AuthorDate: Mon Dec  2 11:07:56 2024 +0000
Commit:     Yixun Lan <dlan <AT> gentoo <DOT> org>
CommitDate: Mon Dec  2 11:51:27 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1a2b5d49

app-admin/bitwarden-desktop-bin: add 2024.11.2

Signed-off-by: Yixun Lan <dlan <AT> gentoo.org>

 app-admin/bitwarden-desktop-bin/Manifest           |  1 +
 .../bitwarden-desktop-bin-2024.11.2.ebuild         | 91 ++++++++++++++++++++++
 2 files changed, 92 insertions(+)

diff --git a/app-admin/bitwarden-desktop-bin/Manifest b/app-admin/bitwarden-desktop-bin/Manifest
index 0767db24b35c..ebc792e2cc99 100644
--- a/app-admin/bitwarden-desktop-bin/Manifest
+++ b/app-admin/bitwarden-desktop-bin/Manifest
@@ -1 +1,2 @@
+DIST Bitwarden-2024.11.2-amd64.deb 84510298 BLAKE2B 7decb80519111fd9d2d29c27aba59acd7bf6ca9733ee06a0e798364a9aad1f91e44e4ed30a021da5e527b562a6b908aa50f07568bae69450d938f89668716364 SHA512 ff5d77afaca6c2579bcd9f4f23be9da4de871cef4288a2fc85bae98517c86eda6040b6affee40256a25e1451bc48c098cf33a83bbcaba69cd7acf13fd1bef794
 DIST Bitwarden-2024.9.0-amd64.deb 83998696 BLAKE2B adce754866e47c82de6defe08bdb91135dca744e11b460d116c9b23d45cef1e95302ea04c5d1f9c77c7c52fb125490272bce0bbeae0ac3738f4fc6cd2529572e SHA512 e0ed593fe1501f40c1721f23e1673e5ea6bda265ffc65c526956a0c26ebc33d88d314bd9db8138a4052fd35c3827a355d36fbf4f171f9702d21f3bbab4ea9fa8

diff --git a/app-admin/bitwarden-desktop-bin/bitwarden-desktop-bin-2024.11.2.ebuild b/app-admin/bitwarden-desktop-bin/bitwarden-desktop-bin-2024.11.2.ebuild
new file mode 100644
index 000000000000..ebc9617b1482
--- /dev/null
+++ b/app-admin/bitwarden-desktop-bin/bitwarden-desktop-bin-2024.11.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop unpacker xdg-utils
+
+MY_PN="Bitwarden"
+
+DESCRIPTION="Bitwarden password manager desktop client"
+HOMEPAGE="https://bitwarden.com/"
+SRC_URI="https://github.com/bitwarden/clients/releases/download/desktop-v${PV}/Bitwarden-${PV}-amd64.deb"
+S="${WORKDIR}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-crypt/libsecret
+	dev-libs/expat
+	dev-libs/glib
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/util-linux
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libxkbcommon
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXScrnSaver
+	x11-libs/libxshmfence
+	x11-libs/libXtst
+	x11-libs/pango
+"
+IDEPEND="
+	dev-util/desktop-file-utils
+	dev-util/gtk-update-icon-cache
+"
+
+QA_PREBUILT="
+	opt/Bitwarden/*.so*
+	opt/Bitwarden/bitwarden
+	opt/Bitwarden/bitwarden-app
+	opt/Bitwarden/chrome-sandbox
+	opt/Bitwarden/chrome_crashpad_handler
+"
+
+src_install() {
+	insinto /opt
+	doins -r opt/${MY_PN}
+	fperms 755 /opt/Bitwarden/bitwarden \
+		/opt/Bitwarden/bitwarden-app
+	fperms 4755 /opt/Bitwarden/chrome-sandbox
+
+	domenu usr/share/applications/bitwarden.desktop
+
+	local x
+	for x in 16 32 64 128 256 512; do
+		doicon -s ${x} usr/share/icons/hicolor/${x}*/*
+	done
+
+	dosym -r "/opt/Bitwarden/bitwarden" "usr/bin/${PN}"
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}