[gentoo-commits] repo/gentoo:master commit in: dev-python/dnspython/

["Michał Górny" <mgorny@gentoo.org>]

commit:     6408d99958990ae7b4b84ab867d49cfc80c8baf8
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Oct  6 02:18:13 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Oct  6 02:30:46 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6408d999

dev-python/dnspython: Bump to 2.7.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/dnspython/Manifest               |  1 +
 dev-python/dnspython/dnspython-2.7.0.ebuild | 55 +++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/dev-python/dnspython/Manifest b/dev-python/dnspython/Manifest
index 69ffca18b716..9c3e7d121de8 100644
--- a/dev-python/dnspython/Manifest
+++ b/dev-python/dnspython/Manifest
@@ -1 +1,2 @@
 DIST dnspython-2.6.1.gh.tar.gz 373684 BLAKE2B 63ac506d528a9e3684daf4888b51d732d9a12c3439ff1c353250a7bad78781f9f12bb13509e69093d5585a4a04bf2fbb1b8eb690a39f27e5d58e8f0f3b3b36a8 SHA512 77e9c69ac70e9e31a11188b968d28b8f2890b053b2cce0e608eefad7fd2c2b0f30c074222b2e5e85c0b4b8705f2e45acfa8b016a7808cc421df1d77f2561d978
+DIST dnspython-2.7.0.gh.tar.gz 386890 BLAKE2B 209bbb761cff2e39f86fb94458976766f3cac93e47f2c25294c359c98126aa4670b8157fad6c2bbf67ef250150310b31068690cec43ef148bbaf541873c37f38 SHA512 d73b90a06fa4c731393f719a79ec1339c3f8010b0ef4e58d8aa1aa5e0f2804dff8a79e20d9c9175b41b66bc9cf1712c33f4e2ed14820afc74d988096a42488b5

diff --git a/dev-python/dnspython/dnspython-2.7.0.ebuild b/dev-python/dnspython/dnspython-2.7.0.ebuild
new file mode 100644
index 000000000000..24a34d0cb853
--- /dev/null
+++ b/dev-python/dnspython/dnspython-2.7.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="DNS toolkit for Python"
+HOMEPAGE="
+	https://www.dnspython.org/
+	https://github.com/rthalley/dnspython/
+	https://pypi.org/project/dnspython/
+"
+SRC_URI="
+	https://github.com/rthalley/dnspython/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="dnssec examples"
+
+RDEPEND="
+	dnssec? (
+		>=dev-python/cryptography-41[${PYTHON_USEDEP}]
+	)
+	>=dev-python/idna-2.1[${PYTHON_USEDEP}]
+"
+# note: skipping DoH test deps because they require Internet anyway
+BDEPEND="
+	test? (
+		>=dev-python/cryptography-41[${PYTHON_USEDEP}]
+		>=dev-python/quart-trio-0.11.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x NO_INTERNET=1
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}