[gentoo-commits] repo/gentoo:master commit in: dev-cpp/wangle/

[gentoo-commits] repo/gentoo:master commit in: dev-cpp/wangle/

[Sam James]

commit:     124c854ab1898b2bc3727610960fa4ccb6b5ba96
Author:     sin-ack <sin-ack <AT> protonmail <DOT> com>
AuthorDate: Sun Nov 10 19:58:31 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Mon Nov 11 22:24:17 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=124c854a

dev-cpp/wangle: new package, add 2024.11.04.00

Signed-off-by: sin-ack <sin-ack <AT> protonmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-cpp/wangle/Manifest                    |  1 +
 dev-cpp/wangle/metadata.xml                | 15 ++++++++
 dev-cpp/wangle/wangle-2024.11.04.00.ebuild | 62 ++++++++++++++++++++++++++++++
 3 files changed, 78 insertions(+)

diff --git a/dev-cpp/wangle/Manifest b/dev-cpp/wangle/Manifest
new file mode 100644
index 000000000000..aa9e398f55a5
--- /dev/null
+++ b/dev-cpp/wangle/Manifest
@@ -0,0 +1 @@
+DIST wangle-2024.11.04.00.gh.tar.gz 372838 BLAKE2B 5d6636aa9cbea7f1438269a8c935b93dd5e3c6abef0cc6c668088d883a9b9326f44409649d809c80c08e79c2fa0527fd26a4db7ceed616f27aea2a3921c5ae75 SHA512 d44f3553b04f378935c2a6cf072d6b4a911be3bb71f3480ccdbb269f83c0f62dce4451bcb2edb365d9b398f719c7162269690d07aab07054dafaa55b5b38e0ad

diff --git a/dev-cpp/wangle/metadata.xml b/dev-cpp/wangle/metadata.xml
new file mode 100644
index 000000000000..54af2041c101
--- /dev/null
+++ b/dev-cpp/wangle/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person" proxied="yes">
+		<email>sin-ack@protonmail.com</email>
+		<name>sin-ack</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">facebook/wangle</remote-id>
+	</upstream>
+</pkgmetadata>

diff --git a/dev-cpp/wangle/wangle-2024.11.04.00.ebuild b/dev-cpp/wangle/wangle-2024.11.04.00.ebuild
new file mode 100644
index 000000000000..15b6be4d72de
--- /dev/null
+++ b/dev-cpp/wangle/wangle-2024.11.04.00.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# These must be bumped together:
+# dev-cpp/edencommon
+# dev-cpp/fb303
+# dev-cpp/fbthrift
+# dev-cpp/fizz
+# dev-cpp/folly
+# dev-cpp/mvfst
+# dev-cpp/wangle
+# dev-util/watchman
+
+CMAKE_USE_DIR="${S}/wangle"
+
+inherit cmake
+
+DESCRIPTION="A framework providing common abstractions for building services"
+HOMEPAGE="https://github.com/facebook/wangle"
+SRC_URI="https://github.com/facebook/wangle/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	~dev-cpp/fizz-${PV}:=
+	~dev-cpp/folly-${PV}:=
+	dev-cpp/gflags:=
+	dev-cpp/glog:=[gflags]
+	dev-libs/libevent:=
+	dev-libs/libfmt:=
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-cpp/gtest )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_DIR="$(get_libdir)/cmake/${PN}"
+		-DLIB_INSTALL_DIR="$(get_libdir)"
+		-DBUILD_TESTS="$(usex test ON OFF)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	CMAKE_SKIP_TESTS=(
+		# These tests expect test certificates to be present in /usr/include/folly/io/async/test/certs/, which folly
+		# doesn't install.
+		SSLContextManagerTest
+	)
+
+	cmake_src_test
+}

[gentoo-commits] repo/gentoo:master commit in: dev-cpp/wangle/

[Sam James]

commit:     d02b4609c2e988640b11ab7fbd95cbef0650882a
Author:     sin-ack <sin-ack <AT> protonmail <DOT> com>
AuthorDate: Wed Nov 13 00:01:12 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Nov 23 14:00:58 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d02b4609

dev-cpp/wangle: skip a test on arm64

This test fails in the QEMU chroot.

Signed-off-by: sin-ack <sin-ack <AT> protonmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-cpp/wangle/wangle-2024.11.04.00.ebuild | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/dev-cpp/wangle/wangle-2024.11.04.00.ebuild b/dev-cpp/wangle/wangle-2024.11.04.00.ebuild
index 15b6be4d72de..fbe0818c12d4 100644
--- a/dev-cpp/wangle/wangle-2024.11.04.00.ebuild
+++ b/dev-cpp/wangle/wangle-2024.11.04.00.ebuild
@@ -58,5 +58,11 @@ src_test() {
 		SSLContextManagerTest
 	)
 
+	if use arm64; then
+		# This test fails on arm64.
+		# https://github.com/facebook/wangle/issues/241
+		CMAKE_SKIP_TESTS+=(TLSInMemoryTicketProcessorTest)
+	fi
+
 	cmake_src_test
 }

[gentoo-commits] repo/gentoo:master commit in: dev-cpp/wangle/

[Sam James]

commit:     62dbe5d073d762951e8455d1d4d39376ef1a81c0
Author:     sin-ack <sin-ack <AT> protonmail <DOT> com>
AuthorDate: Tue Nov 12 14:05:38 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Nov 23 20:15:36 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=62dbe5d0

dev-cpp/wangle: keyword 2024.11.04.00 for ~arm64

One test fails in the QEMU chroot.

Signed-off-by: sin-ack <sin-ack <AT> protonmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-cpp/wangle/wangle-2024.11.04.00.ebuild | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/dev-cpp/wangle/wangle-2024.11.04.00.ebuild b/dev-cpp/wangle/wangle-2024.11.04.00.ebuild
index fbe0818c12d4..33c0a4f2f1dc 100644
--- a/dev-cpp/wangle/wangle-2024.11.04.00.ebuild
+++ b/dev-cpp/wangle/wangle-2024.11.04.00.ebuild
@@ -23,7 +23,7 @@ SRC_URI="https://github.com/facebook/wangle/archive/refs/tags/v${PV}.tar.gz -> $
 
 LICENSE="Apache-2.0"
 SLOT="0/${PV}"
-KEYWORDS="~amd64"
+KEYWORDS="~amd64 ~arm64"
 IUSE="test"
 
 RESTRICT="!test? ( test )"