[gentoo-commits] repo/gentoo:master commit in: media-video/shotcut/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     f4e23866b1f186cb4adc6575c8b3e59d2051d950
Author:     zukas97 <zukaslurker97 <AT> proton <DOT> me>
AuthorDate: Mon Sep 16 20:42:20 2024 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Sat Oct 19 08:36:58 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f4e23866

media-video/shotcut: add 24.09.13

Signed-off-by: Lukas Zuercher <zukaslurker97 <AT> proton.me>
Closes: https://github.com/gentoo/gentoo/pull/38634
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 media-video/shotcut/shotcut-24.09.13.ebuild | 53 +++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/media-video/shotcut/shotcut-24.09.13.ebuild b/media-video/shotcut/shotcut-24.09.13.ebuild
new file mode 100644
index 000000000000..b72aafd2d6c0
--- /dev/null
+++ b/media-video/shotcut/shotcut-24.09.13.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic xdg
+
+DESCRIPTION="A free, open source, cross-platform video editor"
+HOMEPAGE="https://www.shotcut.org/ https://github.com/mltframework/shotcut/"
+if [[ ${PV} != 9999* ]] ; then
+	SRC_URI="https://github.com/mltframework/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mltframework/shotcut/"
+fi
+
+LICENSE="GPL-3+"
+
+SLOT="0"
+
+IUSE="debug"
+
+BDEPEND="
+	dev-qt/qttools:6[linguist]
+"
+DEPEND="
+	dev-qt/qtbase:6[concurrent,gui,network,opengl,sql,widgets,xml]
+	dev-qt/qtdeclarative:6[widgets]
+	dev-qt/qtmultimedia:6
+	dev-qt/qtcharts:6
+	>=media-libs/mlt-7.18.0[ffmpeg,frei0r,jack,opengl,sdl,xml]
+	media-video/ffmpeg
+"
+
+RDEPEND="${DEPEND}
+	virtual/jack
+"
+
+src_configure() {
+	CMAKE_BUILD_TYPE=$(usex debug Debug Release)
+	if [[ ${PV} != 9999* ]] ; then
+		SHOTCUT_VERSION="${PV}"
+	else
+		SHOTCUT_VERSION="$(git log --date=format:'%y.%m.%d' -1 --format='%ad')"
+	fi
+	local mycmakeargs=(
+		-DSHOTCUT_VERSION="${SHOTCUT_VERSION}"
+	)
+	use debug || append-cxxflags "-DNDEBUG"
+	append-cxxflags "-DSHOTCUT_NOUPGRADE"
+	cmake_src_configure
+}