[gentoo-commits] repo/gentoo:master commit in: net-libs/libnetfilter_log/

["Conrad Kostecki" <conikost@gentoo.org>]

commit:     d7625d30a6dcb2cea5535a8b7e7e7cd4a99cf498
Author:     Michael Mair-Keimberger <mmk <AT> levelnine <DOT> at>
AuthorDate: Wed Sep  4 16:44:13 2024 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Thu Oct 10 20:25:37 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d7625d30

net-libs/libnetfilter_log: fix LICENSE, delete unused libtool files

Closes: https://bugs.gentoo.org/840972
Signed-off-by: Michael Mair-Keimberger <mmk <AT> levelnine.at>
Closes: https://github.com/gentoo/gentoo/pull/38436
Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 .../libnetfilter_log-1.0.2-r1.ebuild               | 42 ++++++++++++++++++++++
 1 file changed, 42 insertions(+)

diff --git a/net-libs/libnetfilter_log/libnetfilter_log-1.0.2-r1.ebuild b/net-libs/libnetfilter_log/libnetfilter_log-1.0.2-r1.ebuild
new file mode 100644
index 000000000000..21db6799c7c9
--- /dev/null
+++ b/net-libs/libnetfilter_log/libnetfilter_log-1.0.2-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info verify-sig
+
+DESCRIPTION="Interface to packets that have been logged by the kernel packet filter"
+HOMEPAGE="https://www.netfilter.org/projects/libnetfilter_log/"
+SRC_URI="https://www.netfilter.org/projects/${PN}/files/${P}.tar.bz2
+	verify-sig? ( https://www.netfilter.org/projects/${PN}/files/${P}.tar.bz2.sig )"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~riscv ~sparc ~x86"
+IUSE="doc"
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/netfilter.org.asc
+
+RDEPEND=">=net-libs/libnfnetlink-1.0.0
+	>=net-libs/libmnl-1.0.3"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	doc? ( app-text/doxygen )
+	verify-sig? ( sec-keys/openpgp-keys-netfilter )"
+
+CONFIG_CHECK="~NETFILTER_NETLINK_LOG"
+
+pkg_setup() {
+	linux-info_pkg_setup
+	kernel_is lt 2 6 14 && die "requires at least 2.6.14 kernel version"
+}
+
+src_configure() {
+	econf \
+		$(use_enable doc html-doc) \
+		$(use_enable doc man-pages)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete || die
+}