[gentoo-commits] repo/gentoo:master commit in: dev-python/propcache/

[gentoo-commits] repo/gentoo:master commit in: dev-python/propcache/

[Michał Górny]

commit:     e2cb4c09585d5fbc981051768309e58707c538fc
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Oct  9 07:19:44 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Oct  9 07:47:29 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e2cb4c09

dev-python/propcache: New package, v0.2.0

New package, split out of dev-python/yarl.  Since the code was there
already, no rekeywording.

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/propcache/Manifest               |  1 +
 dev-python/propcache/metadata.xml           | 12 +++++++
 dev-python/propcache/propcache-0.2.0.ebuild | 50 +++++++++++++++++++++++++++++
 3 files changed, 63 insertions(+)

diff --git a/dev-python/propcache/Manifest b/dev-python/propcache/Manifest
new file mode 100644
index 000000000000..1a36abc38824
--- /dev/null
+++ b/dev-python/propcache/Manifest
@@ -0,0 +1 @@
+DIST propcache-0.2.0.tar.gz 40951 BLAKE2B f3e6aed19e6dfd21c02e769a3fa3c5bb0042f0b46d3dbe71ac06d52a49cfc86c62770ed8589fed58872016b5f50905610de50e707051871b9c30930e262d9d0c SHA512 f99838627652ab13919d7f516530a91565a737fc411d728cad1492ce0ed44f25b0cefbdb6fa49b2ef516e7fee120e7c49686b6853691c5cd02f5f7db9a15d998

diff --git a/dev-python/propcache/metadata.xml b/dev-python/propcache/metadata.xml
new file mode 100644
index 000000000000..fc98db92263c
--- /dev/null
+++ b/dev-python/propcache/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">propcache</remote-id>
+		<remote-id type="github">aio-libs/propcache</remote-id>
+	</upstream>
+</pkgmetadata>

diff --git a/dev-python/propcache/propcache-0.2.0.ebuild b/dev-python/propcache/propcache-0.2.0.ebuild
new file mode 100644
index 000000000000..7b568011e055
--- /dev/null
+++ b/dev-python/propcache/propcache-0.2.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Yet another URL library"
+HOMEPAGE="
+	https://github.com/aio-libs/propcache/
+	https://pypi.org/project/propcache/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+native-extensions"
+
+BDEPEND="
+	native-extensions? (
+		dev-python/cython[${PYTHON_USEDEP}]
+	)
+	dev-python/expandvars[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	local -x PROPCACHE_NO_EXTENSIONS=0
+	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
+		PROPCACHE_NO_EXTENSIONS=1
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local opts=()
+	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
+		opts+=( --no-c-extensions )
+	fi
+
+	rm -rf propcache || die
+	epytest -o addopts= "${opts[@]}"
+}