[gentoo-commits] repo/gentoo:master commit in: app-accessibility/orca/

["Pacho Ramos" <pacho@gentoo.org>]

commit:     5aca6ea4a58429dafc2339e1a0c0884809cc6c82
Author:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
AuthorDate: Sun Dec  1 11:32:36 2024 +0000
Commit:     Pacho Ramos <pacho <AT> gentoo <DOT> org>
CommitDate: Sun Dec  1 11:36:18 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5aca6ea4

app-accessibility/orca: Fix shebangs and update homepage

Thanks-to: Squeaktoy
Closes: https://bugs.gentoo.org/939905
Signed-off-by: Pacho Ramos <pacho <AT> gentoo.org>

 app-accessibility/orca/orca-46.2-r1.ebuild | 62 ++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/app-accessibility/orca/orca-46.2-r1.ebuild b/app-accessibility/orca/orca-46.2-r1.ebuild
new file mode 100644
index 000000000000..d7404591ef65
--- /dev/null
+++ b/app-accessibility/orca/orca-46.2-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit gnome2 meson python-single-r1
+
+DESCRIPTION="Extensible screen reader that provides access to the desktop"
+HOMEPAGE="https://orca.gnome.org/"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+IUSE="+braille"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	>=app-accessibility/at-spi2-core-2.50:2[introspection]
+	>=dev-libs/glib-2.28:2
+	media-libs/gstreamer:1.0[introspection]
+	>=x11-libs/gtk+-3.6.2:3[introspection]
+	$(python_gen_cond_dep '
+		dev-python/gst-python:1.0[${PYTHON_USEDEP}]
+		>=dev-python/pygobject-3.18:3[${PYTHON_USEDEP}]
+	')
+	braille? (
+		$(python_gen_cond_dep '
+			>=app-accessibility/brltty-5.0-r3[python,${PYTHON_USEDEP}]
+			dev-libs/liblouis[${PYTHON_SINGLE_USEDEP}]
+		')
+	)
+"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		>=app-accessibility/speech-dispatcher-0.8[python,${PYTHON_USEDEP}]
+		>=dev-python/pyatspi-2.46[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+	')
+	x11-libs/libwnck:3[introspection]
+	x11-libs/pango[introspection]
+"
+BDEPEND="
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+#	app-text/yelp-tools
+
+src_configure() {
+	local emesonargs=(
+		-Dspiel=false # spiel not yet in gentoo
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${ED}"
+	python_optimize
+}