[gentoo-commits] repo/gentoo:master commit in: kde-misc/tellico/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     77f59067fa64360a22a165e8fd9edbcedb9560d0
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 10 17:54:09 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Tue Sep 10 17:58:09 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=77f59067

kde-misc/tellico: add 4.0

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-misc/tellico/Manifest           |  1 +
 kde-misc/tellico/tellico-4.0.ebuild | 86 +++++++++++++++++++++++++++++++++++++
 2 files changed, 87 insertions(+)

diff --git a/kde-misc/tellico/Manifest b/kde-misc/tellico/Manifest
index f1642c3574f9..134f59df8b64 100644
--- a/kde-misc/tellico/Manifest
+++ b/kde-misc/tellico/Manifest
@@ -1 +1,2 @@
 DIST tellico-3.5.5.tar.xz 6796536 BLAKE2B 6e526869840a865bc4dcca37e42141889c66739bee657592d9233eda20da1d6e9fdf44f82a29c6b656f34da82f56b2580324278fd73a810e13c844a72d4abd2c SHA512 4bbb975a8d23ac6fb45160b42d7d893adbaa772fd9f04a5a72a5a48c447cfcf1a933e192d71705b59c36cf64f50038248002174ad132d8f22848e3bbbee5dea7
+DIST tellico-4.0.tar.xz 6794676 BLAKE2B f073448302a994ba3f664bae2f939040b4e635b58ecb7d36fb8415936758dce341cdf47823657b22a9b81cf766703378223004b2679e06ef921b7cf5afc056ce SHA512 e7b32cad708ea48ae614461e3a204a114ecd66d5c45c54295b3e97f722735ea428d7b2a2ccd50571b17db81c42ede0aa0db39a31a6e6b8563a5cff88b38f745f

diff --git a/kde-misc/tellico/tellico-4.0.ebuild b/kde-misc/tellico/tellico-4.0.ebuild
new file mode 100644
index 000000000000..b2c38e9e7150
--- /dev/null
+++ b/kde-misc/tellico/tellico-4.0.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+KFMIN=6.5.0
+QTMIN=6.7.2
+inherit ecm kde.org
+
+DESCRIPTION="Collection manager based on KDE Frameworks"
+HOMEPAGE="https://tellico-project.org/"
+
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	SRC_URI="https://tellico-project.org/files/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64"
+fi
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="0"
+IUSE="bibtex cddb discid pdf scanner semantic-desktop taglib v4l xmp yaz"
+
+# tests need network access
+RESTRICT="test"
+
+DEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
+	>=dev-qt/qtcharts-${QTMIN}:6
+	>=dev-qt/qtwebengine-${QTMIN}:6[widgets]
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kcodecs-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kguiaddons-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/knewstuff-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+	>=kde-frameworks/sonnet-${KFMIN}:6
+	bibtex? ( >=dev-perl/Text-BibTeX-0.780.0-r1 )
+	cddb? ( kde-apps/libkcddb:6 )
+	discid? ( dev-libs/libcdio:= )
+	pdf? ( app-text/poppler[qt6] )
+	scanner? ( kde-apps/libksane:6 )
+	semantic-desktop? ( >=kde-frameworks/kfilemetadata-${KFMIN}:6 )
+	taglib? ( >=media-libs/taglib-1.5:= )
+	v4l? ( >=media-libs/libv4l-0.8.3 )
+	xmp? ( >=media-libs/exempi-2:= )
+	yaz? ( >=dev-libs/yaz-2:0= )
+"
+RDEPEND="${DEPEND}
+	!${CATEGORY}/${PN}:5
+"
+BDEPEND="sys-devel/gettext"
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Csv=ON
+		-DENABLE_BTPARSE=$(usex bibtex)
+		$(cmake_use_find_package cddb KCddb6)
+		$(cmake_use_find_package discid CDIO)
+		$(cmake_use_find_package pdf Poppler)
+		$(cmake_use_find_package scanner KSaneWidgets6)
+		$(cmake_use_find_package semantic-desktop KF6FileMetaData)
+		$(cmake_use_find_package taglib Taglib)
+		-DENABLE_WEBCAM=$(usex v4l)
+		$(cmake_use_find_package xmp Exempi)
+		$(cmake_use_find_package yaz Yaz)
+	)
+
+	ecm_src_configure
+}