[gentoo-commits] repo/gentoo:master commit in: dev-python/pysnmp-lextudio/

[gentoo-commits] repo/gentoo:master commit in: dev-python/pysnmp-lextudio/

[Sam James]

commit:     8b4f7dba2e1d192e9c4944043d380dd7cc440f94
Author:     Alfred Wingate <parona <AT> protonmail <DOT> com>
AuthorDate: Thu Jun  6 14:43:02 2024 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Sat Aug 31 04:35:15 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8b4f7dba

dev-python/pysnmp-lextudio: new package, add 6.1.2

Bug: https://bugs.gentoo.org/909945
Bug: https://bugs.gentoo.org/910076
Bug: https://bugs.gentoo.org/921689
Bug: https://bugs.gentoo.org/933201
Bug: https://bugs.gentoo.org/934494
Signed-off-by: Alfred Wingate <parona <AT> protonmail.com>
Signed-off-by: Sam James <sam <AT> gentoo.org>

 dev-python/pysnmp-lextudio/Manifest                |  1 +
 dev-python/pysnmp-lextudio/metadata.xml            | 28 ++++++++++++++
 .../pysnmp-lextudio/pysnmp-lextudio-6.1.2.ebuild   | 45 ++++++++++++++++++++++
 3 files changed, 74 insertions(+)

diff --git a/dev-python/pysnmp-lextudio/Manifest b/dev-python/pysnmp-lextudio/Manifest
new file mode 100644
index 000000000000..e72987b0c2af
--- /dev/null
+++ b/dev-python/pysnmp-lextudio/Manifest
@@ -0,0 +1 @@
+DIST pysnmp_lextudio-6.1.2.tar.gz 412553 BLAKE2B 8ac761c1fa4762f1fb70bdb69e338c786b44cffe13d59d3fcb5f5a3cb4c0fca9593d12b59687f3f2ec568b8cd9964ce35a70e76b9e932ddb2380c5ba4c0b993f SHA512 b307cafd0a40fa5f2c081b901a19947b5e0b6dcc97bb8571eef6649059cab3f2ab4a7184132f05f7a1982496f3d2fd9d865cbe98355ad987fb09bffbe16b3581

diff --git a/dev-python/pysnmp-lextudio/metadata.xml b/dev-python/pysnmp-lextudio/metadata.xml
new file mode 100644
index 000000000000..2d1f5e6d7f14
--- /dev/null
+++ b/dev-python/pysnmp-lextudio/metadata.xml
@@ -0,0 +1,28 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<!-- maintainer-needed -->
+	<stabilize-allarches/>
+	<longdescription>
+		This is a Python implementation of SNMP v.1/v.2c engine. Its general
+		functionality is to assemble/disassemble SNMP messages from/into
+		given SNMP Object IDs along with associated values. PySNMP also provides
+		a few transport methods specific to TCP/IP networking.
+
+		PySNMP is written entirely in Python and is self-sufficient in terms
+		that it does not rely on any third party tool (it is not a wrapper!).
+	</longdescription>
+	<longdescription lang="ja">
+		これは SNMP v.1/v.2 エンジンのPython言語での実装です。関連値に沿ったSNMPオブジェ
+		クトIDから/へSNMPメッセージをアセンブル/ディスアセンブルするのが一般的な機能です
+		。PySNMPは幾つかのTCP/IPネットワーキングを特定するトランスポート・メソッドも提供
+		します。
+
+		PySNMPは全体をPython言語で記述され、どのサードパーティ製ツールも信用しない立場で
+		自給自足します。(これはラッパー・ツールではありません。)
+	</longdescription>
+	<upstream>
+		<remote-id type="pypi">pysnmp-lextudio</remote-id>
+		<remote-id type="github">lextudio/pysnmp</remote-id>
+	</upstream>
+</pkgmetadata>

diff --git a/dev-python/pysnmp-lextudio/pysnmp-lextudio-6.1.2.ebuild b/dev-python/pysnmp-lextudio/pysnmp-lextudio-6.1.2.ebuild
new file mode 100644
index 000000000000..6dc92eb57f27
--- /dev/null
+++ b/dev-python/pysnmp-lextudio/pysnmp-lextudio-6.1.2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..13} )
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python SNMP library"
+HOMEPAGE="
+	https://pypi.org/project/pysnmp-lexstudio/
+	https://github.com/lextudio/pysnmp/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+PROPERTIES="test_network"
+RESTRICT="test"
+
+RDEPEND="
+	!!dev-python/pysnmp
+	>=dev-python/pyasn1-0.2.3[${PYTHON_USEDEP}]
+	>=dev-python/pysnmpcrypto-0.0.4[${PYTHON_USEDEP}]
+"
+PDEPEND="
+	>=dev-python/pysmi-lextudio-1.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/pysmi-lextudio-1.3.0[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+# TODO
+# distutils_enable_sphinx docs/source dev-python/furo dev-python/sphinx-copybutton dev-python/sphinx-sitemap
+
+python_test() {
+	mibdump NET-SNMP-EXAMPLES-MIB || die
+	epytest
+}