[gentoo-commits] repo/gentoo:master commit in: profiles/, x11-misc/xbindkeys/

[gentoo-commits] repo/gentoo:master commit in: profiles/, x11-misc/xbindkeys/

[Arsen Arsenović]

commit:     fecf67e319addb4a820f79914c55be4b592e7c5d
Author:     Alfred Wingate <parona <AT> protonmail <DOT> com>
AuthorDate: Tue Aug 27 15:30:55 2024 +0000
Commit:     Arsen Arsenović <arsen <AT> gentoo <DOT> org>
CommitDate: Wed Sep 18 13:06:42 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fecf67e3

x11-misc/xbindkeys: switch to new guile mechanism

Signed-off-by: Alfred Wingate <parona <AT> protonmail.com>
Signed-off-by: Arsen Arsenović <arsen <AT> gentoo.org>

 profiles/package.mask                          |  1 +
 x11-misc/xbindkeys/xbindkeys-1.8.7-r100.ebuild | 53 ++++++++++++++++++++++++++
 2 files changed, 54 insertions(+)

diff --git a/profiles/package.mask b/profiles/package.mask
index 028c0d97a91e..e80f0e0496fa 100644
--- a/profiles/package.mask
+++ b/profiles/package.mask
@@ -395,6 +395,7 @@ dev-scheme/guile:3.0
 >=sci-libs/nlopt-2.7.1-r100
 >=sys-devel/autogen-5.18.16-r100
 >=www-client/elinks-0.16.1.1-r100
+>=x11-misc/xbindkeys-1.8.7-r100
 
 # Eli Schwartz <eschwartz@gentoo.org> (2024-08-15)
 # Abandoned upstream since 2011, unmaintained in gentoo since 2017. Tons of

diff --git a/x11-misc/xbindkeys/xbindkeys-1.8.7-r100.ebuild b/x11-misc/xbindkeys/xbindkeys-1.8.7-r100.ebuild
new file mode 100644
index 000000000000..4688b3dae019
--- /dev/null
+++ b/x11-misc/xbindkeys/xbindkeys-1.8.7-r100.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+GUILE_REQ_USE="deprecated"
+GUILE_COMPAT=( 2-2 3-0 )
+inherit autotools guile-single
+
+DESCRIPTION="Tool for launching commands on keystrokes"
+SRC_URI="https://www.nongnu.org/${PN}/${P}.tar.gz"
+HOMEPAGE="https://www.nongnu.org/xbindkeys/xbindkeys.html"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="guile tk"
+
+REQUIRED_USE="guile? ( ${GUILE_REQUIRED_USE} )"
+
+RDEPEND="
+	x11-libs/libX11
+	guile? ( ${GUILE_DEPS} )
+	tk? ( dev-lang/tk )
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+"
+
+DOCS=( AUTHORS BUGS ChangeLog README TODO xbindkeysrc )
+
+src_prepare() {
+	default
+
+	use guile && guile_bump_sources
+
+	# Regenerate to pick up newer versions of Guile macros
+	# bug #828532
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable guile) \
+		$(use_enable tk)
+}
+
+src_install() {
+	default
+
+	use guile && guile_unstrip_ccache
+}