[gentoo-commits] repo/gentoo:master commit in: media-sound/terminatorx/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     c8bbdce9d1e6fb79cd1d16934237ad78181346b1
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 10 10:37:46 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Mon Nov 11 18:36:30 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c8bbdce9

media-sound/terminatorx: Add x11-libs/gtk+[X] USEdep, switch to libpulse

Closes: https://bugs.gentoo.org/889624
Bug: https://bugs.gentoo.org/636832
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../terminatorx/terminatorx-4.2.0-r1.ebuild        | 64 ++++++++++++++++++++++
 1 file changed, 64 insertions(+)

diff --git a/media-sound/terminatorx/terminatorx-4.2.0-r1.ebuild b/media-sound/terminatorx/terminatorx-4.2.0-r1.ebuild
new file mode 100644
index 000000000000..eabac007a9b5
--- /dev/null
+++ b/media-sound/terminatorx/terminatorx-4.2.0-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P=${P/terminatorx/terminatorX}
+inherit gnome2
+
+DESCRIPTION="Realtime audio synthesizer allowing you to 'scratch' on sampled audio data"
+HOMEPAGE="https://terminatorx.org/"
+# this is the original location but there is an issue with their certificate so mirroring the file
+#SRC_URI="https://terminatorx.org/dist/${MY_P}.tar.bz2"
+SRC_URI="https://dev.gentoo.org/~fordfrog/distfiles/${MY_P}.tar.bz2"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+# Making X optional fails when disabled: https://bugs.gentoo.org/636832
+IUSE="+alsa debug jack mad pulseaudio vorbis sox"
+
+REQUIRED_USE="|| ( alsa jack pulseaudio )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/libxml2:2
+	media-libs/audiofile:=
+	media-libs/ladspa-sdk
+	media-libs/liblrdf
+	media-plugins/cmt-plugins
+	x11-libs/gtk+:3[X]
+	x11-libs/libXi
+	x11-libs/libXxf86dga
+	alsa? ( media-libs/alsa-lib )
+	jack? ( virtual/jack )
+	mad? ( media-sound/madplay )
+	pulseaudio? ( media-libs/libpulse )
+	vorbis? ( media-libs/libvorbis )
+	sox? (
+		media-sound/sox
+		media-sound/mpg123
+	)
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-util/itstool
+	virtual/pkgconfig
+"
+
+PATCHES=( "${FILESDIR}/${P}-metadata-dir.patch" )
+
+src_configure() {
+	gnome2_src_configure \
+		--enable-x11 \
+		$(use_enable alsa) \
+		$(use_enable debug) \
+		$(use_enable jack) \
+		$(use_enable mad) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable vorbis) \
+		$(use_enable sox)
+}