[gentoo-commits] repo/gentoo:master commit in: kde-apps/libkgapi/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     23b7733a1087f8618a8529b0806d6e59082fc703
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 29 23:06:45 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Aug 30 14:46:49 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=23b7733a

kde-apps/libkgapi: Empty revbump for $CATEGORY/$PN:6 stabilisation

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 kde-apps/libkgapi/libkgapi-23.08.5-r2.ebuild | 53 ++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/kde-apps/libkgapi/libkgapi-23.08.5-r2.ebuild b/kde-apps/libkgapi/libkgapi-23.08.5-r2.ebuild
new file mode 100644
index 000000000000..4bb890933a7f
--- /dev/null
+++ b/kde-apps/libkgapi/libkgapi-23.08.5-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_QTHELP="true"
+ECM_TEST="true"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="Library for accessing Google calendar and contact resources"
+HOMEPAGE="https://api.kde.org/kdepim/libkgapi/html/index.html"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="kf6compat"
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcalendarcore-${KFMIN}:5
+	>=kde-frameworks/kcontacts-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	!kf6compat? ( dev-libs/cyrus-sasl:2 )
+"
+RDEPEND="${DEPEND}
+	kf6compat? ( kde-apps/libkgapi:6 )
+"
+BDEPEND=">=dev-qt/linguist-tools-${QTMIN}:5"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SASL_PLUGIN=$(usex !kf6compat)
+	)
+	ecm_src_configure
+}
+
+src_test() {
+	local myctestargs=(
+		# Both fail for multiple distros, see bug #832709 for more discussion
+		# Revisit at least once Qt 5.15.3 is in wider distribution (in Gentoo at least):
+		#   contacts-contactcreatejobtest, contacts-contactmodifyjobtest
+		# More failures not specific to Gentoo, bug #852593, KDE-bug #440648:
+		#  calendar-eventcreatejobtest, calendar-eventfetchjobtest, calendar-eventmodifyjobtest
+		-E "(contacts-contactcreatejobtest|contacts-contactmodifyjobtest|calendar-eventcreatejobtest|calendar-eventfetchjobtest|calendar-eventmodifyjobtest)"
+	)
+
+	ecm_src_test
+}