[gentoo-commits] repo/gentoo:master commit in: net-libs/libmbim/

["Sam James" <sam@gentoo.org>]

commit:     37a69f6f9e9e4cb65b26632a1aeee33c2a86ccba
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Oct  9 08:20:32 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Oct  9 08:20:32 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=37a69f6f

net-libs/libmbim: make introspection optional

This is useful for embedded environments that want a small image.

Closes: https://bugs.gentoo.org/936949
Signed-off-by: Sam James <sam <AT> gentoo.org>

 net-libs/libmbim/libmbim-1.28.4-r1.ebuild | 44 +++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

diff --git a/net-libs/libmbim/libmbim-1.28.4-r1.ebuild b/net-libs/libmbim/libmbim-1.28.4-r1.ebuild
new file mode 100644
index 000000000000..d64b685b3b68
--- /dev/null
+++ b/net-libs/libmbim/libmbim-1.28.4-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..13} )
+inherit bash-completion-r1 meson python-any-r1
+
+DESCRIPTION="Mobile Broadband Interface Model (MBIM) modem protocol helper library"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libmbim/ https://gitlab.freedesktop.org/mobile-broadband/libmbim"
+SRC_URI="https://gitlab.freedesktop.org/mobile-broadband/libmbim/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~x86"
+IUSE="gtk-doc introspection"
+
+RDEPEND="
+	>=dev-libs/glib-2.56:2
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	gtk-doc? ( dev-util/gtk-doc )
+	dev-util/glib-utils
+	sys-apps/help2man
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman=true
+		# Let's avoid BuildRequiring bash-completion, install it manually
+		-Dbash_completion=false
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	dobashcomp src/mbimcli/mbimcli
+}