[gentoo-commits] repo/gentoo:master commit in: dev-lang/ruby/

["Hans de Graaff" <graaff@gentoo.org>]

commit:     55d6134c8682d7919ce439aa3955454eae6c3806
Author:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
AuthorDate: Tue Nov  5 06:42:56 2024 +0000
Commit:     Hans de Graaff <graaff <AT> gentoo <DOT> org>
CommitDate: Tue Nov  5 06:42:56 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=55d6134c

dev-lang/ruby: drop 3.3.2, 3.3.4

Signed-off-by: Hans de Graaff <graaff <AT> gentoo.org>

 dev-lang/ruby/Manifest          |   1 -
 dev-lang/ruby/ruby-3.3.2.ebuild | 298 --------------------------------------
 dev-lang/ruby/ruby-3.3.4.ebuild | 306 ----------------------------------------
 3 files changed, 605 deletions(-)

diff --git a/dev-lang/ruby/Manifest b/dev-lang/ruby/Manifest
index 7eefba2bfaa3..45baea003130 100644
--- a/dev-lang/ruby/Manifest
+++ b/dev-lang/ruby/Manifest
@@ -5,7 +5,6 @@ DIST ruby-3.2.3.tar.xz 15163960 BLAKE2B e2cfa215b2cb910bac5f3b58edcdece91b21ffcf
 DIST ruby-3.2.4.tar.xz 15175656 BLAKE2B 9c2300a958b03528d51f0d74a069c8c538ca4009835d55377509a000bcfb43893a8a80d8fda57011e77c72e6283cb259281d5ba7b37444546e49f2a9ad515cf3 SHA512 fb0af37be4b6ad7b98ab9f8a508952238ee68b5828e3926331e4db52e2ebc1e6046f31114069322db0cd3bea7c9b82ace91c8564573ddcfa1f960877b237dbff
 DIST ruby-3.2.5.tar.xz 15189072 BLAKE2B a37c92a0f751e81dcae328b8944c4ecf10f6aee4f4468d6d08bb924c9808c8556c5febb71a825dd62dbcccf56385138e6e306bf3efae3589bdf0512d16d99d1a SHA512 092348b84b513aec62e63ec10b326370d0e3d1fa3126c59c03c84f28e2d7741a4772c461b077ec6a7dac3964a20f434655729e1acd50a3438755d7ad64073305
 DIST ruby-3.2.6.tar.xz 15126888 BLAKE2B d59352e5543b96abe3de5f10b578c2b910a0f18f848fb32a10b80f8e882e7c687a3149ce6ab6ba1271731b8668e1dd47754b778def13010a587aa8544e881943 SHA512 78f7fc76d47c772b9bc313cbcb57a2c0f1a975e09cfe46a3083f6f603d62b0031bd4c55896c8353c1c343974d45077e06e310111198d870883e06a0cf6fd03ce
-DIST ruby-3.3.2.tar.xz 16349500 BLAKE2B 2a474df10363555e8f0b9ad73bb854ad34f3d1485b8bdde833c999b20bc2c17282d2097d887d10f454bbd4dfdf08f04bb644a7e41d0b4a0ff0e9eb144339b5e8 SHA512 70dd8eb933956f894c52a8ede42e8ee74ff0e062bd8134a0bfb6bffc83a2848a658b62c8df5530b4dd64087b2d5373909c48917528facb1e6f4e99e79b6ad449
 DIST ruby-3.3.4.tar.xz 16366580 BLAKE2B e10b81ad7838e3d443ce0b12b8372faebb001f00a32dc0fa1f5e37c46baae99ea714e7f2a8741f0294255312030e844f32fc5d1c3695545cf8303e85b3255f21 SHA512 b26461a13ff82a08a282f10108028bb2a2e4a28da6182a291062fc54089c6655d79c22cc69d59156f9b11cb10a17fe8c69d489343fbae123a45f03361b95c9eb
 DIST ruby-3.3.5.tar.xz 16403660 BLAKE2B 4fa242ceeaf0dbf0d048b3f116f149f299c1a0ccca500a47929344da523cd3c49365381777e56546fe94003ee90ccc1f2cc957697eb82cd8beb7311b0b00287c SHA512 dd5c6a7f74854e143e0ca46b9d7c0d1983fc4886f5f733cd108345dbf4b21f61ad978ad6806e05a57b7af28fd9216dd38d7145808188bbb3695a7f3a4eda3883
 DIST ruby-3.3.6.tar.xz 16398228 BLAKE2B 7e2fb58ca1f5ee7ab9c2fd7b24fdbf9eef9805329cdf23c9926bac0268344f101475c2c7aacb26f73c4c5f73704727e19a9cc074c4587b9c53a115d6fb0a5e85 SHA512 c4b86188bf539fa737932e1ba5b746bc295e7c43b2f8cca2668eb7c88aa7228e2ce9032bbcd244a7d558a11bc842445b5fbeac3503ca7d223b63c53e08dba4ab

diff --git a/dev-lang/ruby/ruby-3.3.2.ebuild b/dev-lang/ruby/ruby-3.3.2.ebuild
deleted file mode 100644
index 5c94ac824b14..000000000000
--- a/dev-lang/ruby/ruby-3.3.2.ebuild
+++ /dev/null
@@ -1,298 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools flag-o-matic multiprocessing
-
-MY_P="${PN}-$(ver_cut 1-3)"
-S=${WORKDIR}/${MY_P}
-
-SLOT=$(ver_cut 1-2)
-MY_SUFFIX=$(ver_rs 1 '' ${SLOT})
-RUBYVERSION=${SLOT}.0
-
-DESCRIPTION="An object-oriented scripting language"
-HOMEPAGE="https://www.ruby-lang.org/"
-SRC_URI="https://cache.ruby-lang.org/pub/ruby/${SLOT}/${MY_P}.tar.xz"
-
-LICENSE="|| ( Ruby-BSD BSD-2 )"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
-IUSE="berkdb debug doc examples gdbm jemalloc jit socks5 +ssl static-libs systemtap tk valgrind xemacs"
-
-RDEPEND="
-	berkdb? ( sys-libs/db:= )
-	gdbm? ( sys-libs/gdbm:= )
-	jemalloc? ( dev-libs/jemalloc:= )
-	jit? ( >=virtual/rust-1.58.1 )
-	ssl? (
-		dev-libs/openssl:0=
-	)
-	socks5? ( >=net-proxy/dante-1.1.13 )
-	systemtap? ( dev-debug/systemtap )
-	tk? (
-		dev-lang/tcl:0=[threads]
-		dev-lang/tk:0=[threads]
-	)
-	dev-libs/libyaml
-	dev-libs/libffi:=
-	sys-libs/zlib
-	virtual/libcrypt:=
-	>=app-eselect/eselect-ruby-20231226
-"
-
-DEPEND="
-	${RDEPEND}
-	valgrind? ( dev-debug/valgrind )
-"
-
-BUNDLED_GEMS="
-	>=dev-ruby/debug-1.9.1[ruby_targets_ruby33(-)]
-	>=dev-ruby/irb-1.11.0[ruby_targets_ruby33(-)]
-	>=dev-ruby/matrix-0.4.2[ruby_targets_ruby33(-)]
-	>=dev-ruby/minitest-5.20.0[ruby_targets_ruby33(-)]
-	>=dev-ruby/net-ftp-0.3.3[ruby_targets_ruby33(-)]
-	>=dev-ruby/net-imap-0.4.9[ruby_targets_ruby33(-)]
-	>=dev-ruby/net-pop-0.1.2[ruby_targets_ruby33(-)]
-	>=dev-ruby/net-smtp-0.4.0[ruby_targets_ruby33(-)]
-	>=dev-ruby/power_assert-2.0.3[ruby_targets_ruby33(-)]
-	>=dev-ruby/prime-0.1.2[ruby_targets_ruby33(-)]
-	>=dev-ruby/racc-1.7.3[ruby_targets_ruby33(-)]
-	>=dev-ruby/rake-13.1.0[ruby_targets_ruby33(-)]
-	>=dev-ruby/rbs-3.4.0[ruby_targets_ruby33(-)]
-	>=dev-ruby/rexml-3.2.6[ruby_targets_ruby33(-)]
-	>=dev-ruby/rss-0.3.0[ruby_targets_ruby33(-)]
-	>=dev-ruby/test-unit-3.6.1[ruby_targets_ruby33(-)]
-	>=dev-ruby/typeprof-0.21.9[ruby_targets_ruby33(-)]
-"
-
-PDEPEND="
-	${BUNDLED_GEMS}
-	virtual/rubygems[ruby_targets_ruby33(-)]
-	>=dev-ruby/bundler-2.5.3[ruby_targets_ruby33(-)]
-	>=dev-ruby/did_you_mean-1.6.3[ruby_targets_ruby33(-)]
-	>=dev-ruby/json-2.7.1[ruby_targets_ruby33(-)]
-	>=dev-ruby/rdoc-6.6.2[ruby_targets_ruby33(-)]
-	xemacs? ( app-xemacs/ruby-modes )
-"
-
-src_prepare() {
-	eapply "${FILESDIR}"/"${SLOT}"/010*.patch
-	eapply "${FILESDIR}"/"${SLOT}"/902*.patch
-
-	if use elibc_musl ; then
-		eapply "${FILESDIR}"/${SLOT}/901-musl-*.patch
-	fi
-
-	einfo "Unbundling gems..."
-	cd "$S"
-	# Remove bundled gems that we will install via PDEPEND, bug
-	# 539700.
-	rm -fr gems/* || die
-	touch gems/bundled_gems || die
-
-	# Avoid the irb default gemspec since we will install the normal gem
-	# instead. This avoids a file collision with dev-ruby/irb.
-	rm lib/irb/irb.gemspec || die
-
-	# Remove tests that are known to fail or require a network connection
-	rm -f test/ruby/test_process.rb test/rubygems/test_gem{,_path_support}.rb || die
-	rm -f test/rinda/test_rinda.rb test/socket/test_tcp.rb test/fiber/test_address_resolve.rb \
-	   spec/ruby/library/socket/tcpsocket/{initialize,open}_spec.rb|| die
-
-	# Remove webrick tests because setting LD_LIBRARY_PATH does not work for them.
-	rm -rf tool/test/webrick || die
-
-	# Avoid test using the system ruby
-	sed -i -e '/test_dumb_terminal/aomit "Uses system ruby"' test/reline/test_reline.rb || die
-
-	# Avoid testing against hard-coded blockdev devices that most likely are not available
-	sed -i -e '/def blockdev/a@blockdev = nil' test/ruby/test_file_exhaustive.rb || die
-
-	# Avoid tests that require gem downloads
-	sed -e '/^\(test-syntax-suggest\|PREPARE_SYNTAX_SUGGEST\)/ s/\$(TEST_RUNNABLE)/no/' \
-		-i common.mk
-
-	# Avoid test that fails intermittently
-	sed -e '/test_gem_exec_gem_uninstall/aomit "Fails intermittently"' \
-		-i test/rubygems/test_gem_commands_exec_command.rb || die
-
-	if use prefix ; then
-		# Fix hardcoded SHELL var in mkmf library
-		sed -i -e "s#\(SHELL = \).*#\1${EPREFIX}/bin/sh#" lib/mkmf.rb || die
-
-		if [[ ${CHOST} == *darwin* ]] ; then
-			# avoid symlink loop on Darwin (?!)
-			sed -i \
-				-e '/LIBRUBY_ALIASES=/s/lib$(RUBY_INSTALL_NAME).$(SOEXT)//' \
-				configure.ac || die
-
-			# make ar/libtool hack for Darwin work
-			sed -i \
-				-e "s/ac_cv_prog_ac_ct_AR='libtool/ac_cv_prog_AR='${CHOST}-libtool/" \
-				configure.ac || die
-
-			# disable using security framework (GCC barfs on those headers)
-			sed -i \
-				-e 's/MAC_OS_X_VERSION_MIN_REQUIRED/_DISABLED_/' \
-				random.c || die
-		fi
-	fi
-
-	eapply_user
-
-	eautoreconf
-}
-
-src_configure() {
-	local modules="win32,win32ole" myconf=
-
-	# Ruby's build system does interesting things with MAKEOPTS and doesn't
-	# handle MAKEOPTS="-Oline" or similar well. Just filter it all out
-	# and use -j/-l parsed out from the original MAKEOPTS, then use that.
-	# Newer Portage sets this option by default in GNUMAKEFLAGS if nothing
-	# is set by the user in MAKEOPTS. See bug #900929 and bug #728424.
-	local makeopts_tmp="-j$(makeopts_jobs) -l$(makeopts_loadavg)"
-	unset MAKEOPTS MAKEFLAGS GNUMAKEFLAGS
-	export MAKEOPTS="${makeopts_tmp}"
-
-	# -fomit-frame-pointer makes ruby segfault, see bug #150413.
-	filter-flags -fomit-frame-pointer
-	# In many places aliasing rules are broken; play it safe
-	# as it's risky with newer compilers to leave it as it is.
-	append-flags -fno-strict-aliasing
-
-	# Workaround for bug #938302
-	if use systemtap && has_version "dev-debug/systemtap[-dtrace-symlink(+)]" ; then
-		export DTRACE="${BROOT}"/usr/bin/stap-dtrace
-	fi
-
-	# Socks support via dante
-	if use socks5 ; then
-		# Socks support can't be disabled as long as SOCKS_SERVER is
-		# set and socks library is present, so need to unset
-		# SOCKS_SERVER in that case.
-		unset SOCKS_SERVER
-	fi
-
-	# Increase GC_MALLOC_LIMIT if set (default is 8000000)
-	if [ -n "${RUBY_GC_MALLOC_LIMIT}" ] ; then
-		append-flags "-DGC_MALLOC_LIMIT=${RUBY_GC_MALLOC_LIMIT}"
-	fi
-
-	# Determine which modules *not* to build depending in the USE flags.
-	if ! use berkdb ; then
-		modules="${modules},dbm"
-	fi
-	if ! use gdbm ; then
-		modules="${modules},gdbm"
-	fi
-	if ! use ssl ; then
-		modules="${modules},openssl"
-	fi
-	if ! use tk ; then
-		modules="${modules},tk"
-	fi
-
-	# Provide an empty LIBPATHENV because we disable rpath but we do not
-	# need LD_LIBRARY_PATH by default since that breaks USE=multitarget
-	# #564272
-	INSTALL="${EPREFIX}/usr/bin/install -c" LIBPATHENV="" econf \
-		--program-suffix=${MY_SUFFIX} \
-		--with-soname=ruby${MY_SUFFIX} \
-		--enable-shared \
-		--enable-pthread \
-		--disable-rpath \
-		--without-baseruby \
-		--with-compress-debug-sections=no \
-		--enable-mkmf-verbose \
-		--with-out-ext="${modules}" \
-		$(use_with jemalloc jemalloc) \
-		$(use_enable jit jit-support) \
-		$(use_enable jit yjit) \
-		$(use_enable socks5 socks) \
-		$(use_enable systemtap dtrace) \
-		$(use_enable doc install-doc) \
-		$(use_enable static-libs static) \
-		$(use_enable static-libs install-static-library) \
-		$(use_with static-libs static-linked-ext) \
-		$(use_enable debug) \
-		${myconf} \
-		$(use_with valgrind) \
-		--enable-option-checking=no
-
-	# Makefile is broken because it lacks -ldl
-	rm -rf ext/-test-/popen_deadlock || die
-}
-
-src_compile() {
-	local -x LD_LIBRARY_PATH="${S}${LD_LIBRARY_PATH+:}${LD_LIBRARY_PATH}"
-	emake V=1 EXTLDFLAGS="${LDFLAGS}" MJIT_CFLAGS="${CFLAGS}" MJIT_OPTFLAGS="" MJIT_DEBUGFLAGS=""
-}
-
-src_test() {
-	local -x LD_LIBRARY_PATH="${S}${LD_LIBRARY_PATH+:}${LD_LIBRARY_PATH}"
-	emake V=1 check
-}
-
-src_install() {
-	# Remove the remaining bundled gems. We do this late in the process
-	# since they are used during the build to e.g. create the
-	# documentation.
-	einfo "Removing default gems before installation"
-	rm -rf lib/bundler* lib/rdoc/rdoc.gemspec || die
-
-	# Ruby is involved in the install process, we don't want interference here.
-	unset RUBYOPT
-
-	local MINIRUBY=$(echo -e 'include Makefile\ngetminiruby:\n\t@echo $(MINIRUBY)'|make -f - getminiruby)
-
-	local -x LD_LIBRARY_PATH="${S}:${ED}/usr/$(get_libdir)${LD_LIBRARY_PATH+:}${LD_LIBRARY_PATH}"
-
-	if [[ ${CHOST} == *darwin* ]] ; then
-		local -x DYLD_LIBRARY_PATH="${S}:${ED}/usr/$(get_libdir)${DYLD_LIBRARY_PATH+:}${DYLD_LIBRARY_PATH}"
-	fi
-
-	local -x RUBYLIB="${S}:${ED}/usr/$(get_libdir)/ruby/${RUBYVERSION}"
-	for d in $(find "${S}/ext" -type d) ; do
-		RUBYLIB="${RUBYLIB}:$d"
-	done
-
-	# Create directory for the default gems
-	local gem_home="${EPREFIX}/usr/$(get_libdir)/ruby/gems/${RUBYVERSION}"
-	mkdir -p "${D}/${gem_home}" || die "mkdir gem home failed"
-
-	emake V=1 DESTDIR="${D}" GEM_DESTDIR=${gem_home} install
-
-	# Remove installed rubygems and rdoc copy
-	rm -rf "${ED}/usr/$(get_libdir)/ruby/${RUBYVERSION}/rubygems" || die "rm rubygems failed"
-	rm -rf "${ED}/usr/bin/"gem"${MY_SUFFIX}" || die "rm rdoc bins failed"
-	rm -rf "${ED}/usr/$(get_libdir)/ruby/${RUBYVERSION}"/rdoc* || die "rm rdoc failed"
-	rm -rf "${ED}/usr/bin/"{bundle,bundler,ri,rdoc}"${MY_SUFFIX}" || die "rm rdoc bins failed"
-
-	if use doc; then
-		emake DESTDIR="${D}" GEM_DESTDIR=${gem_home} install-doc
-	fi
-
-	if use examples; then
-		dodoc -r sample
-	fi
-
-	dodoc ChangeLog NEWS.md README*
-	dodoc -r doc
-}
-
-pkg_postinst() {
-	if [[ ! -n $(readlink "${EROOT}"/usr/bin/ruby) ]] ; then
-		eselect ruby set ruby${MY_SUFFIX}
-	fi
-
-	elog
-	elog "To switch between available Ruby profiles, execute as root:"
-	elog "\teselect ruby set ruby(30|31|...)"
-	elog
-}
-
-pkg_postrm() {
-	eselect ruby cleanup
-}

diff --git a/dev-lang/ruby/ruby-3.3.4.ebuild b/dev-lang/ruby/ruby-3.3.4.ebuild
deleted file mode 100644
index fac732e48cf1..000000000000
--- a/dev-lang/ruby/ruby-3.3.4.ebuild
+++ /dev/null
@@ -1,306 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools flag-o-matic multiprocessing
-
-DESCRIPTION="An object-oriented scripting language"
-HOMEPAGE="https://www.ruby-lang.org/"
-
-MY_P="${PN}-$(ver_cut 1-3)"
-S=${WORKDIR}/${MY_P}
-
-SLOT=$(ver_cut 1-2)
-MY_SUFFIX=$(ver_rs 1 '' ${SLOT})
-RUBYVERSION=${SLOT}.0
-
-SRC_URI="https://cache.ruby-lang.org/pub/ruby/${SLOT}/${MY_P}.tar.xz"
-
-LICENSE="|| ( Ruby-BSD BSD-2 )"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
-IUSE="berkdb debug doc examples gdbm jemalloc jit socks5 +ssl static-libs systemtap tk valgrind xemacs"
-
-RDEPEND="
-	berkdb? ( sys-libs/db:= )
-	gdbm? ( sys-libs/gdbm:= )
-	jemalloc? ( dev-libs/jemalloc:= )
-	jit? ( >=virtual/rust-1.58.1 )
-	ssl? (
-		dev-libs/openssl:0=
-	)
-	socks5? ( >=net-proxy/dante-1.1.13 )
-	systemtap? ( dev-debug/systemtap )
-	tk? (
-		dev-lang/tcl:0=[threads]
-		dev-lang/tk:0=[threads]
-	)
-	dev-libs/libyaml
-	dev-libs/libffi:=
-	sys-libs/zlib
-	virtual/libcrypt:=
-	>=app-eselect/eselect-ruby-20231226
-"
-
-DEPEND="
-	${RDEPEND}
-	valgrind? ( dev-debug/valgrind )
-"
-
-BUNDLED_GEMS="
-	>=dev-ruby/debug-1.9.1[ruby_targets_ruby33(-)]
-	>=dev-ruby/irb-1.11.0[ruby_targets_ruby33(-)]
-	>=dev-ruby/matrix-0.4.2[ruby_targets_ruby33(-)]
-	>=dev-ruby/minitest-5.20.0[ruby_targets_ruby33(-)]
-	>=dev-ruby/net-ftp-0.3.3[ruby_targets_ruby33(-)]
-	>=dev-ruby/net-imap-0.4.9[ruby_targets_ruby33(-)]
-	>=dev-ruby/net-pop-0.1.2[ruby_targets_ruby33(-)]
-	>=dev-ruby/net-smtp-0.4.0[ruby_targets_ruby33(-)]
-	>=dev-ruby/power_assert-2.0.3[ruby_targets_ruby33(-)]
-	>=dev-ruby/prime-0.1.2[ruby_targets_ruby33(-)]
-	>=dev-ruby/racc-1.7.3[ruby_targets_ruby33(-)]
-	>=dev-ruby/rake-13.1.0[ruby_targets_ruby33(-)]
-	>=dev-ruby/rbs-3.4.0[ruby_targets_ruby33(-)]
-	>=dev-ruby/rexml-3.2.8[ruby_targets_ruby33(-)]
-	>=dev-ruby/rss-0.3.0[ruby_targets_ruby33(-)]
-	>=dev-ruby/test-unit-3.6.1[ruby_targets_ruby33(-)]
-	>=dev-ruby/typeprof-0.21.9[ruby_targets_ruby33(-)]
-"
-
-PDEPEND="
-	${BUNDLED_GEMS}
-	virtual/rubygems[ruby_targets_ruby33(-)]
-	>=dev-ruby/bundler-2.5.11[ruby_targets_ruby33(-)]
-	>=dev-ruby/did_you_mean-1.6.3[ruby_targets_ruby33(-)]
-	>=dev-ruby/json-2.7.1[ruby_targets_ruby33(-)]
-	>=dev-ruby/rdoc-6.6.2[ruby_targets_ruby33(-)]
-	xemacs? ( app-xemacs/ruby-modes )
-"
-
-src_prepare() {
-	eapply "${FILESDIR}"/"${SLOT}"/010*.patch
-	eapply "${FILESDIR}"/"${SLOT}"/902*.patch
-
-	if use elibc_musl ; then
-		eapply "${FILESDIR}"/${SLOT}/901-musl-*.patch
-	fi
-
-	einfo "Unbundling gems..."
-	cd "$S"
-	# Remove bundled gems that we will install via PDEPEND, bug
-	# 539700.
-	rm -fr gems/* || die
-	touch gems/bundled_gems || die
-
-	# Avoid the irb default gemspec since we will install the normal gem
-	# instead. This avoids a file collision with dev-ruby/irb.
-	rm lib/irb/irb.gemspec || die
-
-	# Remove tests that are known to fail or require a network connection
-	rm -f test/ruby/test_process.rb test/rubygems/test_gem{,_path_support}.rb || die
-	rm -f test/rinda/test_rinda.rb test/socket/test_tcp.rb test/fiber/test_address_resolve.rb \
-	   spec/ruby/library/socket/tcpsocket/{initialize,open}_spec.rb|| die
-
-	# Remove webrick tests because setting LD_LIBRARY_PATH does not work for them.
-	rm -rf tool/test/webrick || die
-
-	# Avoid test using the system ruby
-	sed -i -e '/test_dumb_terminal/aomit "Uses system ruby"' test/reline/test_reline.rb || die
-
-	# Avoid testing against hard-coded blockdev devices that most likely are not available
-	sed -i -e '/def blockdev/a@blockdev = nil' test/ruby/test_file_exhaustive.rb || die
-
-	# Avoid tests that require gem downloads
-	sed -e '/^\(test-syntax-suggest\|PREPARE_SYNTAX_SUGGEST\)/ s/\$(TEST_RUNNABLE)/no/' \
-		-i common.mk
-
-	# Avoid test that fails intermittently
-	sed -e '/test_gem_exec_gem_uninstall/aomit "Fails intermittently"' \
-		-i test/rubygems/test_gem_commands_exec_command.rb || die
-
-	if use prefix ; then
-		# Fix hardcoded SHELL var in mkmf library
-		sed -i -e "s#\(SHELL = \).*#\1${EPREFIX}/bin/sh#" lib/mkmf.rb || die
-
-		if [[ ${CHOST} == *darwin* ]] ; then
-			# avoid symlink loop on Darwin (?!)
-			sed -i \
-				-e '/LIBRUBY_ALIASES=/s/lib$(RUBY_INSTALL_NAME).$(SOEXT)//' \
-				configure.ac || die
-
-			# make ar/libtool hack for Darwin work
-			sed -i \
-				-e "s/ac_cv_prog_ac_ct_AR='libtool/ac_cv_prog_AR='${CHOST}-libtool/" \
-				configure.ac || die
-
-			# disable using security framework (GCC barfs on those headers)
-			sed -i \
-				-e 's/MAC_OS_X_VERSION_MIN_REQUIRED/_DISABLED_/' \
-				random.c || die
-		fi
-	fi
-
-	eapply_user
-
-	eautoreconf
-}
-
-src_configure() {
-	local modules="win32,win32ole" myconf=
-
-	# Ruby's build system does interesting things with MAKEOPTS and doesn't
-	# handle MAKEOPTS="-Oline" or similar well. Just filter it all out
-	# and use -j/-l parsed out from the original MAKEOPTS, then use that.
-	# Newer Portage sets this option by default in GNUMAKEFLAGS if nothing
-	# is set by the user in MAKEOPTS. See bug #900929 and bug #728424.
-	local makeopts_tmp="-j$(makeopts_jobs) -l$(makeopts_loadavg)"
-	unset MAKEOPTS MAKEFLAGS GNUMAKEFLAGS
-	export MAKEOPTS="${makeopts_tmp}"
-
-	# Avoid a hardcoded path to mkdir to avoid issues with mixed
-	# usr-merge and normal binary packages, bug #932386.
-	export ac_cv_path_mkdir=mkdir
-
-	# -fomit-frame-pointer makes ruby segfault, see bug #150413.
-	filter-flags -fomit-frame-pointer
-	# In many places aliasing rules are broken; play it safe
-	# as it's risky with newer compilers to leave it as it is.
-	append-flags -fno-strict-aliasing
-
-	# Workaround for bug #938302
-	if use systemtap && has_version "dev-debug/systemtap[-dtrace-symlink(+)]" ; then
-		export DTRACE="${BROOT}"/usr/bin/stap-dtrace
-	fi
-
-	# Socks support via dante
-	if use socks5 ; then
-		# Socks support can't be disabled as long as SOCKS_SERVER is
-		# set and socks library is present, so need to unset
-		# SOCKS_SERVER in that case.
-		unset SOCKS_SERVER
-	fi
-
-	# Increase GC_MALLOC_LIMIT if set (default is 8000000)
-	if [ -n "${RUBY_GC_MALLOC_LIMIT}" ] ; then
-		append-flags "-DGC_MALLOC_LIMIT=${RUBY_GC_MALLOC_LIMIT}"
-	fi
-
-	# Determine which modules *not* to build depending in the USE flags.
-	if ! use berkdb ; then
-		modules="${modules},dbm"
-	fi
-	if ! use gdbm ; then
-		modules="${modules},gdbm"
-	fi
-	if ! use ssl ; then
-		modules="${modules},openssl"
-	fi
-	if ! use tk ; then
-		modules="${modules},tk"
-	fi
-
-	# Fix co-routine selection for x32, bug 933070
-	[[ ${CHOST} == *gnux32 ]] && myconf="${myconf} --with-coroutine=amd64"
-
-	# Provide an empty LIBPATHENV because we disable rpath but we do not
-	# need LD_LIBRARY_PATH by default since that breaks USE=multitarget
-	# #564272
-	INSTALL="${EPREFIX}/usr/bin/install -c" LIBPATHENV="" econf \
-		--program-suffix=${MY_SUFFIX} \
-		--with-soname=ruby${MY_SUFFIX} \
-		--enable-shared \
-		--enable-pthread \
-		--disable-rpath \
-		--without-baseruby \
-		--with-compress-debug-sections=no \
-		--enable-mkmf-verbose \
-		--with-out-ext="${modules}" \
-		$(use_with jemalloc jemalloc) \
-		$(use_enable jit jit-support) \
-		$(use_enable jit yjit) \
-		$(use_enable socks5 socks) \
-		$(use_enable systemtap dtrace) \
-		$(use_enable doc install-doc) \
-		$(use_enable static-libs static) \
-		$(use_enable static-libs install-static-library) \
-		$(use_with static-libs static-linked-ext) \
-		$(use_enable debug) \
-		${myconf} \
-		$(use_with valgrind) \
-		--enable-option-checking=no
-
-	# Makefile is broken because it lacks -ldl
-	rm -rf ext/-test-/popen_deadlock || die
-}
-
-src_compile() {
-	local -x LD_LIBRARY_PATH="${S}${LD_LIBRARY_PATH+:}${LD_LIBRARY_PATH}"
-	emake V=1 EXTLDFLAGS="${LDFLAGS}" MJIT_CFLAGS="${CFLAGS}" MJIT_OPTFLAGS="" MJIT_DEBUGFLAGS=""
-}
-
-src_test() {
-	local -x LD_LIBRARY_PATH="${S}${LD_LIBRARY_PATH+:}${LD_LIBRARY_PATH}"
-	emake V=1 check
-}
-
-src_install() {
-	# Remove the remaining bundled gems. We do this late in the process
-	# since they are used during the build to e.g. create the
-	# documentation.
-	einfo "Removing default gems before installation"
-	rm -rf lib/bundler* lib/rdoc/rdoc.gemspec || die
-
-	# Ruby is involved in the install process, we don't want interference here.
-	unset RUBYOPT
-
-	local MINIRUBY=$(echo -e 'include Makefile\ngetminiruby:\n\t@echo $(MINIRUBY)'|make -f - getminiruby)
-
-	local -x LD_LIBRARY_PATH="${S}:${ED}/usr/$(get_libdir)${LD_LIBRARY_PATH+:}${LD_LIBRARY_PATH}"
-
-	if [[ ${CHOST} == *darwin* ]] ; then
-		local -x DYLD_LIBRARY_PATH="${S}:${ED}/usr/$(get_libdir)${DYLD_LIBRARY_PATH+:}${DYLD_LIBRARY_PATH}"
-	fi
-
-	local -x RUBYLIB="${S}:${ED}/usr/$(get_libdir)/ruby/${RUBYVERSION}"
-	for d in $(find "${S}/ext" -type d) ; do
-		RUBYLIB="${RUBYLIB}:$d"
-	done
-
-	# Create directory for the default gems
-	local gem_home="${EPREFIX}/usr/$(get_libdir)/ruby/gems/${RUBYVERSION}"
-	mkdir -p "${D}/${gem_home}" || die "mkdir gem home failed"
-
-	emake V=1 DESTDIR="${D}" GEM_DESTDIR=${gem_home} install
-
-	# Remove installed rubygems and rdoc copy
-	rm -rf "${ED}/usr/$(get_libdir)/ruby/${RUBYVERSION}/rubygems" || die "rm rubygems failed"
-	rm -rf "${ED}/usr/bin/"gem"${MY_SUFFIX}" || die "rm rdoc bins failed"
-	rm -rf "${ED}/usr/$(get_libdir)/ruby/${RUBYVERSION}"/rdoc* || die "rm rdoc failed"
-	rm -rf "${ED}/usr/bin/"{bundle,bundler,ri,rdoc}"${MY_SUFFIX}" || die "rm rdoc bins failed"
-
-	if use doc; then
-		emake DESTDIR="${D}" GEM_DESTDIR=${gem_home} install-doc
-	fi
-
-	if use examples; then
-		dodoc -r sample
-	fi
-
-	dodoc ChangeLog NEWS.md README*
-	dodoc -r doc
-}
-
-pkg_postinst() {
-	if [[ ! -n $(readlink "${EROOT}"/usr/bin/ruby) ]] ; then
-		eselect ruby set ruby${MY_SUFFIX}
-	fi
-
-	elog
-	elog "To switch between available Ruby profiles, execute as root:"
-	elog "\teselect ruby set ruby(30|31|...)"
-	elog
-}
-
-pkg_postrm() {
-	eselect ruby cleanup
-}