[gentoo-commits] repo/gentoo:master commit in: dev-python/moto/

["Michał Górny" <mgorny@gentoo.org>]

commit:     bf210816ec9d34d28390c2857b0fcb6695b31c3b
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 13 14:31:07 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Oct 13 14:58:21 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bf210816

dev-python/moto: Bump to 5.0.17

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/moto/Manifest           |   1 +
 dev-python/moto/moto-5.0.17.ebuild | 136 +++++++++++++++++++++++++++++++++++++
 2 files changed, 137 insertions(+)

diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index 94df0b8288f8..6b854303acfc 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -1,3 +1,4 @@
 DIST moto-4.2.14.tar.gz 4933741 BLAKE2B 4c50a808dc8f27cfbcd0ba234d268084ee9a32f36cb5d6af61aacc4ee79f7bf5cf1045147c4642472129eee37bef8bc2c1953d140260d39d7f333ae0f5e5cf95 SHA512 d4079118ed1d2eef9134575e33dc0ed749bff0293d753baa63a630dbb987914b9933445027abdc344bb93fa1d6e483baf8a337a444c9dd055dda50b095ff9937
 DIST moto-5.0.15.tar.gz 5465282 BLAKE2B c043b0cf5ce42d0633f25ab874e787315367836d54c59ceedc3e85a161b01974671eb6dd42916e45ccaaaab9a48bfa217c0b8f22fbd817da3d2a9b4ee4522a03 SHA512 95c20146d6d5dcb6b49c3bb90e23bc6b656f6773267263bfd6a4f069a572311ef47cde3e1797dce78cfa38a28894b5deaf5e1bbe4bfcde3b49cfeea90cc63b25
 DIST moto-5.0.16.tar.gz 5483357 BLAKE2B 7486a17627451494d09dcad8987da1ab456a9a8ad8fa6bca4650cf1c582e3babb39b502aec0b8c389415181af7e3c8f91ddde16715432a69ade0eb65c0e84ea2 SHA512 2201fe7b74eec9b2896afa5d7eba814c41ffae73b7becfc5e6c80523d51bf19d1de6713a5713758909c8d2343cc0ca1e0e238655153d91da161d043336c1e313
+DIST moto-5.0.17.tar.gz 5500632 BLAKE2B 9807388c0318a99635b0972f7d4d24489ddd37b0ec5272965d895c101ee924ef3915d8ef7546b6eab7574e87a5b3c650abce5dc07dda389a1fd9a0fc55d75cfb SHA512 8f17b4f0367f7068c0896d1db8766a2133dab027f107d742027ca936c3a2aaf13e4255ddc4801958e53197e3dd618bd6db7a7b21fef057662ba98e895c2e6bfc

diff --git a/dev-python/moto/moto-5.0.17.ebuild b/dev-python/moto/moto-5.0.17.ebuild
new file mode 100644
index 000000000000..9637a0ebd64e
--- /dev/null
+++ b/dev-python/moto/moto-5.0.17.ebuild
@@ -0,0 +1,136 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi toolchain-funcs
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="
+	https://github.com/getmoto/moto/
+	https://pypi.org/project/moto/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-0.93[${PYTHON_USEDEP}]
+	dev-python/boto3[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cfn-lint-0.40.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	>=dev-python/docker-3.0.0[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	dev-python/jsonpath-ng[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3.0.7[${PYTHON_USEDEP}]
+	>=dev-python/openapi-spec-validator-0.5.0[${PYTHON_USEDEP}]
+	dev-python/pyaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.15.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/sshpubkeys[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/antlr4-python3-runtime[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+	)
+"
+
+: "${EPYTEST_TIMEOUT:=180}"
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Needs network (or docker?) but not marked as such, bug #807031
+		# TODO: report upstream
+		tests/test_core/test_request_passthrough.py
+		tests/test_core/test_responses_module.py::TestResponsesMockWithPassThru::test_aws_and_http_requests
+		tests/test_core/test_responses_module.py::TestResponsesMockWithPassThru::test_http_requests
+		# broken code? (local variable used referenced before definition)
+		tests/test_appsync/test_appsync_schema.py
+		# require py_partiql_parser
+		tests/test_s3/test_s3_select.py
+		tests/test_dynamodb/test_dynamodb_statements.py
+		# require joserfc
+		tests/test_apigateway/test_apigateway.py::test_update_authorizer_configuration
+		tests/test_apigateway/test_apigateway.py::test_create_authorizer
+		tests/test_apigateway/test_apigateway.py::test_delete_authorizer
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserDeleter::test_authenticate_with_signed_out_user
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserPoolDuplidateEmails::test_use_existing_email__when_email_is_
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserPoolDuplidateEmails::test_use_existing_email__when_username_
+		tests/test_cognitoidp/test_cognitoidp_replay.py::TestCreateUserPoolWithPredeterminedID::test_different_seed
+		tests/test_cognitoidp/test_cognitoidp_replay.py::TestCreateUserPoolWithPredeterminedID::test_same_seed
+		tests/test_cognitoidp/test_server.py::test_sign_up_user_without_authentication
+		tests/test_cognitoidp/test_server.py::test_admin_create_user_without_authentication
+		# TODO
+		tests/test_dynamodb/test_dynamodb_import_table.py
+		tests/test_firehose/test_firehose_put.py::test_put_record_http_destination
+		tests/test_firehose/test_firehose_put.py::test_put_record_batch_http_destination
+		tests/test_stepfunctions/parser/test_stepfunctions_dynamodb_integration.py::test_zero_retry
+	)
+	local EPYTEST_IGNORE=(
+		# require joserfc
+		tests/test_cognitoidp/test_cognitoidp.py
+	)
+
+	case ${EPYTHON} in
+		python3.13)
+			EPYTEST_DESELECT+=(
+				# suddenly started crashing, *shrug*
+				tests/test_xray/test_xray_client.py::test_xray_context_patched
+				tests/test_xray/test_xray_client.py::test_xray_dynamo_request_id
+				tests/test_xray/test_xray_client.py::test_xray_dynamo_request_id_with_context_mgr
+				tests/test_xray/test_xray_client.py::test_xray_udp_emitter_patched
+			)
+			;;
+	esac
+
+	# test for 32-bit time_t
+	"$(tc-getCC)" ${CFLAGS} ${CPPFLAGS} -c -x c - -o /dev/null <<-EOF &>/dev/null
+		#include <sys/types.h>
+		int test[sizeof(time_t) >= 8 ? 1 : -1];
+	EOF
+
+	if [[ ${?} -eq 0 ]]; then
+		einfo "time_t is at least 64-bit long"
+	else
+		einfo "time_t is smaller than 64 bits, will skip broken tests"
+		EPYTEST_DESELECT+=(
+			tests/test_acm/test_acm.py::test_request_certificate_with_optional_arguments
+			tests/test_s3/test_multiple_accounts_server.py::TestAccountIdResolution::test_with_custom_request_header
+			tests/test_s3/test_server.py::test_s3_server_post_cors_multiple_origins
+		)
+		EPYTEST_IGNORE+=(
+			tests/test_route53domains/test_route53domains_domain.py
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x TZ=UTC
+
+	rm -rf moto || die
+	epytest -m 'not network and not requires_docker' \
+		-p rerunfailures --reruns=5
+}