[gentoo-commits] repo/gentoo:master commit in: app-emulation/virtualbox-guest-additions/

["Viorel Munteanu" <ceamac@gentoo.org>]

commit:     2d50fe68c1076038c34d291be68f89ff8dcb5084
Author:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 15 12:44:51 2024 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Sun Sep 15 13:01:53 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2d50fe68

app-emulation/virtualbox-guest-additions: drop 7.1.0_beta2

Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 app-emulation/virtualbox-guest-additions/Manifest  |   2 -
 .../virtualbox-guest-additions-7.1.0_beta2.ebuild  | 289 ---------------------
 2 files changed, 291 deletions(-)

diff --git a/app-emulation/virtualbox-guest-additions/Manifest b/app-emulation/virtualbox-guest-additions/Manifest
index 35a9a025b9e3..710b0f0708f8 100644
--- a/app-emulation/virtualbox-guest-additions/Manifest
+++ b/app-emulation/virtualbox-guest-additions/Manifest
@@ -2,8 +2,6 @@ DIST VirtualBox-6.1.50.tar.bz2 165959648 BLAKE2B e244c4fa2ffe86216664104473e27e8
 DIST VirtualBox-7.0.18.tar.bz2 173295159 BLAKE2B 1371d54d648aafbad3814d55d495836ce7a6f9ca955aeb71e24c57a27ed8acae8c020b8094ca7386d341d5e7460b9b0823cc01e7e69dd3cdadaadee1bc608bd1 SHA512 e78a18fa808152cbdc1d407751acf3f57a8202bf238ad3432c4f0b0f97ab203e915a6cd11619e64f4aca5b907eb72be67bab146869af0e73414144addf0d76b4
 DIST VirtualBox-7.0.20.tar.bz2 173300021 BLAKE2B 23a1553578c8b89c3bea65fd9a451ef5abf419ce8a05524f2afc15b8d9a378a22ffb01c0c792d258320aeddb330b74f8f769180863041e333512d0eed2f4449c SHA512 7682e24d60c1896c661f2689af6820ae67b6bd8d9faaf18c58e8159bc7694ef80722f8e9611d6272da5b46eb2f3a44fc637b277e6801b7a8bf53aad045a81fe9
 DIST VirtualBox-7.1.0.tar.bz2 205966296 BLAKE2B 135805119d1710adbb17164d80a67f9b40fcc72d966af3b6d687b7f742a7bb487e76afc1ec45e31fe880a99a291ecdac3ee3dacdd342dbbe2dcec0eab32c8121 SHA512 d0fc27195b859fb537d57229d60a8895ced24b04c0f703c5862982de01d4787d20a3acb9cee4af29d18c56cd8c7ad846fd0eacc14af0c419e738953ca488463b
-DIST VirtualBox-7.1.0_BETA2.tar.bz2 208790183 BLAKE2B 30d1fb0a37463ab4bf8673414cc56c51f618755fe4ec23720379df2519af7af3664c51c0b49955ee03ffdba0a55e67ec75df6af6d2ff79cd611b50c16048df3e SHA512 730c9728e9bdf46e6846c423c13e8e438716eff518f30b102ef29eb71b6c88aa70fc786f1e8b63f9641ef0f90dd6c9768c4fbf002db9fc15ceb22865b4182b1e
 DIST virtualbox-patches-6.1.36.tar.bz2 2733 BLAKE2B dcfebfeca4873d382441515d48b4dfee9343bc7c83ea3cbb5002dbf7975143a79fae9a701b67dc35505e9ca03ff1b6293cb7c3279c4fdfda8ad21ba5fb9b7e87 SHA512 1bed5cdefbf8e7c4b0d9092ba4961ecf2262f27f35c71a91ef6f2e8fe8a1d92ed74f06bafbf58d70ba7165d933997f58073f4d4f4051e3ba5c0339b729066f57
 DIST virtualbox-patches-7.0.16.tar.bz2 6808 BLAKE2B d15fa2ca306375142c3e25d4759d2790b2bb9eb69e333a8773ad500b29dd127b401943abf59ca59d01858a3ed5551fb3a6c93c4c893c8de971a714ce5306d577 SHA512 a488cbc6660fe8637c44cd79d87156609af089988239a7e76fea8a3c7e6319512c574bef2e942b354b14ce671a8e75ab8b2160abf7c40963795ee8a545ecd992
 DIST virtualbox-patches-7.1.0.tar.bz2 5952 BLAKE2B cb024f36249d7d312c9d0f9231c22a9609d45de1d4c82ca36672fea703765d437d7a414d810adb5eb5f2db92018b669c3b5d0c32372c5ced90f5e13f82344ffa SHA512 c6ef54b7d60f01f5f2b89c6fd7f8b7b509bc62bca0502114cedcbaaf9643445ea413bba481dcf43fb96b5b4d94d64395965682c1ee160d889213615c9272184c
-DIST virtualbox-patches-7.1.0_beta1.tar.bz2 5287 BLAKE2B 5286b5ad2a8c54150f58e2675383ed611b385b9758e1ed6bf81c7551f01724f5132591b3f173b9605c226a200cf70bf3b170ab6c174554b34ed57ada7e35a12b SHA512 d1599d990dd3341393c4be5f5d947b15de9345b6f1d7201fb44c2506d299479564ca7bf5a0c45ade14998e7a48c300e4514da626a248c0447fd31f3cb31e6715

diff --git a/app-emulation/virtualbox-guest-additions/virtualbox-guest-additions-7.1.0_beta2.ebuild b/app-emulation/virtualbox-guest-additions/virtualbox-guest-additions-7.1.0_beta2.ebuild
deleted file mode 100644
index cd37ff892ced..000000000000
--- a/app-emulation/virtualbox-guest-additions/virtualbox-guest-additions-7.1.0_beta2.ebuild
+++ /dev/null
@@ -1,289 +0,0 @@
-# Copyright 2022-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit edo linux-mod-r1 readme.gentoo-r1 systemd toolchain-funcs udev
-
-MY_PN="VirtualBox"
-MY_PV=${PV^^}
-MY_P=${MY_PN}-${MY_PV}
-
-DESCRIPTION="VirtualBox kernel modules and user-space tools for Gentoo guests"
-HOMEPAGE="https://www.virtualbox.org/"
-SRC_URI="https://download.virtualbox.org/virtualbox/${MY_PV}/${MY_P}.tar.bz2
-	https://gitweb.gentoo.org/proj/virtualbox-patches.git/snapshot/virtualbox-patches-7.1.0_beta1.tar.bz2"
-S="${WORKDIR}/${MY_PN}-${MY_PV}"
-
-# Reminder: see the LICENSE related comment in app-emulation/virtualbox-additions ebuild
-LICENSE="GPL-3 LGPL-2.1+ MIT || ( GPL-3 CDDL )"
-SLOT="0/$(ver_cut 1-2)"
-# Still in beta
-#KEYWORDS="~amd64 ~x86"
-IUSE="+dbus gui"
-
-RDEPEND="
-	acct-group/vboxguest
-	acct-group/vboxsf
-	acct-user/vboxguest
-	sys-libs/pam
-	sys-libs/zlib
-	dbus? ( sys-apps/dbus )
-	gui? (
-		x11-apps/xrandr
-		x11-apps/xrefresh
-		x11-libs/libX11
-		x11-libs/libXext
-		x11-libs/libXmu
-		x11-libs/libXt
-	)
-"
-# some libs here are indirect dependencies, and also needed at compile time.
-# keeping them in DEPEND to avoid warnings from qa-vdb.
-DEPEND="
-	${RDEPEND}
-	gui? (
-		x11-libs/libICE
-		x11-libs/libSM
-		x11-libs/libXau
-		x11-libs/libXdmcp
-		x11-base/xorg-proto
-	)
-"
-BDEPEND="
-	>=dev-lang/yasm-0.6.2
-	>=dev-build/kbuild-0.1.9998.3127
-	sys-devel/bin86
-	sys-power/iasl
-"
-
-DOCS=()	# Don't install the default README file during einstalldocs
-
-VBOX_MOD_SRC_DIR="out/linux.${ARCH}/release/bin/additions/src"
-CONFIG_CHECK="~DRM_TTM ~DRM_VMWGFX"
-WARNING_DRM_TTM="DRM_TTM is needed for running the vboxvideo driver."
-WARNING_DRM_VMWGFX="DRM_VMWGFX is the recommended driver for VMSVGA."
-
-DOC_CONTENTS="\n
-Please add users to the \"vboxguest\" group so they can\n
-benefit from seamless mode, auto-resize and clipboard.\n
-\n
-The vboxsf group has been added to make automount services work.\n
-These services are part of the shared folders support.\n
-\n
-Please add:\n
-	/etc/init.d/virtualbox-guest-additions\n
-to the default runlevel in order to start\n
-needed services.\n
-\n
-An autostart .desktop file has been installed to start\n
-VBoxClient in desktop sessions.\n
-\n
-You can mount shared folders with:\n
-	mount -t vboxsf <shared_folder_name> <mount_point>\n
-\n
-Warning:\n
-	this ebuild is only needed if you are running gentoo\n
-	inside a VirtualBox Virtual Machine, you don't need\n
-	it to run VirtualBox itself.\n
-\n"
-
-src_prepare() {
-	# Remove shipped binaries (kBuild,yasm), see bug #232775
-	rm -r kBuild/bin tools || die
-
-	# Provide kernel sources
-	pushd src/VBox/Additions &>/dev/null || die
-	ebegin "Extracting guest kernel module sources"
-	kmk GuestDrivers-src vboxguest-src vboxsf-src vboxvideo-src &>/dev/null
-	eend $? || die
-	popd &>/dev/null || die
-
-	# PaX fixes (see bug #298988)
-	eapply -d "${VBOX_MOD_SRC_DIR}" -- "${FILESDIR}"/vboxguest-6.1.36-log-use-c99.patch
-
-	# Disable things unused or splitted into separate ebuilds
-	cp "${FILESDIR}/${PN}-5-localconfig" LocalConfig.kmk || die
-	if ! use gui; then
-		echo "VBOX_WITH_X11_ADDITIONS :=" >> LocalConfig.kmk || die
-	fi
-
-	# Remove pointless GCC version check
-	sed -e '/ check_gcc$/d' -i configure || die
-
-	# Respect LDFLAGS (bug #759100)
-	sed -i -e '/TEMPLATE_VBoxR3Exe_LDFLAGS.linux[    ]*=/ s/$/ $(CCLDFLAGS)/' Config.kmk || die
-
-	eapply "${WORKDIR}/virtualbox-patches-7.1.0_beta1/patches"
-	eapply_user
-}
-
-src_configure() {
-	tc-export AR CC CXX LD RANLIB
-
-	# Build the user-space tools, warnings are harmless
-	local myconf=(
-		--with-gcc="$(tc-getCC)"
-		--with-g++="$(tc-getCXX)"
-
-		--nofatal
-		--disable-xpcom
-		--disable-sdl-ttf
-		--disable-pulse
-		--disable-alsa
-		$(usev !dbus --disable-dbus)
-		--target-arch=${ARCH}
-		--with-linux="${KV_OUT_DIR}"
-		--build-headless
-	)
-
-	# bug #843437
-	# Respect LDFLAGS (bug #759100)
-	# Cannot use LDFLAGS here because they also get passed to $(LD)
-	cat >> LocalConfig.kmk <<-EOF || die
-		CFLAGS=${CFLAGS}
-		CXXFLAGS=${CXXFLAGS}
-		CCLDFLAGS=${LDFLAGS}
-	EOF
-
-	edo ./configure "${myconf[@]}"
-}
-
-src_compile() {
-	source ./env.sh || die
-
-	# Force kBuild to respect C[XX]FLAGS and MAKEOPTS (bug #178529)
-	MAKEJOBS=$(grep -Eo '(\-j|\-\-jobs)(=?|[[:space:]]*)[[:digit:]]+' <<< ${MAKEOPTS})
-	MAKELOAD=$(grep -Eo '(\-l|\-\-load-average)(=?|[[:space:]]*)[[:digit:]]+' <<< ${MAKEOPTS})
-	MAKEOPTS="${MAKEJOBS} ${MAKELOAD}"
-
-	local myemakeargs=(
-		VBOX_BUILD_PUBLISHER=_Gentoo
-		VBOX_ONLY_ADDITIONS=1
-
-		KBUILD_VERBOSE=2
-
-		AS="$(tc-getCC)"
-		CC="$(tc-getCC)"
-		CXX="$(tc-getCXX)"
-		LD="$(tc-getCC)"
-
-		TOOL_GCC3_CC="$(tc-getCC)"
-		TOOL_GCC3_CXX="$(tc-getCXX)"
-		TOOL_GCC3_LD="$(tc-getCC)"
-		TOOL_GCC3_AS="$(tc-getCC)"
-		TOOL_GCC3_AR="$(tc-getAR)"
-		TOOL_GCC3_OBJCOPY="$(tc-getOBJCOPY)"
-		#TOOL_GCC3_LD_SYSMOD="$(tc-getCC)"
-
-		TOOL_GXX3_CC="$(tc-getCC)"
-		TOOL_GXX3_CXX="$(tc-getCXX)"
-		TOOL_GXX3_LD="$(tc-getCXX)"
-		TOOL_GXX3_AS="$(tc-getCXX)"
-		TOOL_GXX3_AR="$(tc-getAR)"
-		TOOL_GXX3_OBJCOPY="$(tc-getOBJCOPY)"
-		#TOOL_GXX3_LD_SYSMOD="$(tc-getCXX)"
-
-		TOOL_GCC3_CFLAGS="${CFLAGS}"
-		TOOL_GCC3_CXXFLAGS="${CXXFLAGS}"
-		VBOX_GCC_OPT="${CXXFLAGS}"
-		VBOX_NM="$(tc-getNM)"
-		TOOL_YASM_AS=yasm
-	)
-
-	MAKE="kmk" emake "${myemakeargs[@]}"
-
-	# Now creating the kernel modules. We must do this _after_
-	# we compiled the user-space tools as we need two of the
-	# automatically generated header files. (>=3.2.0)
-	# Move this here for bug 836037
-	local modargs=( KERN_DIR="${KV_OUT_DIR}" KERN_VER="${KV_FULL}" )
-	local modlist=( vboxguest vboxsf )
-	use gui && modlist+=( vboxvideo )
-	modlist=( "${modlist[@]/%/=misc:${VBOX_MOD_SRC_DIR}}" )
-	linux-mod-r1_src_compile
-}
-
-src_install() {
-	linux-mod-r1_src_install
-
-	insinto /etc/modprobe.d # 485996
-	newins - vboxsf.conf <<-EOF
-		# modprobe.d configuration file for VBOXSF
-
-		# Internal Aliases - Do not edit
-		# ------------------------------
-		alias fs-vboxsf vboxsf
-	EOF
-
-	cd out/linux.${ARCH}/release/bin/additions || die
-
-	insinto /sbin
-	newins mount.vboxsf mount.vboxsf
-	fperms 4755 /sbin/mount.vboxsf
-
-	if use dbus; then
-		newinitd "${FILESDIR}"/${PN}-8.initd-r1 ${PN}
-	else
-		newinitd <(sed 's/ dbus\>//' "${FILESDIR}"/${PN}-8.initd-r1) ${PN}
-	fi
-
-	insinto /usr/sbin/
-	newins VBoxService vboxguest-service
-	fperms 0755 /usr/sbin/vboxguest-service
-
-	insinto /usr/bin
-	doins VBoxControl
-	fperms 0755 /usr/bin/VBoxControl
-
-	# VBoxClient user service and xrandr wrapper
-	if use gui ; then
-		doins VBoxClient
-		fperms 0755 /usr/bin/VBoxClient
-		doins VBoxDRMClient
-		fperms 4755 /usr/bin/VBoxDRMClient
-
-		pushd "${S}"/src/VBox/Additions/x11/Installer &>/dev/null || die
-		newins 98vboxadd-xclient VBoxClient-all
-		fperms 0755 /usr/bin/VBoxClient-all
-		popd &>/dev/null || die
-	fi
-
-	# udev rule for vboxdrv
-	local udev_rules_dir="/lib/udev/rules.d"
-	dodir ${udev_rules_dir}
-	echo 'KERNEL=="vboxguest", OWNER="vboxguest", GROUP="vboxguest", MODE="0660"' \
-		>> "${ED}/${udev_rules_dir}/60-virtualbox-guest-additions.rules" \
-		|| die
-	echo 'KERNEL=="vboxuser", OWNER="vboxguest", GROUP="vboxguest", MODE="0660"' \
-		>> "${ED}/${udev_rules_dir}/60-virtualbox-guest-additions.rules" \
-		|| die
-
-	# VBoxClient autostart file
-	insinto /etc/xdg/autostart
-	doins "${FILESDIR}"/vboxclient.desktop
-
-	# sample xorg.conf
-	dodoc "${FILESDIR}"/xorg.conf.vbox
-	docompress -x "${ED}"/usr/share/doc/${PF}/xorg.conf.vbox
-
-	systemd_dounit "${FILESDIR}/${PN}.service"
-
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	linux-mod-r1_pkg_postinst
-	udev_reload
-
-	if ! use gui ; then
-		elog "The use flag \"gui\" is off, enable it to install the"
-		elog "X Window System drivers and integration."
-	fi
-
-	readme.gentoo_print_elog
-}
-
-pkg_postrm() {
-	udev_reload
-}