[gentoo-commits] repo/gentoo:master commit in: dev-python/python-daemon/

["Michał Górny" <mgorny@gentoo.org>]

commit:     5e36179a5705eb4af0c3388299b68b03fb8b10bd
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Oct 25 04:02:36 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Oct 25 04:03:22 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5e36179a

dev-python/python-daemon: Bump to 3.1.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/python-daemon/Manifest                  |  1 +
 .../python-daemon/python-daemon-3.1.0.ebuild       | 51 ++++++++++++++++++++++
 2 files changed, 52 insertions(+)

diff --git a/dev-python/python-daemon/Manifest b/dev-python/python-daemon/Manifest
index 2fa6ce8f7a06..3fdf73ffc291 100644
--- a/dev-python/python-daemon/Manifest
+++ b/dev-python/python-daemon/Manifest
@@ -1 +1,2 @@
 DIST python-daemon-2.3.2.tar.gz 83127 BLAKE2B bce00867850e8451bcaf5a51864bdd751fa3b5e7be8ae1d36d724a915680713fc66c0fc6c8499bce03e0eb86465f5806fb8645376e600b8eac579fee3c24a087 SHA512 d9f6e6c376a496fae96bd9efed0a56d00a137617a3d1d5ef74802ef176bc813bb1d49bbb9164cdbec03213529f944b32b257bcc64283abfa4a3522ff00826bfd
+DIST python_daemon-3.1.0.tar.gz 61947 BLAKE2B d6f24cb72a033401a2eb1149c359ec49e044b0d549ae8ccb337dc60525f3ad80efd8646a50a51e6ba0768a5e8e77a3a5bd5b1a5aea3b54c5546769a5599d49ad SHA512 d7641baba841af8724dd37b66db605d07a62c947f01ff6328c44aca56deaa5a0891b8fe3bbbf5840e16c7080402776676892f105aac900944a8d2921a12edba4

diff --git a/dev-python/python-daemon/python-daemon-3.1.0.ebuild b/dev-python/python-daemon/python-daemon-3.1.0.ebuild
new file mode 100644
index 000000000000..a0b03d674d2a
--- /dev/null
+++ b/dev-python/python-daemon/python-daemon-3.1.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Library to implement a well-behaved Unix daemon process"
+HOMEPAGE="
+	https://pagure.io/python-daemon/
+	https://pypi.org/project/python-daemon/
+"
+
+# build system and tests use GPL-3.0+ but none of these files are installed
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/lockfile-0.10[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	test? (
+		dev-python/testtools[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# overengineered logic with NIH deps
+	rm setup.py || die
+	cat > setup.cfg <<-EOF || die
+		[metadata]
+		version = ${PV}
+		description = ${DESCRIPTION}
+		maintainer =
+		long_description =
+	EOF
+
+	# tests for their overengineered setup
+	rm test/test_{setup,util_metadata}.py || die
+}