[gentoo-commits] repo/gentoo:master commit in: sci-libs/cartopy/

["Thomas Beierlein" <tomjbe@gentoo.org>]

commit:     30a8e71b4e2c22c8217109c5c4ef750cd5241078
Author:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 26 10:42:14 2024 +0000
Commit:     Thomas Beierlein <tomjbe <AT> gentoo <DOT> org>
CommitDate: Tue Nov 26 10:43:18 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=30a8e71b

sci-libs/cartopy: add 0.24.1 with minor fixes

Signed-off-by: Thomas Beierlein <tomjbe <AT> gentoo.org>

 sci-libs/cartopy/Manifest              |  1 +
 sci-libs/cartopy/cartopy-0.24.1.ebuild | 84 ++++++++++++++++++++++++++++++++++
 2 files changed, 85 insertions(+)

diff --git a/sci-libs/cartopy/Manifest b/sci-libs/cartopy/Manifest
index 8c142ae4e64b..946a98b3f28a 100644
--- a/sci-libs/cartopy/Manifest
+++ b/sci-libs/cartopy/Manifest
@@ -1 +1,2 @@
 DIST cartopy-0.24.0.gh.tar.gz 10701591 BLAKE2B 93b555e43031561f4927952839ddb7f95bef3801cbdaa5c20d98612b5a6d0383b83f4c41cf965b9ef2c64aea68c0507b34a3959bebb71b00bd86fc25d2de412a SHA512 eb0349dc3c1358b18f8c8ae71166f1947c3024337d7bf27fe28a2dea30593e7c6fcf1aa4a540537dd02d95f66051469ca679f3a5b8b3c2cf09d2f25736e03a9b
+DIST cartopy-0.24.1.gh.tar.gz 10701425 BLAKE2B b1c6980e4e2b03e6ca2f55eec949b7dc4f58577af3795f71af81bd25f0d6e6a2ef3aca1d09b73dbf9c8e9a611f697843189e60bd821516f80bdbc2af2a4f93af SHA512 de5a4c191e3917941b0bab4e9c92fb60a91ef0263f7066753fd64286c347304ae8b7529b08fa901669173e8630c2b396775daf98161e8cadc62346641555c01a

diff --git a/sci-libs/cartopy/cartopy-0.24.1.ebuild b/sci-libs/cartopy/cartopy-0.24.1.ebuild
new file mode 100644
index 000000000000..3c21d69d0004
--- /dev/null
+++ b/sci-libs/cartopy/cartopy-0.24.1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_EXT=1
+PYTHON_COMPAT=( python3_{9..12} )
+
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 multiprocessing virtualx
+
+MY_PV=${PV/_beta/b}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Python package for geospatial data processing and analysis"
+HOMEPAGE="https://scitools.org.uk/cartopy"
+SRC_URI="https://github.com/SciTools/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	sci-libs/gdal[python,${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/numpy-1.19[${PYTHON_USEDEP}]
+		dev-python/shapely[${PYTHON_USEDEP}]
+		dev-python/six[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/pillow[jpeg,${PYTHON_USEDEP}]
+		dev-python/pyproj[${PYTHON_USEDEP}]
+		sci-libs/pyshp[${PYTHON_USEDEP}]
+	')
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/setuptools-scm[${PYTHON_USEDEP}]
+		dev-python/cython[${PYTHON_USEDEP}]
+	')
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/filelock[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/flufl-lock[${PYTHON_USEDEP}]
+			dev-python/pytest-mpl[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Require network access, not covered by markers
+	lib/cartopy/tests/mpl/test_crs.py
+	lib/cartopy/tests/mpl/test_gridliner.py
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+	# Prepare matplotlib backend for test suite
+	export MPLCONFIGDIR="${T}"
+	echo "backend : Agg" > "${MPLCONFIGDIR}"/matplotlibrc || die
+
+	sed -i -e "s/exclude =/#exclude =/" pyproject.toml || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cd "${BUILD_DIR}" || die
+
+	# Drop all tests needing network access
+	virtx epytest -n "$(makeopts_jobs)" -m "not network and not natural_earth" || die "test failed"
+}