[gentoo-commits] repo/proj/guru:master commit in: dev-python/asyncpg/files/, dev-python/asyncpg/

[gentoo-commits] repo/proj/guru:master commit in: dev-python/asyncpg/files/, dev-python/asyncpg/

[David Roman]

commit:     850e6e7134c38c303f47d8c4fba951fc7a22c437
Author:     Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq <DOT> in>
AuthorDate: Tue Oct 22 12:47:48 2024 +0000
Commit:     David Roman <davidroman96 <AT> gmail <DOT> com>
CommitDate: Tue Oct 22 12:47:48 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/guru.git/commit/?id=850e6e71

dev-python/asyncpg: add 0.30.0

Bug: https://bugs.gentoo.org/887651
Bug: https://bugs.gentoo.org/926720
Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo <AT> sysrq.in>

 dev-python/asyncpg/Manifest                        |  1 +
 dev-python/asyncpg/asyncpg-0.30.0.ebuild           | 81 ++++++++++++++++++++++
 .../asyncpg/files/asyncpg-0.30.0-cflags.patch      | 15 ++++
 dev-python/asyncpg/metadata.xml                    |  8 ++-
 4 files changed, 103 insertions(+), 2 deletions(-)

diff --git a/dev-python/asyncpg/Manifest b/dev-python/asyncpg/Manifest
index cbbcfd1ac..a5e95c9b8 100644
--- a/dev-python/asyncpg/Manifest
+++ b/dev-python/asyncpg/Manifest
@@ -1 +1,2 @@
 DIST asyncpg-0.29.0.tar.gz 820455 BLAKE2B 9bb5606dfb103e066dcfd15c327fe8a8135bf4433c816dc354d84227e40b9f18bb2788ead0dd25b087f97b3113645b6dcfd8991a7bb6e2e71528d122c41105d5 SHA512 5db979496323fcf4068d5de111b52f2ae1ad9efe68f80c28e6303ad936eb051d1792409f1e31fb86dc35caad5ef9b92c40e4f6dcbcccc3907ab2247f61db5504
+DIST asyncpg-0.30.0.tar.gz 957746 BLAKE2B 2da92520bd30c1e5eebbfddabf78b9e9e221fb33ad77fa01f77ceb8bdf73e057868bf60987c2c67a6ed5d8b0cacb3b80c0aefd6afa1b574e2629d358c9158bbb SHA512 bbfc83ae881f454cb16343037ae48fbc9c9c65b57d11fc1e28ec054b9051d823f7da0735307090d0ce4e5dca166590b147d0f9d383a1ac0b894396290aa0782a

diff --git a/dev-python/asyncpg/asyncpg-0.30.0.ebuild b/dev-python/asyncpg/asyncpg-0.30.0.ebuild
new file mode 100644
index 000000000..a412dba36
--- /dev/null
+++ b/dev-python/asyncpg/asyncpg-0.30.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )  # doesn't build with pypy3
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 pypi
+
+DESCRIPTION="An asyncio PostgreSQL driver"
+HOMEPAGE="
+	https://pypi.org/project/asyncpg/
+	https://github.com/MagicStack/asyncpg
+"
+
+LICENSE="Apache-2.0 PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="kerberos"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/async-timeout-4.0.3[${PYTHON_USEDEP}]
+	' python3_10)
+	kerberos? ( dev-python/gssapi[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-db/postgresql[kerberos?,server,ssl]
+		dev-python/distro[${PYTHON_USEDEP}]
+		dev-python/uvloop[${PYTHON_USEDEP}]
+		kerberos? (
+			app-crypt/mit-krb5
+			dev-python/k5test[${PYTHON_USEDEP}]
+		)
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.30.0-cflags.patch
+)
+
+EPYTEST_IGNORE=(
+	# checks versions from env variables
+	"${S}"/tests/test__environment.py
+	# runs flake8 (???)
+	"${S}"/tests/test__sourcecode.py
+)
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme
+
+src_prepare() {
+	# remove pre-generated Cython sources
+	rm asyncpg/{pgproto/pgproto,protocol/protocol}.c || die
+
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	use debug && \
+		export ASYNCPG_DEBUG=1
+
+	if ! use kerberos; then
+		EPYTEST_DESELECT+=( tests/test_connect.py::TestGssAuthentication )
+	fi
+
+	distutils-r1_src_configure
+}
+
+python_test() {
+	cd "${T}" || die
+	for opt in "" "1"; do
+		einfo "  testing with USE_UVLOOP='${opt}'"
+		USE_UVLOOP="${opt}" epytest "${S}"/tests
+	done
+}

diff --git a/dev-python/asyncpg/files/asyncpg-0.30.0-cflags.patch b/dev-python/asyncpg/files/asyncpg-0.30.0-cflags.patch
new file mode 100644
index 000000000..19c197dd7
--- /dev/null
+++ b/dev-python/asyncpg/files/asyncpg-0.30.0-cflags.patch
@@ -0,0 +1,15 @@
+Do not overwrite user's optimization.
+
+Bug: https://bugs.gentoo.org/887651
+
+--- a/setup.py
++++ b/setup.py
+@@ -27,7 +27,7 @@ from setuptools.command import build_ext as setuptools_build_ext
+ 
+ CYTHON_DEPENDENCY = 'Cython(>=0.29.24,<4.0.0)'
+ 
+-CFLAGS = ['-O2']
++CFLAGS = []
+ LDFLAGS = []
+ 
+ if platform.uname().system != 'Windows':

diff --git a/dev-python/asyncpg/metadata.xml b/dev-python/asyncpg/metadata.xml
index b90ce0255..7340e7af2 100644
--- a/dev-python/asyncpg/metadata.xml
+++ b/dev-python/asyncpg/metadata.xml
@@ -1,12 +1,16 @@
-<?xml version="1.0" encoding="UTF-8"?>
+<?xml version='1.0' encoding='UTF-8'?>
 <!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 	<maintainer type="person">
 		<email>cyber+gentoo@sysrq.in</email>
 		<name>Anna</name>
-	</maintainer>	
+	</maintainer>
 	<upstream>
 		<remote-id type="github">MagicStack/asyncpg</remote-id>
 		<remote-id type="pypi">asyncpg</remote-id>
+		<maintainer>
+			<name>MagicStack Inc</name>
+			<email>hello@magic.io</email>
+		</maintainer>
 	</upstream>
 </pkgmetadata>