[gentoo-commits] repo/proj/prefix:master commit in: dev-libs/libbsd/

["Fabian Groffen" <grobian@gentoo.org>]

commit:     64b5a2e61ea6b58ab78e9e04dbf4c560365a1047
Author:     Fabian Groffen <grobian <AT> gentoo <DOT> org>
AuthorDate: Wed Oct  9 07:05:55 2024 +0000
Commit:     Fabian Groffen <grobian <AT> gentoo <DOT> org>
CommitDate: Wed Oct  9 07:05:55 2024 +0000
URL:        https://gitweb.gentoo.org/repo/proj/prefix.git/commit/?id=64b5a2e6

dev-libs/libbsd: sync with gx86

Signed-off-by: Fabian Groffen <grobian <AT> gentoo.org>

 dev-libs/libbsd/libbsd-0.11.8.ebuild | 50 ++++++++++++++++++++++++++++++++++++
 dev-libs/libbsd/libbsd-0.12.1.ebuild | 48 ++++++++++++++++++++++++++++++++++
 dev-libs/libbsd/libbsd-0.9.1.ebuild  | 40 -----------------------------
 3 files changed, 98 insertions(+), 40 deletions(-)

diff --git a/dev-libs/libbsd/libbsd-0.11.8.ebuild b/dev-libs/libbsd/libbsd-0.11.8.ebuild
new file mode 100644
index 0000000000..5f6c8cc214
--- /dev/null
+++ b/dev-libs/libbsd/libbsd-0.11.8.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/guillemjover.asc
+inherit flag-o-matic multilib multilib-minimal verify-sig
+
+DESCRIPTION="Library to provide useful functions commonly found on BSD systems"
+HOMEPAGE="https://libbsd.freedesktop.org/wiki/ https://gitlab.freedesktop.org/libbsd/libbsd"
+SRC_URI="https://${PN}.freedesktop.org/releases/${P}.tar.xz"
+SRC_URI+=" verify-sig? ( https://${PN}.freedesktop.org/releases/${P}.tar.xz.asc )"
+
+LICENSE="BEER-WARE BSD BSD-2 BSD-4 ISC MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
+IUSE="static-libs"
+
+RDEPEND="app-crypt/libmd[${MULTILIB_USEDEP}]"
+DEPEND="
+	${RDEPEND}
+	|| ( >=sys-kernel/linux-headers-3.17 virtual/os-headers )
+"
+BDEPEND="verify-sig? ( sec-keys/openpgp-keys-guillemjover )"
+
+multilib_src_configure() {
+	# Broken (still) with lld-17 (bug #922342, bug #915068)
+	append-ldflags $(test-flags-CCLD -Wl,--undefined-version)
+
+	# bug #911726
+	filter-flags -fno-semantic-interposition
+
+	# The build system will install libbsd-ctor.a despite USE="-static-libs"
+	# which is correct, see:
+	# https://gitlab.freedesktop.org/libbsd/libbsd/commit/c5b959028734ca2281250c85773d9b5e1d259bc8
+	ECONF_SOURCE="${S}" econf $(use_enable static-libs static)
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	# ld scripts on standalone prefix (RAP) systems should have the prefix
+	# stripped from any paths, as the sysroot is automatically prepended.
+	local ldscript=${ED}/usr/$(get_libdir)/${PN}$(get_libname)
+	if use prefix && ! use prefix-guest && grep -qIF "ld script" "${ldscript}" 2>/dev/null; then
+		sed -i "s|${EPREFIX}/|/|g" "${ldscript}" || die
+	fi
+}

diff --git a/dev-libs/libbsd/libbsd-0.12.1.ebuild b/dev-libs/libbsd/libbsd-0.12.1.ebuild
new file mode 100644
index 0000000000..3d07234e7c
--- /dev/null
+++ b/dev-libs/libbsd/libbsd-0.12.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/guillemjover.asc
+inherit flag-o-matic multilib multilib-minimal verify-sig
+
+DESCRIPTION="Library to provide useful functions commonly found on BSD systems"
+HOMEPAGE="https://libbsd.freedesktop.org/wiki/ https://gitlab.freedesktop.org/libbsd/libbsd"
+SRC_URI="https://${PN}.freedesktop.org/releases/${P}.tar.xz"
+SRC_URI+=" verify-sig? ( https://${PN}.freedesktop.org/releases/${P}.tar.xz.asc )"
+
+LICENSE="BEER-WARE BSD BSD-2 BSD-4 ISC MIT"
+SLOT="0"
+# Unkeyworded until figured out a solution for bug #925663
+#KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="static-libs"
+
+RDEPEND="app-crypt/libmd[${MULTILIB_USEDEP}]"
+DEPEND="
+	${RDEPEND}
+	|| ( >=sys-kernel/linux-headers-3.17 virtual/os-headers )
+"
+BDEPEND="verify-sig? ( sec-keys/openpgp-keys-guillemjover )"
+
+multilib_src_configure() {
+	# bug #911726
+	filter-flags -fno-semantic-interposition
+
+	# The build system will install libbsd-ctor.a despite USE="-static-libs"
+	# which is correct, see:
+	# https://gitlab.freedesktop.org/libbsd/libbsd/commit/c5b959028734ca2281250c85773d9b5e1d259bc8
+	ECONF_SOURCE="${S}" econf $(use_enable static-libs static)
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	# ld scripts on standalone prefix (RAP) systems should have the prefix
+	# stripped from any paths, as the sysroot is automatically prepended.
+	local ldscript=${ED}/usr/$(get_libdir)/${PN}$(get_libname)
+	if use prefix && ! use prefix-guest && grep -qIF "ld script" "${ldscript}" 2>/dev/null; then
+		sed -i "s|${EPREFIX}/|/|g" "${ldscript}" || die
+	fi
+}

diff --git a/dev-libs/libbsd/libbsd-0.9.1.ebuild b/dev-libs/libbsd/libbsd-0.9.1.ebuild
deleted file mode 100644
index 40d57309e3..0000000000
--- a/dev-libs/libbsd/libbsd-0.9.1.ebuild
+++ /dev/null
@@ -1,40 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit multilib-minimal
-
-DESCRIPTION="An library to provide useful functions commonly found on BSD systems"
-HOMEPAGE="https://libbsd.freedesktop.org/wiki/"
-SRC_URI="https://${PN}.freedesktop.org/releases/${P}.tar.xz"
-
-LICENSE="BSD BSD-2 BSD-4 ISC"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
-IUSE="static-libs"
-
-DEPEND="|| ( >=sys-kernel/linux-headers-3.17 virtual/os-headers )"
-RDEPEND=""
-
-pkg_setup() {
-	local f="${EROOT}/usr/$(get_libdir)/${PN}.a"
-	local m="You need to remove ${f} by hand or re-emerge sys-libs/glibc first."
-	if ! has_version ${CATEGORY}/${PN}; then
-		if [[ -e ${f} ]]; then
-			eerror "${m}"
-			die "${m}"
-		fi
-	fi
-}
-
-multilib_src_configure() {
-	# The build system will install libbsd-ctor.a despite of USE="-static-libs"
-	# which is correct, see:
-	# https://cgit.freedesktop.org/libbsd/commit/?id=c5b959028734ca2281250c85773d9b5e1d259bc8
-	ECONF_SOURCE="${S}" econf $(use_enable static-libs static)
-}
-
-multilib_src_install() {
-	emake DESTDIR="${D}" install
-	find "${ED}" -name "*.la" -delete || die
-}