[gentoo-commits] repo/gentoo:master commit in: app-text/poppler/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     e97834616ac5ac5724bbe816f8a11f8afa3870e0
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Aug 29 17:09:58 2024 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Aug 29 19:02:34 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e9783461

app-text/poppler: drop 24.07.0

Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-text/poppler/Manifest               |   2 -
 app-text/poppler/poppler-24.07.0.ebuild | 157 --------------------------------
 2 files changed, 159 deletions(-)

diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index 1eebf965bd96..d3a13786c93a 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -2,8 +2,6 @@ DIST poppler-24.04.0.tar.xz 1904936 BLAKE2B c4a9350b990981b0018229923160ded621f4
 DIST poppler-24.04.0.tar.xz.sig 833 BLAKE2B 842f500b45396a3a0a6e5789a6f0957ea5f3d66536dfb6e32420201bdfc4a867a0262d0dc97302cc0d530e68ca163fda10f143516a472394bcb085f746d891d1 SHA512 4419a2a94c34621ffde1f1e0d1d26929171f81b6809a5380af30434c2220a7bf694ff2f8e7ba7a611b1ebd265e91424060238f51d2cccd9acecd92f66e0e1e28
 DIST poppler-24.06.1.tar.xz 1910252 BLAKE2B 7eb2543dce1da0a04ce872d4af30eb25304db72fb6dc6f3ed309d478844af0fdd66e886a6e8c3a48df2096a8aa834f6b14e65689466de3283b54bc50289cd8b3 SHA512 4add06c9cb7741a66cd11e169b6cc332e80151b6e3450295400e948f30c340d018f67fcf2b923f4f65a11f20e2ce1c2740008e823d9b97f966eded7ae51e4167
 DIST poppler-24.06.1.tar.xz.sig 833 BLAKE2B f2fa137d12e9143691d1a640a39c40fe8d923b017e60e2a125026082adce8e0863c501167a170d60aa38044d9c799f9e31a8eacfee68847554ac86f7eea84d26 SHA512 f6343d3b7c8889a5b8e8a14a14e60fd11990393608639b0f41bb35451c2ac5ec28bba01af79578c0cb224726886b28a491a769cba5347df67680d18812258b9f
-DIST poppler-24.07.0.tar.xz 1913256 BLAKE2B fe4c227e72b215faea3942d9bab20b495da68cded7fbf082148362eae7ff35004e982fccb80fd05d3774cbf42d510b2784bbb6e71eb8b9fe7ac7f77a52d980ad SHA512 c11877c9977341c75166991118d9cbd0b4167708ead06bc464f0c13ef1e8ff30733f6521d9c8f8608fb6c59db2a3a046eac36a635f90e7aa7124f9be21df422d
-DIST poppler-24.07.0.tar.xz.sig 833 BLAKE2B c903a8f84c65c187f2f976eb83059722ef524331e0bae8aef21f0cc8af0d144528bc8c0b29e821eced49e318565e1c8fff4a674f9d74cf63e645e93caebd976d SHA512 5a80f27ce09ca2864e870a6d1cd9b8ac3d727c7c7522ff865517cb804344c797067ecb0763c58b486a5e371286ca2e0afa93c260cb864b11815972c03207ad5d
 DIST poppler-24.08.0.tar.xz 1912592 BLAKE2B f76ccb8d596909d671df34f6c028e6161ad734d31b460bc7b3578d08a75ad146d6d2c1e4108acb33d08fd518fee014cc84e23d2e04ea92ad152702af614c5ca2 SHA512 47309b75746d5bc309ae98da9280e5178c81505c8873e849ece6923eb0ae0df6f271dab1e38b3aac1dbd5d05518284ad237ea78ba40d90420c6fc53ae1c3b400
 DIST poppler-24.08.0.tar.xz.sig 833 BLAKE2B d257fc092c8541daf2e88a852655827470fb4890316f0a9b334b18c736ea33500e52c3b6b238047e8e3ded6a155b4466dcfa3afabfede11ed89b3fa17553577e SHA512 5e5c0185db2f3c1e1639e1eead93cf9e282db403edb91750d8ec325ca69f4bfb026345f2e9a8a18ed23a5a02b308163f9b4a8d6a75f9e760414cd709681a25a7
 DIST poppler-test-400f3ff05b2b1c0ae17797a0bd50e75e35c1f1b1.tar.bz2 5199265 BLAKE2B d58f6ee7b44ca45291c205f9619db3833871f5789dd6a4e3ccc9acce2b6d7967a6b8596e3f32b7b35ba3d185976e8b9c8a998071c4451bb5ce674825a4005d6d SHA512 5bf5d99956fa0a6a93e0b0dc4713ecd8810811eca35514cc5765ffaafb9485f64f94b21487afa46c16eaf66326fcb999e792b8121eeb188e7e33a32a4798fb76

diff --git a/app-text/poppler/poppler-24.07.0.ebuild b/app-text/poppler/poppler-24.07.0.ebuild
deleted file mode 100644
index 7b4beeb49ab3..000000000000
--- a/app-text/poppler/poppler-24.07.0.ebuild
+++ /dev/null
@@ -1,157 +0,0 @@
-# Copyright 2005-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake flag-o-matic toolchain-funcs xdg-utils
-
-if [[ ${PV} == *9999* ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
-	SLOT="0/9999"
-else
-	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/aacid.asc
-	inherit verify-sig
-
-	TEST_COMMIT="ff3133cdb6cb496ee1d2c3231bfa35006a5e8410"
-	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
-	SRC_URI+=" test? ( https://gitlab.freedesktop.org/poppler/test/-/archive/${TEST_COMMIT}/test-${TEST_COMMIT}.tar.bz2 -> ${PN}-test-${TEST_COMMIT}.tar.bz2 )"
-	SRC_URI+=" verify-sig? ( https://poppler.freedesktop.org/${P}.tar.xz.sig )"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
-	SLOT="0/139"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
-fi
-
-DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
-HOMEPAGE="https://poppler.freedesktop.org/"
-
-LICENSE="GPL-2"
-IUSE="boost cairo cjk curl +cxx debug doc gpgme +introspection +jpeg +jpeg2k +lcms nss png qt5 qt6 test tiff +utils"
-RESTRICT="!test? ( test )"
-
-COMMON_DEPEND="
-	>=media-libs/fontconfig-2.13
-	>=media-libs/freetype-2.10
-	sys-libs/zlib
-	cairo? (
-		>=dev-libs/glib-2.64:2
-		>=x11-libs/cairo-1.16
-		introspection? ( >=dev-libs/gobject-introspection-1.72:= )
-	)
-	curl? ( net-misc/curl )
-	gpgme? ( >=app-crypt/gpgme-1.19.0:=[cxx] )
-	jpeg? ( >=media-libs/libjpeg-turbo-1.1.0:= )
-	jpeg2k? ( >=media-libs/openjpeg-2.3.0-r1:2= )
-	lcms? ( media-libs/lcms:2 )
-	nss? ( >=dev-libs/nss-3.49 )
-	png? ( media-libs/libpng:0= )
-	qt5? (
-		>=dev-qt/qtcore-5.15.2:5
-		>=dev-qt/qtgui-5.15.2:5
-		>=dev-qt/qtxml-5.15.2:5
-	)
-	qt6? ( dev-qt/qtbase:6[gui,xml] )
-	tiff? ( media-libs/tiff:= )
-"
-RDEPEND="${COMMON_DEPEND}
-	cjk? ( app-text/poppler-data )
-"
-DEPEND="${COMMON_DEPEND}
-	boost? ( >=dev-libs/boost-1.74 )
-	test? (
-		qt5? (
-			>=dev-qt/qttest-5.15.2:5
-			>=dev-qt/qtwidgets-5.15.2:5
-		)
-		qt6? ( dev-qt/qtbase:6[widgets] )
-	)
-"
-BDEPEND="
-	>=dev-util/glib-utils-2.64
-	virtual/pkgconfig
-"
-
-if [[ ${PV} != *9999* ]] ; then
-	BDEPEND+=" verify-sig? ( >=sec-keys/openpgp-keys-aacid-20230907 )"
-fi
-
-DOCS=( AUTHORS NEWS README.md README-XPDF )
-
-PATCHES=(
-	"${FILESDIR}/${PN}-23.10.0-qt-deps.patch"
-	"${FILESDIR}/${PN}-21.09.0-respect-cflags.patch"
-	"${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
-)
-
-src_unpack() {
-	if [[ ${PV} == *9999* ]] ; then
-		git-r3_src_unpack
-	elif use verify-sig ; then
-		verify-sig_verify_detached "${DISTDIR}"/${P}.tar.xz{,.sig}
-	fi
-
-	default
-}
-
-src_prepare() {
-	cmake_src_prepare
-
-	# Clang doesn't grok this flag, the configure nicely tests that, but
-	# cmake just uses it, so remove it if we use clang
-	if tc-is-clang ; then
-		sed -e 's/-fno-check-new//' -i cmake/modules/PopplerMacros.cmake || die
-	fi
-
-	if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
-		sed -e '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
-			-i CMakeLists.txt || die
-	else
-		einfo "policy(SET CMP0002 OLD) - workaround can be removed"
-	fi
-}
-
-src_configure() {
-	xdg_environment_reset
-	append-lfs-flags # bug #898506
-
-	local mycmakeargs=(
-		-DBUILD_GTK_TESTS=OFF
-		-DBUILD_QT5_TESTS=$(usex test $(usex qt5))
-		-DBUILD_QT6_TESTS=$(usex test $(usex qt6))
-		-DBUILD_CPP_TESTS=$(usex test)
-		-DBUILD_MANUAL_TESTS=$(usex test)
-		-DTESTDATADIR="${WORKDIR}"/test-${TEST_COMMIT}
-		-DRUN_GPERF_IF_PRESENT=OFF
-		-DENABLE_BOOST="$(usex boost)"
-		-DENABLE_ZLIB_UNCOMPRESS=OFF
-		-DENABLE_UNSTABLE_API_ABI_HEADERS=ON
-		-DUSE_FLOAT=OFF
-		-DWITH_Cairo=$(usex cairo)
-		-DENABLE_LIBCURL=$(usex curl)
-		-DENABLE_CPP=$(usex cxx)
-		-DENABLE_GPGME=$(usex gpgme)
-		-DWITH_JPEG=$(usex jpeg)
-		-DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
-		-DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
-		-DENABLE_LCMS=$(usex lcms)
-		-DENABLE_NSS3=$(usex nss)
-		-DWITH_PNG=$(usex png)
-		-DENABLE_QT5=$(usex qt5)
-		-DENABLE_QT6=$(usex qt6)
-		-DENABLE_LIBTIFF=$(usex tiff)
-		-DENABLE_UTILS=$(usex utils)
-	)
-	use cairo && mycmakeargs+=( -DWITH_GObjectIntrospection=$(usex introspection) )
-
-	cmake_src_configure
-}
-
-src_install() {
-	cmake_src_install
-
-	# live version doesn't provide html documentation
-	if use cairo && use doc && [[ ${PV} != *9999* ]]; then
-		# For now install gtk-doc there
-		insinto /usr/share/gtk-doc/html/poppler
-		doins -r "${S}"/glib/reference/html/*
-	fi
-}