[gentoo-commits] repo/gentoo:master commit in: media-libs/libvisio/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     cabe65079704a7c5fc5970dc6d16ef17b8d42d92
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Nov 14 05:39:27 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Nov 14 18:42:02 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cabe6507

media-libs/libvisio: add 0.1.8

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-libs/libvisio/Manifest              |  1 +
 media-libs/libvisio/libvisio-0.1.8.ebuild | 62 +++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+)

diff --git a/media-libs/libvisio/Manifest b/media-libs/libvisio/Manifest
index 2d0862335acd..9b59b3200a77 100644
--- a/media-libs/libvisio/Manifest
+++ b/media-libs/libvisio/Manifest
@@ -1 +1,2 @@
 DIST libvisio-0.1.7.tar.xz 854296 BLAKE2B db5dd96d769c237bc2926d52a43c2496adca50b74133ea3c81df7ba5a61824891623eb33b4801b463b27f5c03946ea7ffcf827b98c95139c9659b0a1b0f7b604 SHA512 c26f67a09fa6a6d0bf6f3fff5590d5cf16983630d4f7cfcf86d9461baec58dbdf7989fd934be6db0639ca043c160aac2d008275afb9e047766bc878ac579a9ea
+DIST libvisio-0.1.8.tar.xz 1686344 BLAKE2B 5e852e96c6484990349e3fb93dafb1bb3a23f9f72fefc13ceaf56677e3e4aaf01384fcae423cf9f022fb9a91800dc967a89b3eced40a96fe17c756241fb88ad8 SHA512 f89e7cd08287f769936cfacdbdd95fe97a535cca63231c14e2637a8ee6a5e86c6de79b3858c08a5ab483e17cf06107af4fac9014f695b25fedad15f841efba53

diff --git a/media-libs/libvisio/libvisio-0.1.8.ebuild b/media-libs/libvisio/libvisio-0.1.8.ebuild
new file mode 100644
index 000000000000..3b50dc5240e3
--- /dev/null
+++ b/media-libs/libvisio/libvisio-0.1.8.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libvisio.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://dev-www.libreoffice.org/src/libvisio/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+DESCRIPTION="Library parsing the file format of MS Visio documents"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libvisio"
+
+LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
+SLOT="0"
+IUSE="doc test tools"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/icu:=
+	dev-libs/librevenge
+	dev-libs/libxml2
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+	dev-util/gperf
+	dev-build/libtool
+	test? ( dev-util/cppunit )
+"
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig
+	doc? ( app-text/doxygen )
+"
+
+src_prepare() {
+	default
+	[[ -d m4 ]] || mkdir "m4" || die
+	[[ ${PV} == *9999* ]] && eautoreconf
+}
+
+src_configure() {
+	# bug 619688, 932496
+	append-cxxflags -std=c++17
+
+	local myeconfargs=(
+		$(use_with doc docs)
+		$(use_enable test tests)
+		$(use_enable tools)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}