[gentoo-commits] repo/gentoo:master commit in: media-video/ffmpeg-chromium/

["Matt Jolly" <kangie@gentoo.org>]

commit:     aec93c95f3fad14c0a7cc42431f8ce1ea65fa6b5
Author:     Matt Jolly <kangie <AT> gentoo <DOT> org>
AuthorDate: Sat Nov 16 22:08:37 2024 +0000
Commit:     Matt Jolly <kangie <AT> gentoo <DOT> org>
CommitDate: Sat Nov 16 22:08:37 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=aec93c95

media-video/ffmpeg-chromium: add 133

Signed-off-by: Matt Jolly <kangie <AT> gentoo.org>

 media-video/ffmpeg-chromium/Manifest               |   1 +
 .../ffmpeg-chromium/ffmpeg-chromium-133.ebuild     | 239 +++++++++++++++++++++
 2 files changed, 240 insertions(+)

diff --git a/media-video/ffmpeg-chromium/Manifest b/media-video/ffmpeg-chromium/Manifest
index 201e07b60a53..1b9694d58c33 100644
--- a/media-video/ffmpeg-chromium/Manifest
+++ b/media-video/ffmpeg-chromium/Manifest
@@ -6,3 +6,4 @@ DIST ffmpeg-chromium-129.tar.xz 10424032 BLAKE2B dbe0b8c2d799958660b6a3ca0f1a8e6
 DIST ffmpeg-chromium-130.tar.xz 10420352 BLAKE2B 1b7711a3ee349d1e0d8ad8f761c8a38f78a5088dcf985d5da6423938fd93512b177d749949d4a6a3894f6b1faa4e4a0a0584067448d2ac5c886c00bbc25db89c SHA512 ee1a13634695ef5fb3e1a812420662e17449cab5e3c4e29611f9503b771ccb60c4821136160c51faeb4e18919efc3138ca8e034a27f44739a60cc3452d31572a
 DIST ffmpeg-chromium-131.tar.xz 10550352 BLAKE2B 985a4d0caede506050d2277af956723ae74236e2373d766862cef669031e91e44bcb51de219a76a1663f5cac5d85c74bd85215e96dffb14e6090d05ba6031f6c SHA512 1ccba5547ead2a64bcf72b6cdc9b6f9f8a6f817840125248b4d41efdf8376f8a69e8f7d3e4527cf155bb0a058ea6fc9f4cdb12d40a4b74189682e0db7b501ba3
 DIST ffmpeg-chromium-132.tar.xz 10588420 BLAKE2B 988fa447019d4fc3a26685bffd9345b4cf31ace3d39c31a070551f4d4f664cf2982b47c4b6265c2f3e2e7b0eca65effb68a9e25840b6a5ca61600a33d5901b8b SHA512 51856a226e29345c708356e1c6ae478239f1f634937e0ad4caa73e33c7bef1dbaeae97d8670ccd8f15e628fc3d399fdb3a4be1769c57d1283704743b6ce23b72
+DIST ffmpeg-chromium-133.tar.xz 10592716 BLAKE2B 81aac47dfb694c605242e762e6ced29714bc9780907afda6f61f55afef5416d1d998dda6785e8e64b7968f8b9cfc03bdcc4711535ccad65e6a9c55c626d30226 SHA512 798704455973439d3a1990e6344fe7bf1ebef370e7316cb813e898b84b4a39809e5681d54554a765a8f474731fcdf69897fb00f0b5e7ecc6b2e1bd6eef46a77a

diff --git a/media-video/ffmpeg-chromium/ffmpeg-chromium-133.ebuild b/media-video/ffmpeg-chromium/ffmpeg-chromium-133.ebuild
new file mode 100644
index 000000000000..eab885d6038b
--- /dev/null
+++ b/media-video/ffmpeg-chromium/ffmpeg-chromium-133.ebuild
@@ -0,0 +1,239 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic toolchain-funcs
+
+COMMIT=591ae4b02eaff9a03e2ec863da895128b0b49910
+DESCRIPTION="FFmpeg built specifically for codec support in Chromium-based browsers"
+HOMEPAGE="https://ffmpeg.org/"
+SRC_URI="https://deps.gentoo.zip/media-video/${P}.tar.xz"
+
+LICENSE="
+	!gpl? ( LGPL-2.1 )
+	gpl? ( GPL-2 )
+"
+SLOT="${PV}"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64"
+
+# Options to use as use_enable in the foo[:bar] form.
+# This will feed configure with $(use_enable foo bar)
+# or $(use_enable foo foo) if no :bar is set.
+# foo is added to IUSE.
+FFMPEG_FLAG_MAP=(
+		cpudetection:runtime-cpudetect debug
+		+gpl
+		vaapi vdpau vulkan
+		nvenc:ffnvcodec
+		# Threads; we only support pthread for now but ffmpeg supports more
+		+threads:pthreads
+)
+
+IUSE="
+	${FFMPEG_FLAG_MAP[@]%:*}
+"
+
+# Strings for CPU features in the useflag[:configure_option] form
+# if :configure_option isn't set, it will use 'useflag' as configure option
+ARM_CPU_FEATURES=(
+	cpu_flags_arm_thumb:armv5te
+	cpu_flags_arm_v6:armv6
+	cpu_flags_arm_thumb2:armv6t2
+	cpu_flags_arm_neon:neon
+	cpu_flags_arm_vfp:vfp
+	cpu_flags_arm_vfpv3:vfpv3
+	cpu_flags_arm_v8:armv8
+	cpu_flags_arm_asimddp:dotprod
+	cpu_flags_arm_i8mm:i8mm
+)
+ARM_CPU_REQUIRED_USE="
+	arm64? ( cpu_flags_arm_v8 )
+	cpu_flags_arm_v8? ( cpu_flags_arm_vfpv3 cpu_flags_arm_neon )
+	cpu_flags_arm_neon? (
+		cpu_flags_arm_vfp
+		arm? ( cpu_flags_arm_thumb2 )
+	)
+	cpu_flags_arm_vfpv3? ( cpu_flags_arm_vfp )
+	cpu_flags_arm_thumb2? ( cpu_flags_arm_v6 )
+	cpu_flags_arm_v6? (
+		arm? ( cpu_flags_arm_thumb )
+	)
+"
+X86_CPU_FEATURES_RAW=( 3dnow:amd3dnow 3dnowext:amd3dnowext aes:aesni avx:avx avx2:avx2 fma3:fma3 fma4:fma4 mmx:mmx
+					   mmxext:mmxext sse:sse sse2:sse2 sse3:sse3 ssse3:ssse3 sse4_1:sse4 sse4_2:sse42 xop:xop )
+X86_CPU_FEATURES=( ${X86_CPU_FEATURES_RAW[@]/#/cpu_flags_x86_} )
+X86_CPU_REQUIRED_USE="
+	cpu_flags_x86_avx2? ( cpu_flags_x86_avx )
+	cpu_flags_x86_fma4? ( cpu_flags_x86_avx )
+	cpu_flags_x86_fma3? ( cpu_flags_x86_avx )
+	cpu_flags_x86_xop?  ( cpu_flags_x86_avx )
+	cpu_flags_x86_avx?  ( cpu_flags_x86_sse4_2 )
+	cpu_flags_x86_aes? ( cpu_flags_x86_sse4_2 )
+	cpu_flags_x86_sse4_2?  ( cpu_flags_x86_sse4_1 )
+	cpu_flags_x86_sse4_1?  ( cpu_flags_x86_ssse3 )
+	cpu_flags_x86_ssse3?  ( cpu_flags_x86_sse3 )
+	cpu_flags_x86_sse3?  ( cpu_flags_x86_sse2 )
+	cpu_flags_x86_sse2?  ( cpu_flags_x86_sse )
+	cpu_flags_x86_sse?  ( cpu_flags_x86_mmxext )
+	cpu_flags_x86_mmxext?  ( cpu_flags_x86_mmx )
+	cpu_flags_x86_3dnowext?  ( cpu_flags_x86_3dnow )
+	cpu_flags_x86_3dnow?  ( cpu_flags_x86_mmx )
+"
+
+CPU_FEATURES_MAP=(
+	${ARM_CPU_FEATURES[@]}
+	${X86_CPU_FEATURES[@]}
+)
+IUSE="${IUSE}
+	${CPU_FEATURES_MAP[@]%:*}"
+
+CPU_REQUIRED_USE="
+	${ARM_CPU_REQUIRED_USE}
+	${X86_CPU_REQUIRED_USE}
+"
+
+RDEPEND="
+	>=media-libs/opus-1.0.2-r2
+	vaapi? ( >=media-libs/libva-1.2.1-r1:0= )
+	nvenc? ( >=media-libs/nv-codec-headers-11.1.5.3 )
+	vdpau? ( >=x11-libs/libvdpau-0.7 )
+	vulkan? ( >=media-libs/vulkan-loader-1.3.277:= )
+"
+
+DEPEND="${RDEPEND}
+	vulkan? ( >=dev-util/vulkan-headers-1.3.277 )
+"
+BDEPEND="
+	>=dev-build/make-3.81
+	virtual/pkgconfig
+	cpu_flags_x86_mmx? ( || ( >=dev-lang/nasm-2.13 >=dev-lang/yasm-1.3 ) )
+"
+
+REQUIRED_USE="
+	vulkan? ( threads )
+	${CPU_REQUIRED_USE}"
+RESTRICT="
+	test
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-120.patch
+	"${FILESDIR}"/chromium.patch
+)
+
+src_prepare() {
+	export revision=git-N-g${COMMIT:0:10}
+	default
+
+	# -fdiagnostics-color=auto gets appended after user flags which
+	# will ignore user's preference.
+	sed -i -e '/check_cflags -fdiagnostics-color=auto/d' configure || die
+
+	echo 'include $(SRC_PATH)/ffbuild/libffmpeg.mak' >> Makefile || die
+}
+
+src_configure() {
+	local myconf=( )
+
+	# Bug #918997. Will probably be fixed upstream in the next release.
+	use vulkan && append-ldflags -Wl,-z,muldefs
+
+	local ffuse=( "${FFMPEG_FLAG_MAP[@]}" )
+
+	for i in "${ffuse[@]#+}" ; do
+		myconf+=( $(use_enable ${i%:*} ${i#*:}) )
+	done
+
+	# CPU features
+	for i in "${CPU_FEATURES_MAP[@]}" ; do
+		use ${i%:*} || myconf+=( --disable-${i#*:} )
+	done
+
+	# Try to get cpu type based on CFLAGS.
+	# Bug #172723
+	# We need to do this so that features of that CPU will be better used
+	# If they contain an unknown CPU it will not hurt since ffmpeg's configure
+	# will just ignore it.
+	for i in $(get-flag mcpu) $(get-flag march) ; do
+		[[ ${i} = native ]] && i="host" # bug #273421
+		myconf+=( --cpu=${i} )
+		break
+	done
+
+	# LTO support, bug #566282, bug #754654, bug #772854
+	if [[ ${ABI} != x86 ]] && tc-is-lto; then
+		# Respect -flto value, e.g -flto=thin
+		local v="$(get-flag flto)"
+		[[ -n ${v} ]] && myconf+=( "--enable-lto=${v}" ) || myconf+=( "--enable-lto" )
+	fi
+	filter-lto
+
+	# Mandatory configuration
+	myconf=(
+		--disable-stripping
+		# This is only for hardcoded cflags; those are used in configure checks that may
+		# interfere with proper detections, bug #671746 and bug #645778
+		# We use optflags, so that overrides them anyway.
+		--disable-optimizations
+		--disable-libcelt # bug #664158
+		"${myconf[@]}"
+	)
+
+	# cross compile support
+	if tc-is-cross-compiler ; then
+		myconf+=( --enable-cross-compile --arch=$(tc-arch-kernel) --cross-prefix=${CHOST}- --host-cc="$(tc-getBUILD_CC)" )
+		case ${CHOST} in
+			*mingw32*)
+				myconf+=( --target-os=mingw32 )
+				;;
+			*linux*)
+				myconf+=( --target-os=linux )
+				;;
+		esac
+	fi
+
+	# Use --extra-libs if needed for LIBS
+	set -- "${S}/configure" \
+		--prefix="${EPREFIX}/usr" \
+		--libdir="${EPREFIX}/usr/$(get_libdir)" \
+		--shlibdir="${EPREFIX}/usr/$(get_libdir)" \
+		--cc="$(tc-getCC)" \
+		--cxx="$(tc-getCXX)" \
+		--ar="$(tc-getAR)" \
+		--nm="$(tc-getNM)" \
+		--strip="$(tc-getSTRIP)" \
+		--ranlib="$(tc-getRANLIB)" \
+		--pkg-config="$(tc-getPKG_CONFIG)" \
+		--optflags="${CFLAGS}" \
+		--disable-all \
+		--disable-autodetect \
+		--disable-error-resilience \
+		--disable-everything \
+		--disable-faan \
+		--disable-iconv \
+		--disable-network \
+		--enable-avcodec \
+		--enable-avformat \
+		--enable-avutil \
+		--enable-libopus \
+		--enable-decoder=aac,flac,h264,libopus,mp3,pcm_alaw,pcm_f32le,pcm_mulaw,pcm_s16be,pcm_s16le,pcm_s24be,pcm_s24le,pcm_s32le,pcm_u8,theora,vorbis,vp8 \
+		--enable-demuxer=aac,flac,matroska,mov,mp3,ogg,wav \
+		--enable-parser=aac,flac,h264,mpegaudio,opus,vorbis,vp3,vp8,vp9 \
+		--enable-pic \
+		--enable-static \
+		"${myconf[@]}" \
+		${EXTRA_FFMPEG_CONF}
+
+	echo "${@}"
+	"${@}" || die
+}
+
+src_compile() {
+	emake V=1 libffmpeg
+}
+
+src_install() {
+	emake V=1 DESTDIR="${D}" install-libffmpeg
+}