[gentoo-commits] repo/gentoo:master commit in: dev-python/nuitka/

["Michał Górny" <mgorny@gentoo.org>]

commit:     960efc50b06c68c09a86a2fe7cf3776dad8fc504
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 24 15:56:42 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Nov 24 16:57:56 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=960efc50

dev-python/nuitka: Bump to 2.5.2

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/nuitka/Manifest            |  1 +
 dev-python/nuitka/nuitka-2.5.2.ebuild | 55 +++++++++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/dev-python/nuitka/Manifest b/dev-python/nuitka/Manifest
index 932b154dd7ba..61eaa8fd05fb 100644
--- a/dev-python/nuitka/Manifest
+++ b/dev-python/nuitka/Manifest
@@ -1 +1,2 @@
 DIST Nuitka-2.5.1.tar.gz 3776847 BLAKE2B a6c36e736cf8aaa830cb5a47a2ae9ea9394c2afb5163e7955c196fb9ee9c37c61edc085c65f258bac0e27468bd97e5fb93bdeb8776fee85b99fd8c45076166b6 SHA512 ddf86589e2e576ae79b4e88fecac0668ef8e8c720d79d83799a15647c664c0d026f1241bcbc29036fab821611079ae808c22cb81ef14781bc7d0f96c3dba0428
+DIST Nuitka-2.5.2.tar.gz 3779445 BLAKE2B a670a06cab84bf0c6fde599afd50cbd713c780f782240c2349d9636a683fff05a842cd1f9c6c6d7124472ca0bb2a117b5eaa95564d453cdace2a5c672748db68 SHA512 3a112268274931870a11ef00ff17a10e16175b33427babb1159b08cadfe430ff76ca3f5682e238d0813ce1d09c463ea35155c44a1b23fa6b0d3f813bd5c88f7a

diff --git a/dev-python/nuitka/nuitka-2.5.2.ebuild b/dev-python/nuitka/nuitka-2.5.2.ebuild
new file mode 100644
index 000000000000..d79d86fa299c
--- /dev/null
+++ b/dev-python/nuitka/nuitka-2.5.2.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN^}
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 flag-o-matic optfeature pypi
+
+DESCRIPTION="Python to native compiler"
+HOMEPAGE="
+	https://nuitka.net/
+	https://github.com/Nuitka/Nuitka/
+	https://pypi.org/project/Nuitka/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~loong ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-build/scons[${PYTHON_USEDEP}]
+	>=dev-python/ordered-set-4.1.0[${PYTHON_USEDEP}]
+	>=dev-python/zstandard-0.15[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? ( dev-util/ccache )
+"
+
+distutils-r1_src_prepare() {
+	# remove vendored version of SCons that is Python2 only
+	# this should be removed when upstream removes support for Python2
+	rm -vR "nuitka/build/inline_copy/lib/scons-2.3.2/SCons" || die
+	eapply_user
+}
+
+python_install() {
+	distutils-r1_python_install
+	doman doc/nuitka.1 doc/nuitka-run.1
+}
+
+python_test() {
+	append-ldflags -Wl,--no-warn-search-mismatch
+	./tests/basics/run_all.py search || die
+}
+
+pkg_postinst() {
+	optfeature "support for stand-alone executables" dev-util/patchelf
+}