[gentoo-commits] repo/gentoo:master commit in: dev-python/numpy/

["Michał Górny" <mgorny@gentoo.org>]

commit:     fdedfb19e12c8bade5daee6bf4c4ac94d79eb122
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Thu Oct 31 18:21:31 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Thu Oct 31 19:19:28 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fdedfb19

dev-python/numpy: Remove old

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/numpy/Manifest           |   1 -
 dev-python/numpy/numpy-2.1.1.ebuild | 149 ------------------------------------
 2 files changed, 150 deletions(-)

diff --git a/dev-python/numpy/Manifest b/dev-python/numpy/Manifest
index 8530ac7ab169..1d1702edc9ee 100644
--- a/dev-python/numpy/Manifest
+++ b/dev-python/numpy/Manifest
@@ -1,5 +1,4 @@
 DIST numpy-1.26.4.tar.gz 15786129 BLAKE2B ee759d3a857111bc494d5e989a7b005375d942b2a89cda69be4a3bd7c6cb195003fd2a8a0535f1858d8977ff688b0ec36360dcba9c3160206eedce5e28f191ef SHA512 f7121ab4099fa0686f9c095d456baa4a5869d651d7b7a06385f885f329cf08f11024b5df5e7b4ee705970062a8102ec4f709512eabbfd5c9fccce4ef83b9c208
 DIST numpy-2.0.0.tar.gz 18326228 BLAKE2B e3d1084b79e0e55cd9087bb34dc116e6c9d6ab14a416a07f727b9f5d5a9db236ecf74a53b7e758d078781c5e565e5557912962f2ddbfff7251ec5b231fabe01d SHA512 cd5612ce2db4be87afa8479c508c256c9ff7f1b15a6b010eb06ba962759cc26552b512ec82711680bab1ebedeb06dfc8d7bff9cec63c94efacaadd719448b287
 DIST numpy-2.0.2.tar.gz 18902015 BLAKE2B 63f993e3429bff1dac1ff79fad23a36a2493fd2c8a825ef96b6b87d82b0e68393d2829c5ecd9065df345c8bfbb1f8f385077f154264f7d2810d311d1d6672bd7 SHA512 d769fd4f07e082fae1661c6856d6d726e189f6931f3028c6819f9806aa9dfd15ab2b49c48b94bfd925eb3f74fddb6f044c9ba93bbb785b5476440dd1cf0b4999
-DIST numpy-2.1.1.tar.gz 18874860 BLAKE2B c828f2106e32429831aa8c64b3b94dfda1b097bcb7f3475b33306bed0b03c2aeb0af4e43ea47c6b3d5e6387b37e3f9ecdf6ae2a3fd4f526da5d121931b9521f1 SHA512 94843f88a32cc1df3e572ac13f294e49201a1f50fbd28707a500839cdff61958823c5b8748a7a54cd866a1acc9bd11efde53042141a81cca44393ee7cee78cdc
 DIST numpy-2.1.2.tar.gz 18878063 BLAKE2B b976b72bb113fc9c5e5a17c9d89038b6a11f2a09521ef46a610dd1fd04b0b11f08491728b2397ca5e3e9613aab3ad8c63b2b15a6378c535cf0e735226d517617 SHA512 3d69f6583e093e8fd0f441ec7dc4658c88fb714bb29574cd9510091ba059553f79c52492037353caf50b6cff1f7bd1e2501e445c7adde41bd9e08bab363e06e9

diff --git a/dev-python/numpy/numpy-2.1.1.ebuild b/dev-python/numpy/numpy-2.1.1.ebuild
deleted file mode 100644
index c65ca99ea528..000000000000
--- a/dev-python/numpy/numpy-2.1.1.ebuild
+++ /dev/null
@@ -1,149 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=meson-python
-PYTHON_COMPAT=( python3_{10..13} pypy3 )
-PYTHON_REQ_USE="threads(+)"
-FORTRAN_NEEDED=lapack
-
-inherit distutils-r1 flag-o-matic fortran-2 pypi
-
-DESCRIPTION="Fast array and numerical python library"
-HOMEPAGE="
-	https://numpy.org/
-	https://github.com/numpy/numpy/
-	https://pypi.org/project/numpy/
-"
-
-LICENSE="BSD"
-SLOT="0/2"
-KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
-# +lapack because the internal fallbacks are pretty slow. Building without blas
-# is barely supported anyway, see bug #914358.
-IUSE="+lapack"
-
-RDEPEND="
-	lapack? (
-		>=virtual/cblas-3.8
-		>=virtual/lapack-3.8
-	)
-"
-BDEPEND="
-	${RDEPEND}
-	>=dev-build/meson-1.1.0
-	>=dev-python/cython-3.0.6[${PYTHON_USEDEP}]
-	lapack? (
-		virtual/pkgconfig
-	)
-	test? (
-		$(python_gen_cond_dep '
-			>=dev-python/cffi-1.14.0[${PYTHON_USEDEP}]
-		' 'python*')
-		dev-python/charset-normalizer[${PYTHON_USEDEP}]
-		>=dev-python/hypothesis-5.8.0[${PYTHON_USEDEP}]
-		>=dev-python/pytz-2019.3[${PYTHON_USEDEP}]
-	)
-"
-
-QA_CONFIG_IMPL_DECL_SKIP=(
-	# https://bugs.gentoo.org/925367
-	vrndq_f32
-)
-
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	# bug #922457
-	filter-lto
-	# https://github.com/numpy/numpy/issues/25004
-	append-flags -fno-strict-aliasing
-
-	distutils-r1_python_prepare_all
-}
-
-python_configure_all() {
-	DISTUTILS_ARGS=(
-		-Dallow-noblas=$(usex !lapack true false)
-		-Dblas=$(usev lapack cblas)
-		-Dlapack=$(usev lapack lapack)
-		# TODO: cpu-* options
-	)
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# Very disk-and-memory-hungry
-		numpy/lib/tests/test_io.py::TestSaveTxt::test_large_zip
-		numpy/lib/tests/test_io.py::TestSavezLoad::test_closing_fid
-		numpy/lib/tests/test_io.py::TestSavezLoad::test_closing_zipfile_after_load
-
-		# Precision problems
-		numpy/_core/tests/test_umath_accuracy.py::TestAccuracy::test_validate_transcendentals
-
-		# Runs the whole test suite recursively, that's just crazy
-		numpy/core/tests/test_mem_policy.py::test_new_policy
-
-		numpy/typing/tests/test_typing.py
-		# Uses huge amount of memory
-		numpy/core/tests/test_mem_overlap.py
-		'numpy/core/tests/test_multiarray.py::TestDot::test_huge_vectordot[complex128]'
-	)
-
-	if [[ $(uname -m) == armv8l ]]; then
-		# Degenerate case of arm32 chroot on arm64, bug #774108
-		EPYTEST_DESELECT+=(
-			numpy/core/tests/test_cpu_features.py::Test_ARM_Features::test_features
-		)
-	fi
-
-	case ${EPYTHON} in
-		python3.13)
-			EPYTEST_DESELECT+=(
-				numpy/_core/tests/test_nditer.py::test_iter_refcount
-				numpy/_core/tests/test_limited_api.py::test_limited_api
-				numpy/f2py/tests/test_f2py2e.py::test_gh22819_cli
-			)
-			;&
-		python3.12)
-			EPYTEST_DESELECT+=(
-				# flaky
-				numpy/f2py/tests/test_crackfortran.py
-				numpy/f2py/tests/test_data.py::TestData::test_crackedlines
-				numpy/f2py/tests/test_data.py::TestDataF77::test_crackedlines
-				numpy/f2py/tests/test_f2py2e.py::test_gen_pyf
-			)
-			;;
-	esac
-
-	if ! has_version -b "~${CATEGORY}/${P}[${PYTHON_USEDEP}]" ; then
-		# depends on importing numpy.random from system namespace
-		EPYTEST_DESELECT+=(
-			'numpy/random/tests/test_extending.py::test_cython'
-		)
-	fi
-
-	if has_version ">=dev-python/setuptools-74[${PYTHON_USEDEP}]"; then
-		# msvccompiler removal
-		EPYTEST_DESELECT+=(
-			numpy/tests/test_public_api.py::test_all_modules_are_expected_2
-			numpy/tests/test_public_api.py::test_api_importable
-		)
-		EPYTEST_IGNORE+=(
-			numpy/distutils/tests/test_mingw32ccompiler.py
-			numpy/distutils/tests/test_system_info.py
-		)
-	fi
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
-	epytest
-}
-
-python_install_all() {
-	local DOCS=( LICENSE.txt README.md THANKS.txt )
-	distutils-r1_python_install_all
-}