[gentoo-commits] repo/gentoo:master commit in: dev-python/zeroconf/

["Michał Górny" <mgorny@gentoo.org>]

commit:     859088868d7a64d5217133c8f9527bfd02567380
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Aug 27 06:26:46 2024 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Aug 27 07:39:27 2024 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=85908886

dev-python/zeroconf: Bump to 0.133.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/zeroconf/Manifest                |  1 +
 dev-python/zeroconf/zeroconf-0.133.0.ebuild | 56 +++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)

diff --git a/dev-python/zeroconf/Manifest b/dev-python/zeroconf/Manifest
index b74d654ade46..dd0c30a8b50d 100644
--- a/dev-python/zeroconf/Manifest
+++ b/dev-python/zeroconf/Manifest
@@ -1 +1,2 @@
 DIST zeroconf-0.132.2.tar.gz 170698 BLAKE2B 7c76e2a00571a19b23f288dc1183da6ce274ebdf3f64f323e282f444011f7cbf90a63e02a991936a2cfa2d227568b31444b8f61f1110588638d4e888dd8749a6 SHA512 686cdfd2f32c6bad03fb5fd287b1e22f2f0b5099a8971dcff1d9fca7e63bc8069b195feb97be710c20fae8c524ab92143e395cdfec26ede103295d1aa4d32a8f
+DIST zeroconf-0.133.0.tar.gz 171328 BLAKE2B 2a32186bf17120d2448383af252a4a47e83c5900187e841974fa7b1fc4ae70b1227cf5baf556f7d24650f75e6f27a6a4a5b4f2f797b47c55d5016d20a1263c1e SHA512 06ec5f4face3578a16a38ebd750c9f74cc38932e840c8615d597807a3b5781adf9bd5bf2f8b438df165993de4f429c45efe9f4751baf7d00b4ebabc348984b41

diff --git a/dev-python/zeroconf/zeroconf-0.133.0.ebuild b/dev-python/zeroconf/zeroconf-0.133.0.ebuild
new file mode 100644
index 000000000000..42ef77fc404f
--- /dev/null
+++ b/dev-python/zeroconf/zeroconf-0.133.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Pure Python Multicast DNS Service Discovery Library (Bonjour/Avahi compatible)"
+HOMEPAGE="
+	https://github.com/python-zeroconf/python-zeroconf/
+	https://pypi.org/project/zeroconf/
+"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/ifaddr-0.1.7[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/async-timeout-3.0.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+# the build system uses custom build script that uses distutils to build
+# C extensions, sigh
+BDEPEND="
+	>=dev-python/cython-3.0.8[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-65.6.3[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export REQUIRE_CYTHON=1
+
+python_test() {
+	local -x SKIP_IPV6=1
+	local EPYTEST_DESELECT=(
+		# network
+		tests/test_core.py::Framework::test_close_multiple_times
+		tests/test_core.py::Framework::test_launch_and_close
+		tests/test_core.py::Framework::test_launch_and_close_context_manager
+
+		# fragile to timeouts (?)
+		tests/services/test_browser.py::test_service_browser_expire_callbacks
+		tests/utils/test_asyncio.py::test_run_coro_with_timeout
+	)
+
+	epytest -o addopts=
+}