[gentoo-commits] repo/gentoo:master commit in: dev-python/kombu/

["Michał Górny" <mgorny@gentoo.org>]

commit:     87f98669a703170c02515604ec7928420091b5e2
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Oct 15 05:52:27 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Oct 15 07:00:21 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=87f98669

dev-python/kombu: Bump to 5.5.0_rc1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/kombu/Manifest               |  1 +
 dev-python/kombu/kombu-5.5.0_rc1.ebuild | 96 +++++++++++++++++++++++++++++++++
 2 files changed, 97 insertions(+)

diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index f7706d442c46..cfc30ac716dc 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
 DIST kombu-5.4.2.tar.gz 442858 BLAKE2B a613f3a5656c87826345d7e96b4ccf15336afdcd79a77db04140628f8522cb6f348fa31d3ccba66b6d01c423971ae013f157a812e12662bf4639fd4f4dbfc750 SHA512 4224412b8d3ee867af03a1771326681f78d112f31ab7ecd7c0f648bd28e834b296c1b36b7720351ec8e0ba871153caaa6aa06961394c5a9e99cd68291ad20b9b
+DIST kombu-5.5.0rc1.tar.gz 457246 BLAKE2B 32dda81ea2e3efc22f6f4c2b9da477f26c42eff4657d4a8f680e0fed4c99df5549554e9f5589cc10da755155d799ee43801dec4051444437e7fae1d934f997e3 SHA512 8e4acfb6e6dc42299c4c2a8eacb0a9266e3d893bea4af2fe64c193d9239b7c3f7ef1f6722f4c541b2b8e7492752f36294832e53600c3de0c8e85c97cd431167a

diff --git a/dev-python/kombu/kombu-5.5.0_rc1.ebuild b/dev-python/kombu/kombu-5.5.0_rc1.ebuild
new file mode 100644
index 000000000000..07766f9c1954
--- /dev/null
+++ b/dev-python/kombu/kombu-5.5.0_rc1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+	https://github.com/celery/kombu/
+	https://pypi.org/project/kombu/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/amqp-5.1.1[${PYTHON_USEDEP}]
+	<dev-python/amqp-6.0.0[${PYTHON_USEDEP}]
+	dev-python/tzdata[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		>=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+		dev-python/pytest-freezer[${PYTHON_USEDEP}]
+		dev-python/zstandard[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		>=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx-celery
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin deps (notably tzdata, sigh)
+	> requirements/default.txt || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
+		t/unit/transport/test_redis.py::test_Channel::test_global_keyprefix_transaction
+		# bad filename assumption?
+		t/unit/asynchronous/aws/test_connection.py::test_AsyncHTTPSConnection::test_request_with_cert_path_https
+	)
+	local EPYTEST_IGNORE=(
+		# obsolete Pyro4
+		t/unit/transport/test_pyro.py
+		# unpackaged azure
+		t/unit/transport/test_azurestoragequeues.py
+		# unpackage google-cloud
+		t/unit/transport/test_gcpubsub.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+	optfeature "Etcd backend" dev-python/python-etcd
+	optfeature "MongoDB backend" dev-python/pymongo
+	optfeature "Redis backend" dev-python/redis
+	optfeature "sqlalchemy backend" dev-python/sqlalchemy
+	optfeature "yaml backend" dev-python/pyyaml
+	optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+	optfeature "brotli compression" "app-arch/brotli[python]"
+	optfeature "zstd compression" dev-python/zstandard
+}