[gentoo-commits] repo/gentoo:master commit in: app-i18n/ibus-libpinyin/

["Yixun Lan" <dlan@gentoo.org>]

commit:     6a1ec49682a3212cfd61226c234cdececfc45b1c
Author:     Graham Ramsey <graham.ramsey <AT> gmail <DOT> com>
AuthorDate: Thu Nov 21 18:11:02 2024 +0000
Commit:     Yixun Lan <dlan <AT> gentoo <DOT> org>
CommitDate: Sun Nov 24 08:55:19 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6a1ec496

app-i18n/ibus-libpinyin: Version bump 1.15.8

Includes fix to prevent build breaking with latest toolchain.

Closes: https://bugs.gentoo.org/935270
Closes: https://github.com/gentoo/gentoo/pull/39400
Signed-off-by: Graham Ramsey <graham.ramsey <AT> gmail.com>
Signed-off-by: Yixun Lan <dlan <AT> gentoo.org>

 app-i18n/ibus-libpinyin/Manifest                   |  1 +
 .../ibus-libpinyin/ibus-libpinyin-1.15.8.ebuild    | 70 ++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/app-i18n/ibus-libpinyin/Manifest b/app-i18n/ibus-libpinyin/Manifest
index dfab2eab8291..4cb1b9af7dfe 100644
--- a/app-i18n/ibus-libpinyin/Manifest
+++ b/app-i18n/ibus-libpinyin/Manifest
@@ -1 +1,2 @@
 DIST ibus-libpinyin-1.15.2.tar.gz 1728300 BLAKE2B a7699fe7f4d7360d09b8c311919630c87fcf2250929f42be2adf1b29a16e60bef2df46539e0fb75ee27700ec7262eb175e6a4d56bedeb895a6272e097a636d00 SHA512 be7525221c4a95df885d1c8c60716c32ad0cfa0a13ca5f9034d06efebf18ab1c207383b30c017da28c1078724b4d9943fc82def68c94bb4e2a0a1e6273c7ad7f
+DIST ibus-libpinyin-1.15.8.tar.gz 1732564 BLAKE2B 94c2729ce0135fbc9ba9f4baad81e97b8589d1bbd048cae840de3565a01513a0d23e3152ddad6aefaf57915f67ca8d2c6592627ab622f2cefb451aab7ee3325c SHA512 525529b1d53a7c40d72097c48f6bfb912810049d46759d8c3c4408b88196edb1d2914d8804d3e83b7f3b5d90a3134697aa8032ecf333ebfd1eb1e6fe741dc025

diff --git a/app-i18n/ibus-libpinyin/ibus-libpinyin-1.15.8.ebuild b/app-i18n/ibus-libpinyin/ibus-libpinyin-1.15.8.ebuild
new file mode 100644
index 000000000000..58b6b8f884c0
--- /dev/null
+++ b/app-i18n/ibus-libpinyin/ibus-libpinyin-1.15.8.ebuild
@@ -0,0 +1,70 @@
+# Copyright 2015-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+LUA_COMPAT=( lua5-{1..3} )
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit autotools gnome2-utils lua-single python-single-r1
+
+DESCRIPTION="Intelligent Pinyin and Bopomofo input methods based on LibPinyin for IBus"
+HOMEPAGE="https://github.com/libpinyin/ibus-libpinyin https://sourceforge.net/projects/libpinyin/"
+SRC_URI="https://github.com/libpinyin/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="boost lua opencc"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	lua? ( ${LUA_REQUIRED_USE} )"
+
+BDEPEND="dev-db/sqlite:3
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+DEPEND="${PYTHON_DEPS}
+	>=app-i18n/libpinyin-2.7.91:=
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	virtual/libintl
+	$(python_gen_cond_dep '
+		app-i18n/ibus[python(+),${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	')
+	boost? ( dev-libs/boost:= )
+	lua? ( ${LUA_DEPS} )
+	opencc? ( app-i18n/opencc:= )"
+
+RDEPEND="${DEPEND}"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+
+	if use lua; then
+		lua-single_pkg_setup
+	fi
+}
+
+src_prepare() {
+	sed -i \
+		-e "/^appdatadir/s:/appdata:/metainfo:" \
+		data/Makefile.am || die
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--enable-english-input-mode \
+		$(use_enable boost) \
+		$(use_enable lua lua-extension) \
+		$(use_enable opencc)
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}