[gentoo-commits] repo/gentoo:master commit in: app-misc/fastfetch/

["Viorel Munteanu" <ceamac@gentoo.org>]

commit:     7ccea3c9df09d0e59277e833da367257a610199c
Author:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 13 16:33:54 2024 +0000
Commit:     Viorel Munteanu <ceamac <AT> gentoo <DOT> org>
CommitDate: Fri Sep 13 16:34:38 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7ccea3c9

app-misc/fastfetch: add 2.24.0

Signed-off-by: Viorel Munteanu <ceamac <AT> gentoo.org>

 app-misc/fastfetch/Manifest                |   1 +
 app-misc/fastfetch/fastfetch-2.24.0.ebuild | 110 +++++++++++++++++++++++++++++
 2 files changed, 111 insertions(+)

diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 044e51f33b66..2d29709a41b7 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -2,3 +2,4 @@ DIST fastfetch-2.20.0.tar.gz 1076860 BLAKE2B 61c50a4c96962063f18ae895d2f7cbe505c
 DIST fastfetch-2.21.3.tar.gz 1093534 BLAKE2B dca99e337e1239958add6323c159f58de5f38fe92c9a7c778d04b127e1467066948e4bc5503afb1054ccbab914eb35d8f35cd2a3cb88bf2ba595255fac5f2ece SHA512 e097d9360b7c5b93b30ad117e47ae5375c48c7e941eaaa56ee5f39b7757374c1ecfe321bec0999ee81aa52deff1be001ff057b621d34a90e95ec6ea83bf9f0b6
 DIST fastfetch-2.22.0.tar.gz 1099230 BLAKE2B 4faef7574bc8897f17c9e59f05f033f8952d97ed56677f0ebe5afec11b7b708fce5d907431dda567cc71b0dd067239d97614b6035792009fff340a069691b547 SHA512 edb4532d220e031d666eac3ae12a004e1481a7c36c68a94b17323953822d0cedb80cdf34c84a184766e9bad64089aaadc3828b5e13f8867e961533c6919dbeae
 DIST fastfetch-2.23.0.tar.gz 1105725 BLAKE2B 8b79deb0f35d8238979441014ca049fcfa838c27323fec13127f5a48e6b28feb03965135c1a338b6bd1e59913e660fc91196c27acbe1b693bc5ff7727efaa5cb SHA512 aad3d549c0f4be3b1f99e7bbbf992dccf79f9ef7ea6a26bfc31ba574b1a32496a1cf75b85c32e0643941cad4061d7ba003b42924f9f272a825a1a09b628acc39
+DIST fastfetch-2.24.0.tar.gz 1104540 BLAKE2B 619d77e533a9e105228d2ce7bb077c7ac561c2ebfe9d7f4d535c8a736ff9123b333865b237409d5fd65ed27d3943ec86a9e6b2ce9a68e317c178a741046b616b SHA512 6dde07346a6ae08c49f8deca19f974fafd94a964542d97f70c39625ccbf151bf01aa626af7582367dab208bb09fc2208f18ba831bdb06202a271f05831617ffd

diff --git a/app-misc/fastfetch/fastfetch-2.24.0.ebuild b/app-misc/fastfetch/fastfetch-2.24.0.ebuild
new file mode 100644
index 000000000000..2609a6c86f16
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-2.24.0.ebuild
@@ -0,0 +1,110 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Fast neofetch-like system information tool"
+HOMEPAGE="https://github.com/fastfetch-cli/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/fastfetch-cli/fastfetch.git"
+	[[ ${PV} == *0.1.9999 ]] && EGIT_BRANCH=master
+	[[ ${PV} == *0.2.9999 ]] && EGIT_BRANCH=dev
+	[[ "${EGIT_BRANCH}" == "" ]] && die "Please set a git branch"
+else
+	SRC_URI="https://github.com/fastfetch-cli/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X chafa dbus ddcutil drm elf gnome imagemagick opencl opengl osmesa pulseaudio sqlite test vulkan wayland xcb xfce xrandr"
+RESTRICT="!test? ( test )"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+# make sure to crank yyjson minimum version to match bundled version
+RDEPEND="
+	>=dev-libs/yyjson-0.10.0
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	ddcutil? ( app-misc/ddcutil:= )
+	drm? ( x11-libs/libdrm )
+	elf? ( virtual/libelf:= )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pulseaudio? ( media-libs/libpulse )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? (
+		media-libs/vulkan-loader
+		sys-apps/pciutils
+	)
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="
+	${RDEPEND}
+	vulkan? ( dev-util/vulkan-headers )
+"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_ZLIB=yes
+		-DENABLE_SYSTEM_YYJSON=yes
+		-DIS_MUSL=$(usex elibc_musl)
+		-DINSTALL_LICENSE=no
+
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_DDCUTIL=$(usex ddcutil)
+		-DENABLE_DRM=$(usex drm)
+		-DENABLE_ELF=$(usex elf)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_PULSE=$(usex pulseaudio)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	append-cppflags -DNDEBUG
+
+	cmake_src_configure
+}