[gentoo-commits] repo/gentoo:master commit in: x11-libs/qwtpolar/

["Andrew Ammerlaan" <andrewammerlaan@gentoo.org>]

commit:     d174eeb4b033bef712a7a310202b8497bff4a187
Author:     Filip Kobierski <fkobi <AT> pm <DOT> me>
AuthorDate: Sat Aug 10 12:24:49 2024 +0000
Commit:     Andrew Ammerlaan <andrewammerlaan <AT> gentoo <DOT> org>
CommitDate: Mon Sep 23 14:53:57 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d174eeb4

x11-libs/qwtpolar: bump EAPI, fix pkgcheck issues

- fix src_uri redirect
- remove empty IUSE

Signed-off-by: Filip Kobierski <fkobi <AT> pm.me>
Closes: https://github.com/gentoo/gentoo/pull/38061
Signed-off-by: Andrew Ammerlaan <andrewammerlaan <AT> gentoo.org>

 x11-libs/qwtpolar/qwtpolar-1.1.1-r4.ebuild | 60 ++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/x11-libs/qwtpolar/qwtpolar-1.1.1-r4.ebuild b/x11-libs/qwtpolar/qwtpolar-1.1.1-r4.ebuild
new file mode 100644
index 000000000000..ff4af44583b7
--- /dev/null
+++ b/x11-libs/qwtpolar/qwtpolar-1.1.1-r4.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit qmake-utils
+
+DESCRIPTION="Library for displaying values on a polar coordinate system"
+HOMEPAGE="https://qwtpolar.sourceforge.io/"
+SRC_URI="https://downloads.sourceforge.net/project/${PN}/${PN}/${PV}/${P}.tar.bz2"
+
+LICENSE="qwt"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	<x11-libs/qwt-6.2:6=[designer,qt5(+),svg,-polar(-)]
+"
+DEPEND="${RDEPEND}
+	dev-qt/qtconcurrent:5
+"
+
+src_prepare() {
+	default
+
+	local qtplugindir="${EPREFIX}$(qt5_get_plugindir)"
+
+	sed \
+		-e "/QWT_POLAR_INSTALL_PREFIX /s:=.*$:= ${EPREFIX}/usr:g" \
+		-e "/QWT_POLAR_INSTALL_LIBS/s:lib:$(get_libdir):g" \
+		-e "/QWT_POLAR_INSTALL_DOCS/s:doc:share/doc/${PF}:g" \
+		-e "/QWT_POLAR_INSTALL_PLUGINS/s:=.*$:= ${qtplugindir}/designer/:g" \
+		-e "/QWT_POLAR_INSTALL_FEATURES/s:=.*$:= ${qtplugindir}/features/:g" \
+		-e "/= QwtPolarDesigner/ d" \
+		-e "/= QwtPolarExamples/d" \
+		-i ${PN}config.pri || die
+
+	sed \
+		-e "s:{QWT_POLAR_ROOT}/lib:{QWT_POLAR_ROOT}/$(get_libdir):" \
+		-i src/src.pro || die
+	echo "INCLUDEPATH += ${EPREFIX}/usr/include/qwt6" >> src/src.pro
+	cat >> designer/designer.pro <<- EOF
+	INCLUDEPATH += "${EPREFIX}"/usr/include/qwt6
+	LIBS += -L"${S}/$(get_libdir)"
+	EOF
+}
+
+src_configure() {
+	eqmake5
+}
+
+src_install() {
+	emake DESTDIR="${D}" INSTALL_ROOT="${D}" install
+	einstalldocs
+}