[gentoo-commits] repo/gentoo:master commit in: dev-python/hishel/

["Michał Górny" <mgorny@gentoo.org>]

commit:     2e888f6034a56ddb17e67cee2d3519458b8728a6
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 22 14:19:59 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Sep 22 14:19:59 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2e888f60

dev-python/hishel: Bump to 0.0.31

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/hishel/Manifest             |  1 +
 dev-python/hishel/hishel-0.0.31.ebuild | 74 ++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/dev-python/hishel/Manifest b/dev-python/hishel/Manifest
index 64d077b991f1..bb0e0be7acb9 100644
--- a/dev-python/hishel/Manifest
+++ b/dev-python/hishel/Manifest
@@ -1 +1,2 @@
 DIST hishel-0.0.30.gh.tar.gz 832978 BLAKE2B 932150b3464dcbc4fc2ff1361bafa6b2ea3fef496b0c89117c18b62122d07b0d71db66762e3eb87edb03f84eb4af0273f1792131e110291924bb29299051741a SHA512 f55f04badfe9ea161e20d8eca631cc02f9b1195ddaf3ba75b5e1a0ef143337a13438181ede9c853f30f7a24d3b6e59cffdc044860fc564d18392a59bd603c5c9
+DIST hishel-0.0.31.gh.tar.gz 833160 BLAKE2B 417cd61a88ca2dd29661f00bf7ce743b38a3d50f4eb111c69a42f6c59fdb8e9774f00e1802fb87cc8156975ffb3fabddc17cdc8f217cc62fce161ce780bea315 SHA512 88a459f4898af0d10718e7a90ec4502bb323f41a26c03ea36bf03ea0e88fe0984778094fafe9c4f8fea21a6e051a4c424a137faa239812d407c3468d231c12ab

diff --git a/dev-python/hishel/hishel-0.0.31.ebuild b/dev-python/hishel/hishel-0.0.31.ebuild
new file mode 100644
index 000000000000..046e93ae7033
--- /dev/null
+++ b/dev-python/hishel/hishel-0.0.31.ebuild
@@ -0,0 +1,74 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..13} )
+inherit distutils-r1
+
+DESCRIPTION="An elegant HTTP Cache implementation for HTTPX and HTTP Core"
+HOMEPAGE="
+	https://github.com/karpetrosyan/hishel
+	https://pypi.org/project/hishel/
+"
+SRC_URI="https://github.com/karpetrosyan/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	dev-python/httpx[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	${RDEPEND}
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	test? (
+		dev-db/redis
+		dev-python/anyio[${PYTHON_USEDEP}]
+		dev-python/boto3[${PYTHON_USEDEP}]
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/redis[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -e 's:mock_s3:mock_aws:g' \
+		-e '/import anysqlite/ d' \
+		-i tests/_async/test_storages.py \
+		tests/_sync/test_storages.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	local EPYTEST_DESELECT=(
+		# tests that need anysqlite
+		tests/_async/test_storages.py::test_sqlitestorage
+		tests/_async/test_storages.py::test_sqlite_expired
+		tests/_async/test_storages.py::test_sqlite_ttl_after_hits
+	)
+
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+
+	einfo "Starting Redis"
+	"${EPREFIX}"/usr/sbin/redis-server - <<- EOF
+		daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1 ::1
+	EOF
+
+	# Run the tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}