[gentoo-commits] repo/gentoo:master commit in: games-roguelike/stone-soup/

["Erik Mackdanz" <stasibear@gentoo.org>]

commit:     b835aba23cff8c20856a10f6850f22c03409192f
Author:     Erik Mackdanz <stasibear <AT> gentoo <DOT> org>
AuthorDate: Sun Sep 15 00:42:57 2024 +0000
Commit:     Erik Mackdanz <stasibear <AT> gentoo <DOT> org>
CommitDate: Sun Sep 15 00:43:08 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b835aba2

games-roguelike/stone-soup: add 0.32.0

Signed-off-by: Erik Mackdanz <stasibear <AT> gentoo.org>

 games-roguelike/stone-soup/Manifest                |   1 +
 .../stone-soup/stone-soup-0.32.0.ebuild            | 241 +++++++++++++++++++++
 2 files changed, 242 insertions(+)

diff --git a/games-roguelike/stone-soup/Manifest b/games-roguelike/stone-soup/Manifest
index 028ea549eb88..fff38bbf259f 100644
--- a/games-roguelike/stone-soup/Manifest
+++ b/games-roguelike/stone-soup/Manifest
@@ -15,6 +15,7 @@ DIST stone-soup-0.30.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d2
 DIST stone-soup-0.31.0.tar.gz 22432560 BLAKE2B f3e696915458674e3f7ce2a47d19c740c53de897ab40227efc9c127be42dcfbb4b3ee93258ea4094fb1a18aceb37c4341aac86c1174c42ab1ce300bca3281fc6 SHA512 ad354d57a39d07ad8a1a89a7fd20b33a4cd88fcbf1f2276cdefe8890c223272b7a34969a373f6b1f39cff72499c1e2773592ce368e887307908acd59ca00ca4b
 DIST stone-soup-0.31.png 1351 BLAKE2B cc31abd59701aa6f0fb0bdcd90630ceebf7b3cb8b60f0e2817f8800c5bc4b3a5b9fef63c90a97b6248f306e7e3da0df3863a2195b8771863344d2443e7956d59 SHA512 4695204c8b936f7aac1ba15b02a6115a955fb2c56aa9a0b968ff007bc9a1a59b608110d60cce5625a9b92cd2c869bbea7e15433a53c1a338622809477a5846bc
 DIST stone-soup-0.31.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d248c3fd5b06e308782bbc651814f21ec958b30c36074a2576ced4bb10f291b5236da6f6e865ce1d7cefdf96d SHA512 dca555271faf704eb8ecdf5ee8a763df42cdeba94e9c163608c438cfc73c6fbf53416547050cad57f477ade191842e701785b65b7a9f18e27ceab05df8f2f75f
+DIST stone-soup-0.32.0.tar.gz 24408342 BLAKE2B 884c8b067f692bcaeaed0098ab4d89936095c6bda068e9f7cc713357f709879b282f57c831ab23103e4639a0966ec940649e469e7f07db890d03bb6283254b42 SHA512 2c9dbe34158c1c00d58069be21226a739ed8f9da724d9ac615d4420473272e91699bd462c187041ab5744d661dc77b766f95b9dce8ae97a616098c0d7b477c5f
 DIST stone-soup-0.32.0_pre20240626.tar.gz 23577520 BLAKE2B 43a7d9db8037cb1f37ff821da95106d77fa46b0bf34a6b0ef02b66023e1e77a76cc906d2f34d66d6bdea4e9b3859728e2e93909f2c9e1898caab52955d218de2 SHA512 f7a3c58a9f266f354e01175fcc9e2978f4afc5d4e1fc7b5f84979e36213057f2e3bb15f600d40988135e06dc01b65540a4342b16c82edf1c3cfb41421ea92285
 DIST stone-soup-0.32.png 1351 BLAKE2B cc31abd59701aa6f0fb0bdcd90630ceebf7b3cb8b60f0e2817f8800c5bc4b3a5b9fef63c90a97b6248f306e7e3da0df3863a2195b8771863344d2443e7956d59 SHA512 4695204c8b936f7aac1ba15b02a6115a955fb2c56aa9a0b968ff007bc9a1a59b608110d60cce5625a9b92cd2c869bbea7e15433a53c1a338622809477a5846bc
 DIST stone-soup-0.32.svg 68546 BLAKE2B 7c66286c9e8a3516e8483b3edb628a59fce29d8d248c3fd5b06e308782bbc651814f21ec958b30c36074a2576ced4bb10f291b5236da6f6e865ce1d7cefdf96d SHA512 dca555271faf704eb8ecdf5ee8a763df42cdeba94e9c163608c438cfc73c6fbf53416547050cad57f477ade191842e701785b65b7a9f18e27ceab05df8f2f75f

diff --git a/games-roguelike/stone-soup/stone-soup-0.32.0.ebuild b/games-roguelike/stone-soup/stone-soup-0.32.0.ebuild
new file mode 100644
index 000000000000..18316a1186e0
--- /dev/null
+++ b/games-roguelike/stone-soup/stone-soup-0.32.0.ebuild
@@ -0,0 +1,241 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# There are many slots for this package because people in the community
+# like to play old versions.  Every release includes content changes
+# where species/spells/monsters are added or removed.  The public
+# servers (e.g. http://crawl.akrasiac.org:8080) usually support playing
+# versions back to 0.11.
+
+# It's not necessary for Gentoo to support these old version but it's
+# something nice that our distro can offer that others don't.  If the
+# maintenance burden becomes excessive than we can revisit that
+# position.
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 )
+LUA_REQ_USE="deprecated"
+PYTHON_COMPAT=( python3_{10,11,12,13} )
+VIRTUALX_REQUIRED="manual"
+inherit desktop python-any-r1 lua-single xdg-utils toolchain-funcs
+
+DESCRIPTION="Role-playing roguelike game of exploration and treasure-hunting in dungeons"
+HOMEPAGE="https://crawl.develz.org"
+
+# Leave empty string if not a _pre release
+COMMITSHA=""
+if [ -z "${COMMITSHA}" ]; then
+	# This is a tagged release
+	# Note the archive URI and file layout changed upstream between 0.29.0 and 0.29.1
+	SRC_URI="
+		https://github.com/crawl/crawl/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz
+	"
+	MY_P="crawl-${PV}/crawl-ref"
+else
+	# This is a _pre release
+	SRC_URI="
+		https://github.com/crawl/crawl/archive/${COMMITSHA}.tar.gz -> ${P}.tar.gz
+	"
+	MY_P="crawl-${COMMITSHA}/crawl-ref"
+fi
+# MY_SLOT to satisfy pkgcheck variable order checking
+MY_SLOT="0.32"
+SRC_URI="
+	${SRC_URI}
+	https://dev.gentoo.org/~stasibear/distfiles/${PN}.png -> ${PN}-${MY_SLOT}.png
+	https://dev.gentoo.org/~stasibear/distfiles/${PN}.svg -> ${PN}-${MY_SLOT}.svg
+"
+
+S=${WORKDIR}/${MY_P}/source
+# 3-clause BSD: mt19937ar.cc, MSVC/stdint.h
+# 2-clause BSD: all contributions by Steve Noonan and Jesse Luehrs
+# Public Domain|CC0: most of tiles
+# MIT: json.cc/json.h, some .js files in webserver/static/scripts/contrib/
+LICENSE="GPL-2 BSD BSD-2 public-domain CC0-1.0 MIT"
+SLOT="${MY_SLOT}"
+KEYWORDS="~amd64 ~x86"
+IUSE="advpng debug ncurses sound test +tiles"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="
+	${LUA_DEPS}
+	dev-db/sqlite:3
+	sys-libs/zlib
+	!ncurses? ( !tiles? ( sys-libs/ncurses:0 ) )
+	ncurses? ( sys-libs/ncurses:0 )
+	tiles? (
+		media-fonts/dejavu
+		media-libs/freetype:2
+		media-libs/libpng:0
+		sound? (
+			   media-libs/libsdl2[X,opengl,sound,video]
+			   media-libs/sdl2-mixer
+		)
+		!sound? ( media-libs/libsdl2[X,opengl,video] )
+		media-libs/sdl2-image[png]
+		virtual/glu
+		virtual/opengl
+	)"
+DEPEND="${RDEPEND}
+	test? ( <dev-cpp/catch-3.0.0:0 )
+	tiles? (
+		sys-libs/ncurses:0
+	)
+	"
+BDEPEND="
+	app-arch/unzip
+	dev-lang/perl
+	${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+	app-alternatives/lex
+	tiles? (
+		advpng? (
+			app-arch/advancecomp
+		)
+		!advpng? (
+			media-gfx/pngcrush
+		)
+	)
+	virtual/pkgconfig
+	app-alternatives/yacc
+	"
+
+PATCHES=(
+	"${FILESDIR}"/make-v3.patch
+	"${FILESDIR}"/rltiles-make.patch
+	"${FILESDIR}"/avoid-musl-execinfo.patch
+)
+
+python_check_deps() {
+	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+
+	if use !ncurses && use !tiles ; then
+		ewarn "Neither ncurses nor tiles frontend"
+		ewarn "selected, choosing ncurses only."
+		ewarn "Note that you can also enable both."
+	fi
+
+	if use sound && use !tiles ; then
+		ewarn "Sound support is only available with tiles."
+	fi
+}
+
+src_prepare() {
+	default
+	python_fix_shebang "${S}/util/species-gen.py"
+
+	if use advpng; then
+		eapply "${FILESDIR}/make-advpng.patch"
+	fi
+
+	sed -i -e "s/GAME = crawl$/GAME = crawl-${SLOT}/" "${S}/Makefile" \
+		|| die "Couldn't append slot to executable name"
+
+	# File required for a _pre build
+	if ! [ -f "${S}/util/release_ver" ]; then
+		echo "${SLOT}" >"${S}/util/release_ver" || die "Couldn't write release_ver"
+	fi
+
+	# Replace bundled catch2 package with system implementation
+	# https://bugs.gentoo.org/829950
+	if use test; then
+		cp /usr/include/catch2/catch.hpp "${S}/catch2-tests" || die "Couldn't substitute system catch2"
+	fi
+}
+
+src_compile() {
+
+	# Insurance that we're not using bundled lib sources
+	rm -rf contrib || die "Couldn't delete contrib directory"
+
+	myemakeargs=(
+		$(usex debug "FULLDEBUG=y DEBUG=y" "")
+		BUILD_LUA=
+		AR="$(tc-getAR)"
+		CFOPTIMIZE=''
+		# -DLUA_COMPAT_OPENLIB=1 is required to enable the
+		# deprecated (in 5.1) luaL_openlib API (#869671)
+		CFOTHERS="${CXXFLAGS} -DLUA_COMPAT_OPENLIB=1"
+		CONTRIBS=
+		DATADIR="/usr/share/${PN}-${SLOT}"
+		FORCE_CC="$(tc-getCC)"
+		FORCE_CXX="$(tc-getCXX)"
+		LDFLAGS="${LDFLAGS}"
+		MAKEOPTS="${MAKEOPTS}"
+		PKGCONFIG="$(tc-getPKG_CONFIG)"
+		RANLIB="$(tc-getRANLIB)"
+		SAVEDIR="~/.crawl-${SLOT}"
+		SOUND=$(usex sound "y" "")
+		STRIP=touch
+		USE_LUAJIT=
+		V=1
+		prefix="/usr"
+	)
+
+	if use ncurses || (use !ncurses && use !tiles) ; then
+		emake "${myemakeargs[@]}"
+		# move it in case we build both variants
+		use tiles && { mv "crawl-${SLOT}" "${WORKDIR}"/crawl-ncurses-${SLOT} || die ;}
+	fi
+
+	if use tiles ; then
+		emake "${myemakeargs[@]}" clean
+		emake "${myemakeargs[@]}" "TILES=y"
+	fi
+}
+
+src_test() {
+	emake "${myemakeargs[@]}" \
+		  $(usex tiles "TILES=y" "") \
+		  catch2-tests
+}
+
+src_install() {
+	emake "${myemakeargs[@]}" \
+		  $(usex tiles "TILES=y" "") \
+		  DESTDIR="${D}" \
+		  prefix_fp="" \
+		  bin_prefix="${D}/usr/bin" \
+		  install
+
+	[[ -e "${WORKDIR}/crawl-ncurses-${SLOT}" ]] && dobin "${WORKDIR}/crawl-ncurses-${SLOT}"
+
+	# don't relocate docs, needed at runtime
+	rm -rf "${D}/usr/share/${PN}-${SLOT}"/docs/license
+
+	mv "${WORKDIR}/${MY_P}"/docs/crawl.6 "${WORKDIR}/${MY_P}/docs/crawl-${SLOT}.6" \
+	   || die "Couldn't append slot to man page name"
+	doman "${WORKDIR}/${MY_P}/docs/crawl-${SLOT}.6"
+
+	# icons and menu for graphical build
+	if use tiles ; then
+		doicon -s 48 "${DISTDIR}"/${PN}-${SLOT}.png
+		doicon -s scalable "${DISTDIR}"/${PN}-${SLOT}.svg
+		make_desktop_entry "crawl-${SLOT}" "crawl-${SLOT}" "crawl-${SLOT}"
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	elog "crawl is a slotted install that supports having"
+	elog "multiple versions installed.  The binary has the"
+	elog "slot appended, e.g. 'crawl-"${SLOT}"'."
+
+	if use tiles && use ncurses ; then
+		elog
+		elog "Since you have enabled both tiles and ncurses frontends"
+		elog "the ncurses binary is called 'crawl-ncurses-"${SLOT}"' and the"
+		elog "tiles binary is called 'crawl-"${SLOT}"'."
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}