[gentoo-commits] repo/gentoo:master commit in: dev-python/kombu/

["Michał Górny" <mgorny@gentoo.org>]

commit:     1422aae6f47682bbde650487ef6b6865c730cf80
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 11 18:06:53 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Sep 11 18:39:27 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1422aae6

dev-python/kombu: Bump to 5.4.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/kombu/Manifest           |  1 +
 dev-python/kombu/kombu-5.4.1.ebuild | 83 +++++++++++++++++++++++++++++++++++++
 2 files changed, 84 insertions(+)

diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index 23e9f1591975..63d610e6477c 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
 DIST kombu-5.4.0.tar.gz 442120 BLAKE2B 138fc4287f98179166973da019cb5d2536ec2daeb995e1ec94972c95dd3d42c33d97e4e0ed79eedda75e5668c789f463bc115638d8774bcee7018821de9ca3a5 SHA512 fd9b47018a6bb95067486858ee90c052dc497ae4625884521c37b0b18a226de52bee84599b7f7e4aa9ee956e1c648a2672e8c6dda4deaf493b20ffe30fca13bb
+DIST kombu-5.4.1.tar.gz 442786 BLAKE2B b9772bd3a2ebabc4424b029ef72b7378dc2c4f4b0f6002732e5466910589d2c056317bc49ee7c9b3bc8dd02a820614eaf75dfcdebdade84d58fe919b5d11126a SHA512 e0ccab1037e840f11bbdd1f7055df4b25e09c5a00716b1b6b1d754fe7e73b21cc1f85062cb544321eb87bf3eb294837373496e1dca6266c9bc27ed68f7e2c1d8

diff --git a/dev-python/kombu/kombu-5.4.1.ebuild b/dev-python/kombu/kombu-5.4.1.ebuild
new file mode 100644
index 000000000000..5b95ce34649e
--- /dev/null
+++ b/dev-python/kombu/kombu-5.4.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+	https://github.com/celery/kombu/
+	https://pypi.org/project/kombu/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/amqp-5.1.1[${PYTHON_USEDEP}]
+	<dev-python/amqp-6.0.0[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		>=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+		dev-python/pytest-freezer[${PYTHON_USEDEP}]
+		dev-python/zstandard[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		>=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx-celery
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
+	)
+	local EPYTEST_IGNORE=(
+		# obsolete Pyro4
+		t/unit/transport/test_pyro.py
+		# unpackaged azure
+		t/unit/transport/test_azurestoragequeues.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+	optfeature "Etcd backend" dev-python/python-etcd
+	optfeature "MongoDB backend" dev-python/pymongo
+	optfeature "Redis backend" dev-python/redis
+	optfeature "sqlalchemy backend" dev-python/sqlalchemy
+	optfeature "yaml backend" dev-python/pyyaml
+	optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+	optfeature "brotli compression" "app-arch/brotli[python]"
+	optfeature "zstd compression" dev-python/zstandard
+}