[gentoo-commits] repo/gentoo:master commit in: dev-python/pgspecial/

["Michał Górny" <mgorny@gentoo.org>]

commit:     3210a5741809f07fcd6fa17e3279c1362e7f1efc
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Nov 26 06:51:13 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Nov 26 07:01:29 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3210a574

dev-python/pgspecial: Bump to 2.1.3

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/pgspecial/Manifest               |  1 +
 dev-python/pgspecial/pgspecial-2.1.3.ebuild | 60 +++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-python/pgspecial/Manifest b/dev-python/pgspecial/Manifest
index 0831f7595432..c55b7bf77d96 100644
--- a/dev-python/pgspecial/Manifest
+++ b/dev-python/pgspecial/Manifest
@@ -1 +1,2 @@
 DIST pgspecial-2.1.2.tar.gz 51057 BLAKE2B d164555363e421f716fd9a03653fa8ef6628fc15b71a03acb040c321a20d03e4193725ca3a809b3d4b8710e62005ba9637f35789795d7b4e195f653527617436 SHA512 3ef15c96b8ae84c2c346f44607360aad4bd0abe6f2dfec421af1ca176178b19c64d55baece118600038e105cacb4b5f9b9c3eebbd1e816a9e7a78877d2cb604c
+DIST pgspecial-2.1.3.tar.gz 51204 BLAKE2B 9dec06aba3c1389d0f2a772305dbde4218ecdcc298a325645e3c3869d9f7dc67d55c3b7dc724dbe4dde7b730ea90dd66028f71db3d5361a2618962d20fc97425 SHA512 67f7376cbad896a29e9ae76fd1f78b1e43069dc6a648eb0e68048f22420c606da437ef4b9f1b149a748161e12f061ccff2fd0682e7f2b9d2ac41003bc062b768

diff --git a/dev-python/pgspecial/pgspecial-2.1.3.ebuild b/dev-python/pgspecial/pgspecial-2.1.3.ebuild
new file mode 100644
index 000000000000..0d092904d231
--- /dev/null
+++ b/dev-python/pgspecial/pgspecial-2.1.3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python implementation of PostgreSQL meta commands"
+HOMEPAGE="
+	https://github.com/dbcli/pgspecial/
+	https://pypi.org/project/pgspecial/
+"
+
+LICENSE="BSD MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/click-4.1[${PYTHON_USEDEP}]
+	>=dev-python/configobj-5.0.6[${PYTHON_USEDEP}]
+	>=dev-python/psycopg-3.0.10:0[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.1.19[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-db/postgresql-8.1[server]
+	)
+"
+
+distutils_enable_tests pytest
+
+DOCS=( License.txt README.rst changelog.rst  )
+
+EPYTEST_DESELECT=(
+	# assumes a very specific locale
+	tests/test_specials.py::test_slash_l
+	tests/test_specials.py::test_slash_l_pattern
+	# change in postgres? *shrug*
+	tests/test_specials.py::test_slash_d_view_verbose
+	tests/test_specials.py::test_slash_dn
+)
+
+src_test() {
+	local db=${T}/pgsql
+
+	initdb --username=postgres -D "${db}" || die
+	# TODO: random port
+	pg_ctl -w -D "${db}" start \
+		-o "-h '127.0.0.1' -p 5432 -k '${T}'" || die
+	psql -h "${T}" -U postgres -d postgres \
+		-c "ALTER ROLE postgres WITH PASSWORD 'postgres';" || die
+	createdb -h "${T}" -U postgres _test_db || die
+
+	distutils-r1_src_test
+
+	pg_ctl -w -D "${db}" stop || die
+}